Uplink Data DHT11 dengan Push Button

---

In this project, you will use the Antares Workshop Shield on the Lynx-32 Development Board module. In this Antares Shield Workshop, there are temperature, humidity (DHT11), relay, LED and push button sensors. You will monitor the temperature and humidity according to the specified interval period. The results of the data sent by the sensors can be monitored through the Antares console.

Image of Development Board Lynx-32 and Shield Workshop Antares.

Prerequisites

The materials required follow the General Prerequisites on the previous page. If you have not prepared the requirements on that page, then you can visit the following page.

General Prerequisites ESP32 LoRa

The additional materials specific to this project are as follows.

1. Shield Workshop Antares

2. DHT11 Library. This documentation uses DHT11 Sensor Library version 1.4.4.

If you have not installed the DHT11 Sensor Library version 1.4.4, you can follow the steps at the following link.

DHT11 Sensor Library

Follow These Steps

1. Launch the Arduino IDE application

2. Opening Sample Programme

Class A

You can open the programme code in the Arduino IDE via File > Examples > Antares LoRaWAN > Lynx32-Simple-Project > Class A > UPLINK_DHT11_PUSHBUTTON_CLASS_A.

The following is the programme code of the UPLINK_DHT11_PUSHBUTTON_CLASS_A example.

#include <lorawan.h>
#include "DHT.h"

#define DHTTYPE  DHT11
#define SENSOR_DHT  14
#define pushButtonPin 32
#define ledPin 12

DHT dht(SENSOR_DHT, DHTTYPE);
bool ledState = false;
bool lastButtonState = false;

//ABP Credentials
/*
  Notes:
  - select ABP Activation on ANTARES
  - select inherit to generate your keys
  - nwkSKey: 32 digit hex, you can put 16 first digits by first 16 digits your access key and add 16 digits with 0 (ex : abcdef01234567890000000000000000)
  - appSKey: 32 digit hex, put 16 first digits by 0 and put last 16 digits by last 16 digit your access key (ex : 0000000000000000abcdef0123456789)
*/
const char *devAddr = "Lora-Device-Address"; // Replace with the Device Address that you have in the Antares console
const char *nwkSKey = "Network-Session-Key"; // Replace with the Network Session Key that you have in the Antares console
const char *appSKey = "Application-Session-Key"; // Replace with the Application Session Key that you have in the Antares console

char myStr[50];
char outStr[255];
byte recvStatus = 0;
int channel;

const sRFM_pins RFM_pins = {
  .CS = 5,    //LYNX32 to RFM NSS
  .RST = 0,   //LYNX32 to RFM RST
  .DIO0 = 27, //LYNX32 to RFM DIO0
  .DIO1 = 2,  //LYNX32 to RFM DIO1
};

// get temperature and humidity from DHT11
float getTemperature()
{
  float t = dht.readTemperature();
  if (isnan(t)) return 0;
  return t;
}

float getHumidity()
{
  float h = dht.readHumidity();
  if (isnan(h)) return 0;
  return h;
}

void setup() {
  // Setup loraid access
  Serial.begin(115200);
  dht.begin();
  pinMode(pushButtonPin, INPUT_PULLUP);
  pinMode(ledPin, OUTPUT);
  digitalWrite(ledPin, LOW);

  delay(2000);
  if (!lora.init()) {
    Serial.println("RFM95 not detected");
    delay(5000);
    return;
  }

  // Set LoRaWAN Class change CLASS_A or CLASS_C
  lora.setDeviceClass(CLASS_A);

  // Set Data Rate
  lora.setDataRate(SF10BW125);

  // set channel to random
  lora.setChannel(MULTI);

  // Set TxPower to 15 dBi (max)
  lora.setTxPower1(15);

  // Put ABP Key and DevAddress here
  lora.setNwkSKey(nwkSKey);
  lora.setAppSKey(appSKey);
  lora.setDevAddr(devAddr);
}

void loop() {
  bool currentButtonState = digitalRead(pushButtonPin);


  // only toggle the LED if the new button state is HIGH
  if (currentButtonState != lastButtonState && currentButtonState == LOW)
  {
    Serial.println("The button is pressed");
    int t, h;
    t = getTemperature();
    h = getHumidity();
    Serial.println("Temperature : " + (String)t + " C");
    Serial.println("Humidity    : " + (String)h + " %");

    // Turn on the LED as an indicator
    digitalWrite(ledPin, HIGH);

    String dataSend = "{\"Temp\": " + (String)t + ", \"Humd\": " + (String)h + "}";
    dataSend.toCharArray(myStr, 50);

    Serial.print("Sending : ");
    Serial.println(dataSend);

    lora.sendUplink(myStr, strlen(myStr), 0, 5);
    channel = lora.getChannel();
    Serial.print(F("Ch : "));    Serial.print(channel); Serial.println(" ");

    // Delay to avoid multiple uplinks due to button debouncing
    delay(1000);

    // Turn off the LED after sending the uplink
    digitalWrite(ledPin, LOW);
  }
  // save the reading. Next time through the loop, it'll be the lastButtonState:
  lastButtonState = currentButtonState;


  // Check Lora RX
  lora.update();

  recvStatus = lora.readData(outStr);
  if (recvStatus) {
    int counter = 0;

    for (int i = 0; i < recvStatus; i++)
    {
      if (((outStr[i] >= 32) && (outStr[i] <= 126)) || (outStr[i] == 10) || (outStr[i] == 13))
        counter++;
    }
    if (counter == recvStatus)
    {
      Serial.print(F("Received String : "));
      for (int i = 0; i < recvStatus; i++)
      {
        Serial.print(char(outStr[i]));
      }
    }
    else
    {
      Serial.print(F("Received Hex : "));
      for (int i = 0; i < recvStatus; i++)
      {
        Serial.print(outStr[i], HEX); Serial.print(" ");
      }
    }
    Serial.println();
  }

}

