Downlink Data Ditampilkan pada Display Oled


Pendahuluan

Pada project ini, anda akan menggunakan Shield Workshop Antares pada modul Development Board Lynx-32 Antares. Pada Shield Workshop Antares ini terdapat sensor suhu, kelembapan (DHT11), relay, LED dan push button. Anda akan mengirim pesan downlink kemudian ditampilkan pada display OLED. Proses pengiriman downlink ini menggunakan software POSTMAN yang melakukan HIT API downlink ke Platform Antares.

Prasyarat

Material yang dibutuhkan mengikuti dengan Prasyarat Umum pada laman sebelumnya. Jika anda belum menyiapkan kebutuhan pada laman tersebut, maka anda dapat mengunjungi laman berikut.

Adapun tambahan material yang spesifik untuk project ini adalah sebagai berikut.

  1. Shield Workshop Antares

  1. Modul OLED SSD1306 0.96inch 128x64 pixel berbasis I2C.

  1. Library display OLED. Pada dokumentasi ini menggunakan Adafruit_SSD1306 versi 2.5.7.

Jika anda belum menginstall libraryAdafruit_SSD1306 versi 2.5.7 dapat mengikuti langkah pada link berikut.

Adafruit SSD1306

  1. Software Postman.

Jika anda belum menginstall Software POSTMAN anda dapat mengikuti langkah pada link berikut.

Instalasi Postman

Langkah Kerja

1. Jalankan Aplikasi Arduino IDE

2. Membuka Contoh Program

Kode program dapat anda buka pada Arduino IDE melalui File > Examples > Antares LoRaWAN > Lynx32-Simple-Project > Class A > DOWNLINK_OLED_CLASS_A.

Berikut adalah kode program dari contoh DOWNLINK_OLED_CLASS_A.

#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <lorawan.h>

// OLED Initialitation
#define OLED_RESET 4
Adafruit_SSD1306 display(OLED_RESET);

//ABP Credentials
/*
  Notes:
  - select ABP Activation on ANTARES
  - select inherit to generate your keys
  - nwkSKey: 32 digit hex, you can put 16 first digits by first 16 digits your access key and add 16 digits with 0 (ex : abcdef01234567890000000000000000)
  - appSKey: 32 digit hex, put 16 first digits by 0 and put last 16 digits by last 16 digit your access key (ex : 0000000000000000abcdef0123456789)
*/
const char *devAddr = "Lora-Device-Address"; // Replace with the Device Address that you have in the Antares console
const char *nwkSKey = "Network-Session-Key"; // Replace with the Network Session Key that you have in the Antares console
const char *appSKey = "Application-Session-Key"; // Replace with the Application Session Key that you have in the Antares console

const unsigned long interval = 60000;    // 60 s interval to send message
unsigned long previousMillis = 0;  // will store last time message sent
unsigned int counter = 0;     // message counter

char myStr[50];
char outStr[255];
byte recvStatus = 0;
int channel;

const sRFM_pins RFM_pins = {
  .CS = 5,    //LYNX32 to RFM NSS
  .RST = 0,   //LYNX32 to RFM RST
  .DIO0 = 27, //LYNX32 to RFM DIO0
  .DIO1 = 2,  //LYNX32 to RFM DIO1
};

void setup() {
  // Setup loraid access
  Serial.begin(115200);
  delay(2000);
  if (!lora.init()) {
    Serial.println("RFM95 not detected");
    delay(5000);
    return;
  }

  // Set LoRaWAN Class change CLASS_A or CLASS_C
  lora.setDeviceClass(CLASS_A);

  // Set Data Rate
  lora.setDataRate(SF10BW125);

  // set channel to random
  lora.setChannel(MULTI);

  // Set TxPower to 15 dBi (max)
  lora.setTxPower1(15);

  // Put ABP Key and DevAddress here
  lora.setNwkSKey(nwkSKey);
  lora.setAppSKey(appSKey);
  lora.setDevAddr(devAddr);

  // OLED initialization
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);  // OLED initialization with address 0x3C
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 0);
  display.display();
  delay(2000);
}

