# Send Data DHT 11 dan Retrieve Data ditampilkan pada Display OLED

## Pendahuluan

Pada project ini, Anda akan menggunakan **Shield Workshop Antares** pada modul **Development Board Lynx-32.** Pada **Shield Workshop Antares** ini terdapat sensor suhu, kelembapan (DHT11), relay, LED, dan push button. Anda akan melakukan monitoring suhu dan kelembapan dengan periode interval yang dintentukan. Hasil data yang dikirim sensor dapat Anda pantau melalui console Antares dan ditampilkan pada **OLED.** Anda juga dapat mengirim pesan berupa **data string** yang ditampilkan pada display **OLED**. Proses pengiriman data ini menggunakan **Software MQTTX**  untuk mengirimkan data ke **Antares IoT Platform**.

<figure><img src="/files/DqrsYAcEt6E0oV82Kf36" alt=""><figcaption><p>Gambar Ilustrasi Project</p></figcaption></figure>

## Prasyarat

Material yang dibutuhkan mengikuti **Prasyarat Umum** pada laman sebelumnya. Jika Anda belum menyiapkan kebutuhan pada laman tersebut, maka Anda dapat mengunjungi laman berikut.

{% content-ref url="/pages/Zpk3iTltrVZubNhHlGNm" %}
[Prasyarat Umum ESP32 Wi-Fi](/contoh-kode-dan-library/esp32-wi-fi/prasyarat-umum-esp32-wi-fi.md)
{% endcontent-ref %}

Adapun tambahan material yang spesifik untuk project ini adalah sebagai berikut.

1. Shield Workshop Antares
2. Modul OLED SSD1036 0,96inch 128x64 pixel berbasis I2C

<figure><img src="/files/fEaGYo4Mk5nBeWEOa6rm" alt="" width="345"><figcaption><p>Gambar Modul OLED SSD1036 0.96inch</p></figcaption></figure>

3. Library Antares ESP HTTP. Pada dokumentasi ini menggunakan library **Antares ESP MQTT versi 1.0.**

{% hint style="info" %}
Jika anda belum menginstall **Antares ESP MQTT versi 1.0** dapat mengikuti langkah berikut.

[Antares Wi-Fi MQTT](/pendahuluan/instalasi-library-arduino/antares-wi-fi-mqtt.md)
{% endhint %}

4. Library DHT11. Pada dokumentasi ini menggunakan **DHT11 Sensor Library versi 1.4.4.**

{% hint style="info" %}
Jika Anda belum menginstall library **DHT11 Sensor Library versi 1.4.4.** dapat mengikuti langkah pada link berikut.

[DHT11 Sensor Library](/pendahuluan/instalasi-library-arduino/dht11-sensor-library.md)
{% endhint %}

5. Library OLED SSD1306. Pada dokumentasi ini menggunakan **Adafruit SSD1306 by Adafruit versi 2.5.7.**

{% hint style="info" %}
Jika Anda belum menginstall library **Adafruit SSD1306 by Adafruit versi 2.5.7.** dapat mengikuti langkah pada link berikut.

[Adafruit SSD1306](/pendahuluan/instalasi-library-arduino/adafruit-ssd1306.md)
{% endhint %}

6. Software MQTTX&#x20;

{% hint style="info" %}
Jika Anda belum menginstall **Software MQTTX** dapat mengikuti langkah pada link berikut.

[Instalasi MQTTX](/pendahuluan/instalasi-software/instalasi-mqttx.md)
{% endhint %}

## Langkah Kerja

### 1. Jalankan Aplikasi Arduino IDE

### 2. Membuka Contoh Program

{% hint style="info" %}
Kode program dapat Anda buka pada Arduino IDE melalui **File > Examples > Antares ESP HTTP > Lynx32-Simple-Project > SEND\_DATA\_RETRIEVE\_DATA\_OLED.**
{% endhint %}

Berikut adalah kode program contoh **SEND\_DATA\_RETRIEVE\_DATA\_OLED**.