Class C

3. Set LoRaWAN Parameters in Antares

On the Antares Device console page, set the LoRa by pressing the Set LoRa button as shown below.

Image of the Antares Console Page for LoRa Set.

Class A

Input LoRaWAN parameters with Lora Device Class A, Activation Mode ABP, ABP Parameters Inherit as shown below.

When selecting ABP Parameters Inherit, the LoRa parameters will be generated by Antares. From the device side, the Lynx32 Development Board needs to adjust the LoRa parameters.

Don't forget to save (copy) the Network Session Key and Application Session Key parameters before clicking Set LoRa to facilitate the next process.

The Form image contains the LoRa Class A Parameter Set.

Make sure your antares account has an active LoRa package.

Class C

4. Set LoRaWAN Parameters in Programme Code

Change the LoRaWAN ABP parameters in the following variables *devAddr , *nwkSkey and *appSKey. Adjust to the parameters in the Antares console.

const char *devAddr = "Lora-Device-Address";
const char *nwkSKey = "Network-Session-Key";
const char *appSKey = "Application-Session-Key"

The *devAddr parameter that has been generated by Antares can be seen on the device page after completing the LoRa Set.

The parameters *nwkSKey and *appSKey are obtained during Set LoRa in the previous step.

Figure Antares Console Page After successful LoRa Set

Jika anda lupa menyimpan *nwkSkey dan *appSKey pada langkah sebelumnya maka lihat accesskey pada akun antares anda kemudian ikuti format berikut.

Example Accesskey = "aaaaaaaaaaaaaaaa:bbbbbbbbbbbbbbbb"; //32 digit accesskey

const char *nwkSKey = "aaaaaaaaaaaaaaaa0000000000000000"; //16 digit first accesskey plus 16 digit zero

const char *appSKey = "0000000000000000bbbbbbbbbbbbbbbb"; //16 digit zero plus 16 digit last acesskey

5. Compile and Upload Program

Connect the Lynx-32 Development Board to your computer and make sure the Communication Port is read.

On Windows operating systems the check can be done via Device Manager. If your Lynx-32 Development Board is read, the USB-Serial CH340 will appear with the port adjusting the port availability (in this case it reads COM4).

Device Manager Display

Set up the Lynx-32 Board by clicking Tools > Board > ESP32 Arduino in the Arduino IDE, then make sure the board used is the ESP32 Dev Module. Select the port according to the communicaion port that is read (in this case COM4). The result will look like the following picture.

Image of the Tools Menu in the Arduino IDE.

After all the setup is complete, upload the programme by pressing the arrow icon as shown below. Wait for the compile and upload process to finish.

Image of the Verify and Upload Icon in the Arduino IDE.

The Tick icon on the Arduino IDE is just the verify process. Usually used to Compile the programme to find out whether there are errors or not. The Arrow icon on the Arduino IDE is the verify and upload process. Usually used to Compile the programme as well as Flash the programme to the target board.

If the programme upload is successful, it will look like the following image.

Arduino IDE page image after successful upload.

After uploading the programme, you can view the serial monitor to debug the programme. The serial monitor icon is shown in the following image.

Image of the Serial Monitor Icon in the Arduino IDE.

Set the serial baud rate to 115200 and select BothNL & CR. The result will look like the following image.

Serial Monitor Image

Make sure the serial baud rate matches the value defined in the programme code. If the serial baud rate is not the same between the programme code and the serial monitor, the ASCII characters will not be read properly.

6. Check Data in Antares

After uploading the programme successfully, then open the device antares page and see if the lora data has been successfully sent.

Image of the Antares Console Page When LoRa Data is Successfully Received.

The data sent from the Lynx-32 Development Board is in the form of "counter", "port", and message in the JSON field "data". DHT11 temperature monitoring results are in the JSON field "data" which includes the fields "Temp" and "Humd". While other parameters are supporting parameters generated by the LoRaWAN Antares Infrastructure.