void loop() {
  // Check interval overflow
  if (millis() - previousMillis > interval) {
    previousMillis = millis();

    sprintf(myStr, "Lora Counter-%d", counter);

    Serial.print("Sending : ");
    Serial.println(myStr);

    lora.sendUplink(myStr, strlen(myStr), 0, 5);
    counter++;
    channel = lora.getChannel();
    Serial.print(F("Ch : "));    Serial.print(channel); Serial.println(" ");
  }

  // Check Lora RX
  lora.update();

  recvStatus = lora.readData(outStr);
  if (recvStatus) {
    int counter = 0;

    for (int i = 0; i < recvStatus; i++)
    {
      if (((outStr[i] >= 32) && (outStr[i] <= 126)) || (outStr[i] == 10) || (outStr[i] == 13))
        counter++;
    }
    if (counter == recvStatus)
    {
      Serial.print(F("Received String : "));
      for (int i = 0; i < recvStatus; i++)
      {
        Serial.print(char(outStr[i]));
      }
      // Show on OLED
      display.clearDisplay();
      display.setTextSize(1);
      display.setTextColor(SSD1306_WHITE);
      display.setCursor(0, 0);
      display.println("Received String : ");
      display.println((char*)outStr);
      display.display();
    }
    else
    {
      Serial.print(F("Received Hex : "));
      for (int i = 0; i < recvStatus; i++)
      {
        Serial.print(outStr[i], HEX); Serial.print(" ");
      }

      display.clearDisplay();
      display.setTextSize(1);
      display.setTextColor(SSD1306_WHITE);
      display.setCursor(0, 0);
      display.println("Received Hex : ");
      for (int i = 0; i < recvStatus; i++) {
        display.print(outStr[i] < 16 ? "0" : "");
        display.print(outStr[i], HEX);
        display.print(" ");
      }
      display.display();
    }
    Serial.println();
  }

}

3. Set LoRaWAN Parameter di Antares

Pada halaman Device console Antares lakukan Set LoRa dengan menekan button Set LoRa seperti gambar berikut.

Masukan parameter LoRaWAN dengan Lora Device Class A, Activation Mode ABP, ABP Parameters Inherit seperti pada gambar berikut.

Ketika memilih ABP Parameters Inherit maka parameter LoRa akan digenerate oleh Antares. Dari sisi perangkat, Development Board Lynx32 perlu menyesuaikan parameter LoRa tersebut.

Jangan lupa untuk menyimpan (copy) parameter Network Session Key dan Application Session Key sebelum klik Set LoRa untuk memudahkan proses selanjutnya.

Pastikan akun antares anda memiliki paket LoRa yang aktif.

4. Set LoRaWAN Parameter pada Kode Program

Ubah parameter LoRaWAN ABP pada variabel berikut *devAddr , *nwkSkey , dan *appSKey. Sesuaikan dengan parameter di console Antares.

const char *devAddr = "Lora-Device-Address";
const char *nwkSKey = "Network-Session-Key";
const char *appSKey = "Application-Session-Key"

Parameter *devAddr yang telah digenerate oleh Antares dapat dilihat pada halaman device setelah selesai Set LoRa.

Parameter *nwkSKey dan *appSKey didapatkan saat Set LoRa pada langkah sebelumnya.

Jika anda lupa menyimpan *nwkSkey dan *appSKey pada langkah sebelumnya maka lihat accesskey pada akun antares anda kemudian ikuti format berikut.

Example Accesskey = "aaaaaaaaaaaaaaaa:bbbbbbbbbbbbbbbb"; //32 digit accesskey

const char *nwkSKey = "aaaaaaaaaaaaaaaa0000000000000000"; //16 digit first accesskey plus 16 digit zero

const char *appSKey = "0000000000000000bbbbbbbbbbbbbbbb"; //16 digit zero plus 16 digit last acesskey

