# Uplink Data DHT11 Secara Periodik

***

## Pendahuluan

Pada project ini, anda akan menggunakan **Shield Workshop Antares** pada modul **Development Board Lynx-32** **Antares**. Pada **Shield Workshop Antares** ini terdapat sensor suhu, kelembapan (DHT11), relay, LED dan push button. Anda akan melakukan monitoring suhu dan kelembapan sesuai periode interval yang ditentukan. Hasil data yang dikirim oleh sensor dapat anda pantau melalui console Antares**.**

<figure><img src="https://content.gitbook.com/content/rRkxjRLeqOm0pNhLfsus/blobs/ENmSheCahg2yBrCd9p3I/Uplink%20Data%20DHT11%20Secara%20Periodik.png" alt=""><figcaption><p>Gambar Ilustrasi Project</p></figcaption></figure>

## Prasyarat

Material yang dibutuhkan mengikuti dengan **Prasyarat Umum** pada laman sebelumnya. Jika anda belum menyiapkan kebutuhan pada laman tersebut, maka anda dapat mengunjungi laman berikut.

{% content-ref url="../prasyarat-umum-esp32-lora" %}
[prasyarat-umum-esp32-lora](https://docs.antares.id/contoh-kode-dan-library/esp32-lora/prasyarat-umum-esp32-lora)
{% endcontent-ref %}

Adapun tambahan material yang spesifik untuk project ini adalah sebagai berikut.

1. Shield Workshop Antares

<figure><img src="https://content.gitbook.com/content/rRkxjRLeqOm0pNhLfsus/blobs/m6EIO4aK8DAyPeEK3mrP/workshop%20shield.png" alt=""><figcaption><p>Gambar Development Board Lynx-32 beserta Shield Workshop Antares.</p></figcaption></figure>

2. Library DHT11. Pada dokumentasi ini menggunakan **DHT11 Sensor Library versi 1.4.4.**

{% hint style="info" %}
Jika anda belum menginstall library **DHT11 Sensor Library versi 1.4.4** dapat mengikuti langkah pada link berikut.

[dht11-sensor-library](https://docs.antares.id/pendahuluan/instalasi-library-arduino/dht11-sensor-library "mention")
{% endhint %}

## Langkah Kerja

### 1. Jalankan Aplikasi Arduino IDE

### 2. Membuka Contoh Program

{% tabs %}
{% tab title="Class A" %}
{% hint style="info" %}
Kode program dapat anda buka pada Arduino IDE melalui **File > Examples > Antares LoRaWAN >  Lynx32-Simple-Project** > **Class A > UPLINK\_DHT11\_CLASS\_A.**
{% endhint %}

Berikut adalah kode program dari contoh **UPLINK\_DHT11\_CLASS\_A.**

```arduino
#include <lorawan.h>
#include "DHT.h"

#define DHTTYPE  DHT11
#define SENSOR_DHT  14

DHT dht(SENSOR_DHT, DHTTYPE);
//ABP Credentials
/*
  Notes:
  - select ABP Activation on ANTARES
  - select inherit to generate your keys
  - nwkSKey: 32 digit hex, you can put 16 first digits by first 16 digits your access key and add 16 digits with 0 (ex : abcdef01234567890000000000000000)
  - appSKey: 32 digit hex, put 16 first digits by 0 and put last 16 digits by last 16 digit your access key (ex : 0000000000000000abcdef0123456789)
*/
const char *devAddr = "Lora-Device-Address"; // Replace with the Device Address that you have in the Antares console
const char *nwkSKey = "Network-Session-Key"; // Replace with the Network Session Key that you have in the Antares console
const char *appSKey = "Application-Session-Key"; // Replace with the Application Session Key that you have in the Antares console

const unsigned long interval = 60000;    // 60 s interval to send message
unsigned long previousMillis = 0;  // will store last time message sent
unsigned int counter = 0;     // message counter
String dataSend = "";

char myStr[50];
char outStr[255];
byte recvStatus = 0;
int channel;

const sRFM_pins RFM_pins = {
  .CS = 5,    //LYNX32 to RFM NSS
  .RST = 0,   //LYNX32 to RFM RST
  .DIO0 = 27, //LYNX32 to RFM DIO0
  .DIO1 = 2,  //LYNX32 to RFM DIO1
};

// get temperature and humidity from DHT11
float getTemperature()
{
  float t = dht.readTemperature();
  if (isnan(t)) return 0;
  return t;
}

float getHumidity()
{
  float h = dht.readHumidity();
  if (isnan(h)) return 0;
  return h;
}

void setup() {
  // Setup loraid access
  Serial.begin(115200);
  dht.begin();

  delay(2000);
  if (!lora.init()) {
    Serial.println("RFM95 not detected");
    delay(5000);
    return;
  }

  // Set LoRaWAN Class change CLASS_A or CLASS_C
  lora.setDeviceClass(CLASS_A);

  // Set Data Rate
  lora.setDataRate(SF10BW125);

  // set channel to random
  lora.setChannel(MULTI);

  // Set TxPower to 15 dBi (max)
  lora.setTxPower1(15);

  // Put ABP Key and DevAddress here
  lora.setNwkSKey(nwkSKey);
  lora.setAppSKey(appSKey);
  lora.setDevAddr(devAddr);
}

void loop() {
  // Check interval overflow
  if (millis() - previousMillis > interval) {
    previousMillis = millis();

    int t, h;
    t = getTemperature();
    h = getHumidity();
    Serial.println("Temperature : " + (String)t + " C");
    Serial.println("Humidity    : " + (String)h + " %");

    dataSend = "{\"Temp\": " + (String)t + ", \"Humd\": " + (String)h + "}";
    dataSend.toCharArray(myStr, 50);

    Serial.print("Sending : ");
    Serial.println(dataSend);

    lora.sendUplink(myStr, strlen(myStr), 0, 5);
    channel = lora.getChannel();
    Serial.print(F("Ch : "));    Serial.print(channel); Serial.println(" ");
  }

  // Check Lora RX
  lora.update();

  recvStatus = lora.readData(outStr);
  if (recvStatus) {
    int counter = 0;

    for (int i = 0; i < recvStatus; i++)
    {
      if (((outStr[i] >= 32) && (outStr[i] <= 126)) || (outStr[i] == 10) || (outStr[i] == 13))
        counter++;
    }
    if (counter == recvStatus)
    {
      Serial.print(F("Received String : "));
      for (int i = 0; i < recvStatus; i++)
      {
        Serial.print(char(outStr[i]));
      }
    }
    else
    {
      Serial.print(F("Received Hex : "));
      for (int i = 0; i < recvStatus; i++)
      {
        Serial.print(outStr[i], HEX); Serial.print(" ");
      }
    }
    Serial.println();
  }

}
```

{% endtab %}

{% tab title="Class C" %}
{% hint style="info" %}
Kode program dapat anda buka pada Arduino IDE melalui **File > Examples > Antares LoRaWAN >  Lynx32-Simple-Project** > **Class C > UPLINK\_DHT11\_CLASS\_C.**
{% endhint %}

Berikut adalah kode program dari contoh **UPLINK\_DHT11\_CLASS\_C.**

```arduino
#include <lorawan.h>
#include "DHT.h"

#define DHTTYPE  DHT11
#define SENSOR_DHT  14

DHT dht(SENSOR_DHT, DHTTYPE);
//ABP Credentials
/*
  Notes:
  - select ABP Activation on ANTARES
  - select inherit to generate your keys
  - nwkSKey: 32 digit hex, you can put 16 first digits by first 16 digits your access key and add 16 digits with 0 (ex : abcdef01234567890000000000000000)
  - appSKey: 32 digit hex, put 16 first digits by 0 and put last 16 digits by last 16 digit your access key (ex : 0000000000000000abcdef0123456789)
*/
const char *devAddr = "Lora-Device-Address"; // Replace with the Device Address that you have in the Antares console
const char *nwkSKey = "Network-Session-Key"; // Replace with the Network Session Key that you have in the Antares console
const char *appSKey = "Application-Session-Key"; // Replace with the Application Session Key that you have in the Antares console

const unsigned long interval = 60000;    // 60 s interval to send message
unsigned long previousMillis = 0;  // will store last time message sent
unsigned int counter = 0;     // message counter
String dataSend = "";

char myStr[50];
char outStr[255];
byte recvStatus = 0;
int channel;

const sRFM_pins RFM_pins = {
  .CS = 5,    //LYNX32 to RFM NSS
  .RST = 0,   //LYNX32 to RFM RST
  .DIO0 = 27, //LYNX32 to RFM DIO0
  .DIO1 = 2,  //LYNX32 to RFM DIO1
};

// get temperature and humidity from DHT11
float getTemperature()
{
  float t = dht.readTemperature();
  if (isnan(t)) return 0;
  return t;
}

float getHumidity()
{
  float h = dht.readHumidity();
  if (isnan(h)) return 0;
  return h;
}

void setup() {
  // Setup loraid access
  Serial.begin(115200);
  dht.begin();

  delay(2000);
  if (!lora.init()) {
    Serial.println("RFM95 not detected");
    delay(5000);
    return;
  }

  // Set LoRaWAN Class change CLASS_A or CLASS_C
  lora.setDeviceClass(CLASS_C);

  // Set Data Rate
  lora.setDataRate(SF10BW125);

  // set channel to random
  lora.setChannel(MULTI);

  // Set TxPower to 15 dBi (max)
  lora.setTxPower1(15);

  // Put ABP Key and DevAddress here
  lora.setNwkSKey(nwkSKey);
  lora.setAppSKey(appSKey);
  lora.setDevAddr(devAddr);
}

void loop() {
  // Check interval overflow
  if (millis() - previousMillis > interval) {
    previousMillis = millis();

    int t, h;
    t = getTemperature();
    h = getHumidity();
    Serial.println("Temperature : " + (String)t + " C");
    Serial.println("Humidity    : " + (String)h + " %");

    dataSend = "{\"Temp\": " + (String)t + ", \"Humd\": " + (String)h + "}";
    dataSend.toCharArray(myStr, 50);

    Serial.print("Sending : ");
    Serial.println(dataSend);

    lora.sendUplink(myStr, strlen(myStr), 0, 5);
    channel = lora.getChannel();
    Serial.print(F("Ch : "));    Serial.print(channel); Serial.println(" ");
  }

  // Check Lora RX
  lora.update();

  recvStatus = lora.readData(outStr);
  if (recvStatus) {
    int counter = 0;

    for (int i = 0; i < recvStatus; i++)
    {
      if (((outStr[i] >= 32) && (outStr[i] <= 126)) || (outStr[i] == 10) || (outStr[i] == 13))
        counter++;
    }
    if (counter == recvStatus)
    {
      Serial.print(F("Received String : "));
      for (int i = 0; i < recvStatus; i++)
      {
        Serial.print(char(outStr[i]));
      }
    }
    else
    {
      Serial.print(F("Received Hex : "));
      for (int i = 0; i < recvStatus; i++)
      {
        Serial.print(outStr[i], HEX); Serial.print(" ");
      }
    }
    Serial.println();
  }

}
```

{% endtab %}
{% endtabs %}

### 3. Set LoRaWAN Parameter di Antares

Pada halaman Device console Antares lakukan Set LoRa dengan menekan button **Set LoRa** seperti gambar berikut.

<figure><img src="https://3995702122-files.gitbook.io/~/files/v0/b/gitbook-x-prod.appspot.com/o/spaces%2FrRkxjRLeqOm0pNhLfsus%2Fuploads%2FsyprxAyDcgBPEI5NPcPK%2Fsetlora%201.png?alt=media&#x26;token=e49c923b-be8e-4f78-8587-3004b6f99a37" alt=""><figcaption><p>Gambar Halaman Console Antares untuk Set LoRa.</p></figcaption></figure>

{% tabs %}
{% tab title="Class A" %}
Masukan parameter LoRaWAN dengan **Lora Device Class A, Activation Mode ABP, ABP Parameters Inherit** seperti pada gambar berikut.

{% hint style="info" %}
Ketika memilih **ABP Parameters Inherit** maka parameter LoRa akan digenerate oleh Antares. Dari sisi perangkat, **Development Board Lynx32** perlu menyesuaikan parameter LoRa tersebut.
{% endhint %}

{% hint style="warning" %}
Jangan lupa untuk menyimpan **(copy)** parameter **Network Session Key** dan **Application Session Key** sebelum klik **Set LoRa** untuk memudahkan proses selanjutnya.
{% endhint %}

<figure><img src="https://content.gitbook.com/content/rRkxjRLeqOm0pNhLfsus/blobs/RWESRt60bfuG1IZVAlYG/kotak%20setlora.png" alt=""><figcaption><p>Gambar Form berisi Parameter Set LoRa Class A.</p></figcaption></figure>

{% hint style="danger" %}
Pastikan akun antares anda memiliki paket LoRa yang aktif.
{% endhint %}
{% endtab %}

{% tab title="Class C" %}
Masukan parameter LoRaWAN dengan **Lora Device Class C, Activation Mode ABP, ABP Parameters Inherit** seperti pada gambar berikut.

{% hint style="info" %}
Ketika memilih **ABP Parameters Inherit** maka parameter LoRa akan digenerate oleh Antares. Dari sisi perangkat, **Development Board Lynx32** perlu menyesuaikan parameter LoRa tersebut.
{% endhint %}

{% hint style="warning" %}
Jangan lupa untuk menyimpan **(copy)** parameter **Network Session Key** dan **Application Session Key** sebelum klik **Set LoRa** untuk memudahkan proses selanjutnya.
{% endhint %}

<figure><img src="https://content.gitbook.com/content/rRkxjRLeqOm0pNhLfsus/blobs/IjkpN1mMpV2lvjXP6tVX/CLASS%20C%20kotak%20setlora.png" alt=""><figcaption><p>Gambar Form berisi Parameter Set LoRa Class C.</p></figcaption></figure>

{% hint style="danger" %}
Pastikan akun antares anda memiliki paket LoRa yang aktif.
{% endhint %}
{% endtab %}
{% endtabs %}

### 4. Set LoRaWAN Parameter pada Kode Program

Ubah parameter LoRaWAN ABP pada variabel berikut **`*devAddr`** , **`*nwkSkey`** , dan **`*appSKey`**. Sesuaikan dengan parameter di console Antares.

```arduino
const char *devAddr = "Lora-Device-Address";
const char *nwkSKey = "Network-Session-Key";
const char *appSKey = "Application-Session-Key"
```

{% hint style="info" %}
Parameter **\*devAddr** yang telah digenerate oleh Antares dapat dilihat pada halaman device setelah selesai **Set LoRa.**
{% endhint %}

{% hint style="info" %}
Parameter **\*nwkSKey**  dan **\*appSKey** didapatkan saat **Set LoRa** pada langkah sebelumnya.
{% endhint %}

<figure><img src="https://3995702122-files.gitbook.io/~/files/v0/b/gitbook-x-prod.appspot.com/o/spaces%2FrRkxjRLeqOm0pNhLfsus%2Fuploads%2FWT02gmg7U0lzwd8GsWr7%2Fsetlora%202.png?alt=media&#x26;token=fe83472e-cb98-4754-ad82-c5ff4a598140" alt=""><figcaption><p>Gambar Halaman Console Antares Setelah berhasil Set LoRa.</p></figcaption></figure>

{% hint style="danger" %}
Jika anda lupa menyimpan \***nwkSkey** dan **\*appSKey** pada langkah sebelumnya maka lihat accesskey pada akun antares anda kemudian ikuti format berikut.

{% code overflow="wrap" %}

```arduino
Example Accesskey = "aaaaaaaaaaaaaaaa:bbbbbbbbbbbbbbbb"; //32 digit accesskey

const char *nwkSKey = "aaaaaaaaaaaaaaaa0000000000000000"; //16 digit first accesskey plus 16 digit zero

const char *appSKey = "0000000000000000bbbbbbbbbbbbbbbb"; //16 digit zero plus 16 digit last acesskey
```

{% endcode %}
{% endhint %}

### 5. Compile dan Upload Program

Hubungkan **Development Board Lynx-32**  dengan komputer anda dan pastikan **Communication Port** terbaca.

{% hint style="info" %}
Pada sistem operasi Windows pengecekan dapat dilakukan melalui **Device Manager.**&#x20;

Jika **Development Board Lynx-32** anda terbaca maka akan tampil **USB-Serial CH340** dengan port menyesuaikan ketersediaan port (pada kasus ini terbaca **COM4**).
{% endhint %}

<figure><img src="https://content.gitbook.com/content/rRkxjRLeqOm0pNhLfsus/blobs/XAiXBxxXUFVX8swfWA0c/comport.png" alt=""><figcaption><p>Gambar Device Manager pada Windows.</p></figcaption></figure>

Atur Board **Lynx-32** dengan klik **Tools > Board > ESP32 Arduino** pada Arduino IDE, kemudian pastikan board yang digunakan adalah **ESP32 Dev Module.** Pilih port sesuai communicaion port yang terbaca (dalam kasus ini COM4). Hasilnya akan terlihat seperti gambar berikut.

<figure><img src="https://content.gitbook.com/content/rRkxjRLeqOm0pNhLfsus/blobs/bHXMy9BOpFxKNI2exOhW/4_Board%20Setup.png" alt=""><figcaption><p>Gambar Menu Tools pada Arduino IDE.</p></figcaption></figure>

Setelah semua setup selesai, lakukan upload program dengan menekan icon panah seperti gambar berikut. Tunggu hingga selesai proses compile dan upload.

<figure><img src="https://content.gitbook.com/content/rRkxjRLeqOm0pNhLfsus/blobs/gNBqwRJL1J1RIMyPYhob/5_Upload%20and%20Compile.png" alt=""><figcaption><p>Gambar Icon Verify and Upload pada Arduino IDE.</p></figcaption></figure>

{% hint style="info" %}
**Icon Centang** pada Arduino IDE hanyalah proses verify. Biasanya digunakan untuk **Compile** program untuk mengetahui apakah terdapat error atau tidak.

**Icon Panah** pada Arduino IDE adalah proses verify and upload. Biasanya digunakan untuk **Compile** program sekaligus **Flash program** kedalam target board.
{% endhint %}

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

<figure><img src="https://content.gitbook.com/content/rRkxjRLeqOm0pNhLfsus/blobs/0OF6UAOfhw7B3CfQNRLa/doneupload.png" alt=""><figcaption><p>Gambar Halaman Arduino IDE Setelah Upload berhasil.</p></figcaption></figure>

Setelah selesai upload program, anda dapat melihat **serial monitor** untuk melakukan debug program. Icon **serial monitor** terlihat seperti pada gambar berikut.

<figure><img src="https://content.gitbook.com/content/rRkxjRLeqOm0pNhLfsus/blobs/weQ7rgplDgbBvpcC2gNR/8_Serial%20Monitor.png" alt=""><figcaption><p>Gambar Icon Serial Monitor pada Arduino IDE.</p></figcaption></figure>

Atur **serial baud rate** menjadi 115200 dan pilih **BothNL & CR**. Hasilnya akan terlihat seperti gambar berikut.

<figure><img src="https://content.gitbook.com/content/rRkxjRLeqOm0pNhLfsus/blobs/5edbRb1iad5GNSQO0nlO/9_Serial%20Communication.png" alt=""><figcaption><p>Gambar Serial Monitor.</p></figcaption></figure>

{% hint style="danger" %}
Pastikan **serial baud rate** sesuai dengan nilai yang terdefinisi di kode program. Jika **serial baud rate** tidak sama, antara **kode program** dan **serial monitor** maka karakter ASCII tidak akan terbaca dengan baik.
{% endhint %}

### 6. Periksa Data di Antares

Setelah upload program berhasil, selanjutnya buka halaman device antares kemudian lihat apakah data lora sudah berhasil dikirim.&#x20;

<figure><img src="https://3995702122-files.gitbook.io/~/files/v0/b/gitbook-x-prod.appspot.com/o/spaces%2FrRkxjRLeqOm0pNhLfsus%2Fuploads%2FPpGKZZOStJo8M4fxDfy2%2F153.png?alt=media&#x26;token=197809ca-fd50-435f-8312-2f7a2b383240" alt=""><figcaption></figcaption></figure>

<figure><img src="https://3995702122-files.gitbook.io/~/files/v0/b/gitbook-x-prod.appspot.com/o/spaces%2FrRkxjRLeqOm0pNhLfsus%2Fuploads%2FNXTn87qoKqiIzoKDAuvn%2F154.png?alt=media&#x26;token=63799d65-021d-4f30-a4f6-16634388092c" alt=""><figcaption><p>Gambar Halaman Console Antares Ketika Data LoRa Berhasil Diterima.</p></figcaption></figure>

Bentuk data yang diterima oleh antares akan berbentuk JSON seperti format berikut.

{% hint style="info" %}
Data yang dikirimkan dari **Development Board Lynx-32** berupa **`"counter"`**, **`"port"`**, dan pesan yang berada didalam JSON field **`"data"`**. Hasil pemantauan suhu DHT11 berada di dalam JSON field **`"data"`** yang didalamnya terdapat field **`"Temp"`** dan **`"Humd"`**. Sementara parameter lainnya adalah parameter pendukung yang dihasilkan oleh Infrastruktur LoRaWAN Antares.
{% endhint %}