```arduino
// Include necessary libraries
#include <AntaresESPMQTT.h>   // Include AntaresESP32HTTP library for Antares platform communication
#include <Adafruit_SSD1306.h>   // Include Adafruit_SSD1306 library for OLED display
#include "DHT.h"               // Include DHT library for temperature and humidity sensor

#define DHTPIN 14               // Define the pin connected to the DHT sensor
#define DHTTYPE DHT11           // Set the DHT sensor type as DHT11

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"   // Replace with the Antares application name that was created
#define deviceNameSensor "YOUR-DEVICE-NAME-1"     // Replace with the Antares device name that was created
#define deviceNameMQTT "YOUR-DEVICE-NAME-2" // Replace with your Antares device name, make sure all devices are in one application

AntaresESPMQTT antares(ACCESSKEY); // Create AntaresESP32HTTP object
DHT dht(DHTPIN, DHTTYPE);            // Create DHT object for sensor readings

#define SCREEN_WIDTH 128          // Set OLED screen width
#define SCREEN_HEIGHT 64          // Set OLED screen height
#define OLED_RESET -1             // Define OLED reset pin, not used in this case

const unsigned long interval = 5000; // Interval for sending sensor data (5 seconds)
const unsigned long interval2 = 10000; // Interval for receiving Postman data (10 seconds)
unsigned long previousMillis = 0;     // Store the last time sensor data was sent
unsigned long previousMillis2 = 0;    // Store the last time Postman data was received

String testData;             // Store received Postman data
String lastData = "";        // Store last received Postman data

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET); // Create OLED display object

bool showSensorData = true;  // Flag to control displaying sensor data

void callback(char topic[], byte payload[], unsigned int length) {
  antares.get(topic, payload, length);

  Serial.println("New Message!");
  Serial.println("Topic: " + antares.getTopic());
  Serial.println("Payload: " + antares.getPayload());

  testData = antares.getString("Test");
  Serial.println("Received: " + testData);
  if (testData!="null")
  {
    if (lastData!=testData)
    {
      lastData=testData;
      display.clearDisplay();
      display.setTextSize(1);
      display.setTextColor(SSD1306_WHITE);
      display.setCursor(0, 0);
      display.println("Received: " + testData);
      display.display();
    }
  }
}

void setup() {
  Serial.begin(115200);                 // Initialize serial communication
  antares.setDebug(true);               // Enable debugging for Antares
  antares.wifiConnection(WIFISSID, PASSWORD);
  antares.setMqttServer();
  antares.setCallback(callback);

  dht.begin();                          // Initialize DHT sensor

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Initialize OLED display
    Serial.println(F("SSD1306 allocation failed"));
    for (;;)
      ;
  }

  display.clearDisplay();               // Clear the display buffer
  display.display();                    // Display the cleared buffer
}

void loop() {
   /*
    Check if we're still connected to the MQTT broker/server.
    If disconnected, the device will try to reconnect.
   */
  antares.checkMqttConnection();
  // Send sensor data
  if (millis() - previousMillis > interval) {
    previousMillis = millis();

    float hum = dht.readHumidity();      // Read humidity from DHT sensor
    float temp = dht.readTemperature();  // Read temperature from DHT sensor

    if (isnan(hum) || isnan(temp)) {     // Check if sensor reading is valid
      Serial.println("Failed to read DHT sensor!");
      return;
    }

    // Add temperature and humidity data to the storage buffer
    antares.add("temperature", temp);
    antares.add("humidity", hum);

    // Send data from the storage buffer to Antares
    antares.publish(projectName, deviceNameSensor);

    // Display temperature and humidity on OLED
    display.clearDisplay();
    display.setTextSize(1);
    display.setTextColor(SSD1306_WHITE);
    display.setCursor(0, 0);
    display.println("Temp: " + String(temp) + " *C");
    display.println("Humidity: " + String(hum) + " %");
    display.display();
  }
  
  // Receive and display latest data
  if (millis() - previousMillis2 > interval2) {
    previousMillis2 = millis();
    antares.retrieveLastData(projectName,deviceNameMQTT);
   }
}

```

### 3. Set **Credential WiFi dan Credential Antares pada Kode Program**&#x20;

Ubah parameter Protokol HTTP pada variabel berikut **\*ACCESSKEY, \*WIFISSID, \*PASSWORD, \*projectName,** dan **\*deviceNameSensor,** dan **\*deviceNamePostman.** Sesuaikan dengan parameter di console Antares.&#x20;

```arduino
#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"          // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNamePostman "YOUR-DEVICE-NAME-2"     // Name of the device receiving data
```

{% hint style="info" %}
Parameter **\*Access key** didapat dari laman akun Antares Anda.
{% endhint %}

<figure><img src="/files/xfmf0ZwiWkeinNu95sAR" alt=""><figcaption><p>Letak Access Key di Laman Akun Antares</p></figcaption></figure>

{% hint style="info" %}
Parameter **WIFISSID** didapat dari nama **Wifi/Hotspot** yang sedang digunakan oleh Anda. contohnya pada gambar di bawah ini.
{% endhint %}

<figure><img src="/files/1YWYZS4Q2uYxH6phtARQ" alt=""><figcaption><p>WIFISSID</p></figcaption></figure>

{% hint style="info" %}
Parameter **\*PASSWORD** didapat dari **password WiFi** yang sedang anda gunakan.
{% endhint %}