5. Compile dan Upload Program

Hubungkan Development Board Lynx-32 dengan komputer anda dan pastikan Communication Port terbaca.

Pada sistem operasi Windows pengecekan dapat dilakukan melalui Device Manager.

Jika Development Board Lynx-32 anda terbaca maka akan tampil USB-Serial CH340 dengan port menyesuaikan ketersediaan port (pada kasus ini terbaca COM4).

Atur Board Lynx-32 dengan klik Tools > Board > ESP32 Arduino pada Arduino IDE, kemudian pastikan board yang digunakan adalah ESP32 Dev Module. Pilih port sesuai communicaion port yang terbaca (dalam kasus ini COM4). Hasilnya akan terlihat seperti gambar berikut.

Setelah semua setup selesai, lakukan upload program dengan menekan icon panah seperti gambar berikut. Tunggu hingga selesai proses compile dan upload.

Icon Centang pada Arduino IDE hanyalah proses verify. Biasanya digunakan untuk Compile program untuk mengetahui apakah terdapat error atau tidak.

Icon Panah pada Arduino IDE adalah proses verify and upload. Biasanya digunakan untuk Compile program sekaligus Flash program kedalam target board.

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

Setelah selesai upload program, anda dapat melihat serial monitor untuk melakukan debug program. Icon serial monitor terlihat seperti pada gambar berikut.

Atur serial baud rate menjadi 115200 dan pilih BothNL & CR. Hasilnya akan terlihat seperti gambar berikut.

Pastikan serial baud rate sesuai dengan nilai yang terdefinisi di kode program. Jika serial baud rate tidak sama, antara kode program dan serial monitor maka karakter ASCII tidak akan terbaca dengan baik.

6. Setup software POSTMAN

Pada langkah ini anda memerlukan software POSTMAN. Anda dapat menginput end-point, request header, dan request body terlebih dahulu dengan mengikuti format berikut.

End Point

Sesuaikan your-application-name dan your-device-name sesuai nama-nama yang terdaftar pada akun Antares anda.

Request Header

Sesuaikan your-access-key dengan access key akun Antares anda.

Hasilnya seperti pada gambar berikut.

Selanjutnya anda perlu menginput request body untuk dengan mengikuti format berikut.

Request Body

{
      "m2m:cin": {
        "con": "{\"type\":\"downlink\", \"data\":\"your-downlink-data\"}"
    }
}

Default Downlink Port yaitu port 10.

Pada software POSTMAN pilih tab Body kemudian pilih raw dan masukan payload sesuai request body yang ingin digunakan seperti gambar berikut.

Sesuaikan isi field "data" sesuai dengan perintah downlink yang ingin anda kirimkan.

Setelah setup software POSTMAN selesai, saatnya mengirimkan perintah downlink. Pada field "data" diisi dengan string "test" sebagai pesan yang akan dikirim melalui lorawan downlink. Jika sudah selesai mengisi field "data" selanjutnya tekan tombol Send pada software POSTMAN.

Jika request HTTP melalui software POSTMAN berhasil, pada bagian response software POSTMAN akan muncul pesan seperti gambar berikut.

8. Periksa Data di Antares

Setelah langkah mengirim pesan downlink pada software POSTMAN berhasil, selanjutnya buka halaman device antares kemudian lihat apakah perintah downlink sudah masuk di Antares.

Data yang dikirimkan dari POSTMAN berupa "type": "downlink" dan "data". pesan downlink yang diteruskan ke Development Board Lynx-32 ada didalam field "data".

Pesan downlink yang diteruskan dari Antares ke Development Board Lynx-32 dapat dilihat pada Serial Monitor terlihat seperti gambar berikut.

Pada LoRaWAN Class A, pesan downlink akan diterima oleh Lynx-32 setelah Lynx-32 melakukan uplink.

Pesan downlink yang diterima juga ditampilkan pada OLED terlihat seperti gambar berikut.