{% hint style="info" %}
Parameter **\*projectName** dan **\*deviceName** didapat dari **Application Name** dan **Device Name** yang sudah dibuat dalam akun Antares.
{% endhint %}

<figure><img src="/files/XsKvcNkpTsUrGyimjxat" alt=""><figcaption><p>Tampilan Application Name</p></figcaption></figure>

<figure><img src="/files/tCr0uVbWgGv0jGAJTfVF" alt=""><figcaption><p>Tampilan Device Name</p></figcaption></figure>

### 4. Compile dan Upload Program

Hubungkan **Lynx-32** dengan komputer Anda dan pastikan **Communication Port** terbaca.

{% hint style="info" %}
Pada sistem operasi Windows pengecekan dapat dilakukan melalui **Device Manager.** Jika **Lynx-32** Anda terbaca maka tampil **USB-Serial CH340** dengan port menyesuaikan ketersediaan port (pada kasus ini terbaca **COM4**).
{% endhint %}

<figure><img src="/files/EYILW4jcOs6sMXRxmxjh" alt=""><figcaption><p>Tampilan Device Manager</p></figcaption></figure>

Atur board **ESP32** dengan klik **Tools > Board > esp32** pada Arduino IDE, kemudian pastikan yang digunakan adalah **ESP32 Dev Module.** Pilih port sesuai communication port yang terbaca (dalam kasus ini COM4). Hasilnya akan terlihat seperti gambar berikut.

<figure><img src="/files/V2G1PfRzcS6WbvsDx5S8" alt="" width="464"><figcaption><p>Tampilan Spesifikasi Board dan Port yang Digunakan</p></figcaption></figure>

Setelah semua setup selesai, lakukan upload program dengan menekan icon panah seperti gambar berikut. Tunggu hingga selesai proses compile dan upload

<figure><img src="/files/SbWGiGKiBtavySv74cfA" alt=""><figcaption><p>Ikon Compile untuk Centang dan Ikon Upload untuk Tanda Panah</p></figcaption></figure>

{% hint style="info" %}
**Icon Centang** pada Arduino IDE hanyalah proses verify. Biasanya digunakan untuk **Compile** program untuk mengetahui apakah terdapat error atau tidak .

**Icon panah** pada Arduino IDE adalah proses verify dan upload. Biasanya digunakan untuk **Compile** program sekaligus **Flash Program** pada target board.
{% endhint %}

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

<figure><img src="/files/h6QGODJTrMnmqvuFAi6e" alt=""><figcaption></figcaption></figure>

Setelah selesai upload program, Anda dapat melihat **serial monitor** untuk melakukan debug program. Icon **serial monitor** terlihat pada gambar berikut.

<figure><img src="/files/8S7xm5y59s4BMsMVKXhO" alt=""><figcaption><p>Ikon Serial Monitor</p></figcaption></figure>

Atur **serial baud rate** menjadi 115200 dan pilih BothNL & CR. Hasilnya akan terlihat seperti gambar berikut.

<figure><img src="/files/zNXEf9gAIpGGaG6s1nNO" alt=""><figcaption><p>Tampilan Serial Monitor</p></figcaption></figure>

{% hint style="danger" %}
Pastikan **serial baud rate** sesuai dengan nilai yang terdefinisi di kode program. Jika **serial baud rate** tidak sama, antara **kode program** dan **serial monitor** maka karakter ASCII tidak akan terbaca dengan baik.
{% endhint %}

### 5. **Setup Software MQTTX**

**Buka Aplikasi MQTTX, lalu pilih New Connection**

<figure><img src="/files/I8Px9gDjlPPmLaiFncxs" alt=""><figcaption><p>Membuat New Connection</p></figcaption></figure>

Agar dapat terconfigurasi antara MQTTX dengan broker Antares, sesuaikan Name, Host dan Port seperti yang ditunjukan di bawah ini, setelah itu klik Connect

<figure><img src="/files/BhRxLGdQ63X7IRxXqnRL" alt=""><figcaption><p>Antares MQTT Broker Configuration</p></figcaption></figure>

Jika sudah terkoneksi maka terdapat notifikasi seperti gambar berikut

<figure><img src="/files/FzhpoD65ttPhDgBdSweB" alt=""><figcaption><p>Antares Broker MQTTX Connected</p></figcaption></figure>

Masukan **Topic** dan **Payload** pada kolom di MQTTX.

<figure><img src="/files/7Uybrtrp00D3FlzZQkxn" alt=""><figcaption><p>Laman Topic dan Payload pada MQTTX</p></figcaption></figure>

<table><thead><tr><th width="111">Field</th><th>Value</th></tr></thead><tbody><tr><td><strong>Topic</strong></td><td><mark style="color:red;"><code>/oneM2M/req/your-access-key/antares-cse/json</code></mark></td></tr><tr><td><strong>Payload</strong></td><td><pre class="language-json"><code class="lang-json">{
      "m2m:rqp": {
        "fr": "your-access-key",
        "to": "/antares-cse/antares-id/nama-aplikasi-anda/nama-device-anda",
        "op": 1,
        "rqi": 123456,
        "pc": {
          "m2m:cin": {
            "cnf": "message",
            "con": "{\"your-first-data\":\"the-integer-value\",\"your-second-data\":\"the-string-data\"}"
          }
        },
        "ty": 4
      }
    }
</code></pre></td></tr></tbody></table>

{% hint style="info" %}
Sesuaikan <mark style="color:red;">your-access-key</mark>, <mark style="color:red;">nama-aplikasi-anda</mark>, dan <mark style="color:red;">nama-device-anda</mark> sesuai nama-nama yang terdaftar pada akun Antares Anda. Isikan pula "Field" data dan "Nilai" data pada "con" sesuai yang Anda inginkan.
{% endhint %}

Pada software MQTTX masukan Topic dan Payload yang ingin digunakan. Kemudian klik Publish untuk mengirimkan pesan dari MQTTX ke server Antares.&#x20;

<figure><img src="/files/lDekytsV5B5Su1tkVam4" alt=""><figcaption><p>Publish untuk mengirim pesan ke server Antares</p></figcaption></figure>

### **6. Mengirim Pesan MQTTX ke Server Antares**

Setelah setup software MQTTX selesai, saatnya mengirimkan perintah PUBLISH. Pada field "Test" diisi dengan string "Hallo Antares" sebagai pesan yang akan dikirim melalui protokol MQTT ke server Antares.&#x20;

```json
{
      "m2m:rqp": {
        "fr": "your-access-key",
        "to": "/antares-cse/antares-id/nama-aplikasi-anda/nama-device-anda",
        "op": 1,
        "rqi": 123456,
        "pc": {
          "m2m:cin": {
            "cnf": "message",
            "con": "{\"Test\":\"Hallo Antares\"}"
          }
        },
        "ty": 4
      }
    }
```

Jika sudah selesai mengisi field "Test" selanjutnya tekan tombol **Publish** pada software MQTTX, seperti pada gambar berikut.

<figure><img src="/files/pD9Y4D2BrygIXLdTLd6D" alt=""><figcaption><p>Gambar isi Payload MQTTX</p></figcaption></figure>

Jika sudah publish maka laman MQTTX akan terdapat Message seperti berikut.

<figure><img src="/files/azXc6lIl1OXgqvYyQwQe" alt=""><figcaption><p>Notifikasi Message Published</p></figcaption></figure>

### 7. Periksa Data di Antares

Setelah upload program berhasil, selanjutnya buka halaman device antares kemudian lihat apakah data sudah berhasil dikirim.

<figure><img src="/files/qfFj3EtZyhENJTzWWOhw" alt=""><figcaption><p>Gambar Halaman Console Antares Ketika Data Berhasil Diterima dari MQTTX. </p></figcaption></figure>

<figure><img src="/files/x7mdm1pBORkLckmnnUUC" alt=""><figcaption><p>Gambar Halaman Console Antares Ketika Data Berhasil Diterima dari Sensor DHT11.</p></figcaption></figure>

{% hint style="info" %}
Data yang diterima oleh **LYNX-32** dengan protokol MQTT berupa variabel Test Data.
{% endhint %}

### 8. Melihat Pesan Retrieve&#x20;

Retrieve data dari **Antares IoT Platform** dan ditampilkan pada display OLED setelah terhubung ke Wi-Fi tertampil pada gambar dibawah ini:

<figure><img src="/files/EP0mgzaLRIaMg8Y5kjFq" alt=""><figcaption></figcaption></figure>

<figure><img src="/files/1NNf3vbXQ8HTzJLBAyRp" alt=""><figcaption></figcaption></figure>


---

# Agent Instructions: Querying This Documentation

If you need additional information that is not directly available in this page, you can query the documentation dynamically by asking a question.

Perform an HTTP GET request on the current page URL with the `ask` query parameter:

```
GET https://docs.antares.id/contoh-kode-dan-library/esp32-wi-fi/esp32-wi-fi-protokol-mqtt/project-sederhana-lynx-32-mqtt-antares/send-data-dht-11-dan-retrieve-data-ditampilkan-pada-display-oled.md?ask=<question>
```

The question should be specific, self-contained, and written in natural language.
The response will contain a direct answer to the question and relevant excerpts and sources from the documentation.

Use this mechanism when the answer is not explicitly present in the current page, you need clarification or additional context, or you want to retrieve related documentation sections.