Send DHT 11 data and display on OLED display

In this project, you will use the Antares Shield Workshop on the ESP8266 module. In this Antares Shield Workshop, there are temperature, humidity (DHT11), relay, LED and push button sensors. You will monitor the temperature and humidity according to the specified interval period. The results of the data sent by the sensor can be monitored through the Antares console and displayed on the OLED.

Image of WEMOS D1R2 Installed Antares Shield and OLED.

Prerequisites

The materials required follow the General Prerequisites on the previous page. If you have not prepared the requirements on that page, then you can visit the following page.

General Prerequisites ESP8266 Wi-Fi

The additional materials specific to this project are as follows.

1. Shield Workshop Antares

2. I2C-based 0.96inch 128x64 pixel SSD1036 OLED module

SSD1036 0.96inch OLED Module Picture

1. Antares ESP MQTT Library. This documentation uses the Antares ESP MQTT library version 1.0.

If you have not installed Antares ESP MQTT version 1.0, you can follow these steps.

Antares Wi-Fi MQTT

1. DHT11 Library. This documentation uses DHT11 Sensor Library version 1.4.4.

If you have not installed the DHT11 Sensor Library version 1.4.4. you can follow the steps in the following link.

DHT11 Sensor Library

1. SSD1306 OLED Library. This documentation uses Adafruit SSD1306 by Adafruit version 2.5.7.

If you have not installed the Adafruit SSD1306 by Adafruit library version 2.5.7. you can follow the steps in the following link.

Adafruit SSD1306

Follow These Steps

1. Launch the Arduino IDE application

2. Opening Sample Programme

You can open the programme code in the Arduino IDE via File > Example > Antares ESP HTTP > ESP8266-Simple-Project > SEND_DATA_DHT11_OLED.

Below is the programme code of the SEND_DATA_DHT11_OLED example.

// Library initialization
#include <AntaresESPMQTT.h>    // Library initiation for Antares ESP8266 MQTT
#include "DHT.h"               // Load DHT sensor library for reading temperature and humidity
#include <Adafruit_SSD1306.h>  // Load OLED display library

#define DHTPIN D1         // Define DHTPIN variable, pointing to pin D1
#define DHTTYPE DHT11     // Set DHT type to DHT11
#define SCREEN_WIDTH 128  // Define OLED screen width
#define SCREEN_HEIGHT 64  // Define OLED screen height

#define OLED_RESET -1        // Define OLED reset pin, set to -1 as it's not used
#define SCREEN_ADDRESS 0x3C  // Define OLED I2C address

#define ACCESSKEY "YOUR-ACCESS-KEY"    // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"      // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"  // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"  // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"        // Replace with the Antares device name that was created

const unsigned long interval = 10000;  // 10 s interval to send message
unsigned long previousMillis = 0;      // will store last time message sent

AntaresESPMQTT antares(ACCESSKEY);                                         // Create an antares object for connecting to Antares
DHT dht(DHTPIN, DHTTYPE);                                                  // Create a dht object for the DHT sensor
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);  // Create a display object for the OLED screen

void setup() {
  Serial.begin(115200);                        // Initialize serial communication with baudrate 115200
  antares.setDebug(true);                      // Turn on debug mode. Set to "false" if you don't want messages to appear in the serial monitor
  antares.wifiConnection(WIFISSID, PASSWORD);  // Attempt to connect to Wi-Fi with the specified SSID and password
  antares.setMqttServer();
  dht.begin();  // Initialize the DHT sensor object

  if (!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));  // Check if the OLED is successfully initialized
    for (;;)
      ;
  }
  display.clearDisplay();                        // Clear the OLED display
  display.setTextColor(SSD1306_WHITE);           // Set text color to white
  display.setTextSize(1);                        // Set text size to 1
  display.setCursor(0, 0);                       // Set cursor position to (0, 0)
  display.println(F("Temperature & Humidity"));  // Display "Temperature & Humidity" text on the OLED
  display.display();                             // Show the text on the OLED
  delay(2000);                                   // Delay for 2 seconds
}

void loop() {
  antares.checkMqttConnection();
  // Check interval overflow
  if (millis() - previousMillis > interval) {
    previousMillis = millis();

    float hum = dht.readHumidity();                  // Read humidity value from the DHT sensor
    float temp = dht.readTemperature();              // Read temperature value from the DHT sensor
    if (isnan(hum) || isnan(temp)) {                 // Check if the sensor reading is invalid
      Serial.println("Failed to read DHT sensor!");  // If the reading is invalid, print an error message
      return;                                        // Exit the loop function and wait for the next cycle
    }
    display.clearDisplay();             // Clear the OLED display
    display.setTextSize(1);             // Set text size to 1
    display.setCursor(0, 0);            // Set cursor position to (0, 0)
    display.print(F("Temperature: "));  // Display "Temperature: " text on the OLED
    display.print(temp);                // Display temperature value on the OLED
    display.println(F(" C"));           // Display " C" (for Celsius) on the OLED
    display.print(F("Humidity: "));     // Display "Humidity: " text on the OLED
    display.print(hum);                 // Display humidity value on the OLED
    display.println(F(" %"));           // Display " %" (for percentage) on the OLED
    display.display();                  // Show the text on the OLED

    Serial.println("Temperature: " + (String)temp + " *C");  // Print temperature value to the serial monitor with "*C" format
    Serial.println("Humidity: " + (String)hum + " %");       // Print humidity value to the serial monitor with "%" format

    // Add variable data to the storage buffer in Antares
    antares.add("temperature", temp);
    antares.add("humidity", hum);

    // Send data from the storage buffer to Antares
    antares.publish(projectName, deviceName);
  }
}

3. Set WiFi Credential and Antares Credential in Program Code

Change the HTTP Protocol parameters in the following variables *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, and *deviceName. Adjust to the parameters in the Antares console.

#define ACCESSKEY "your-access-key" // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid" // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password" // Replace with your Wi-Fi password

#define projectName "your-project-name"   // Antares project name
#define deviceName "YOUR-DEVICE-NAME-"    // Antares device name

The *Access key parameter is obtained from your Antares account page.

Access Key Location on Antares Account Page

The WIFISSID parameter is obtained from the name of the Wifi / Hotspot that is currently being used by you. for example in the image below.

The WiFi SSID being used.

The *PASSWORD parameter is obtained from the WiFi password you are currently using.

The parameters *projectName and *deviceName are obtained from the Application Name and Device Name that have been created in the Antares account.

Application Name Display

Tampilan Device Name

4. Compile and Upload Program

Connect the ESP8266 WEMOS D1R2 with your computer and make sure the Communication Port is read.

On Windows operating systems, checking can be done via Device Manager. If your ESP8266 WEMOS D1R2 is read, the USB-Serial CH340 appears with the port adjusting the port availability (in this case it reads COM4).

Device Manager image on Windows.

Set up the ESP8266 WEMOS D1R2 board by clicking Tools > Board > esp8266 in the Arduino IDE, then make sure the one used is LOLIN (WEMOS) D1 R2 & mini. Select the port according to the communication port that is read (in this case COM4). The result will look like the following picture.

Image of Tools Menu on Arduino IDE

After all the setup is complete, upload the programme by pressing the arrow icon as shown below. Wait for the compile and upload process to finish.

Image of the Verify and Upload icons in the Arduino IDE.

The Tick icon on the Arduino IDE is just the verify process. Usually used to Compile the programme to find out whether there are errors or not. The Arrow icon on the Arduino IDE is the verify and upload process. Usually used to Compile the programme as well as Flash the programme to the target board.

If the programme upload is successful, it will look like the following image.

Arduino IDE page image after successful upload.

After uploading the programme, you can view the serial monitor to debug the programme. The serial monitor icon is shown in the following image.

Image of the Serial Monitor Icon in the Arduino IDE.

Set the serial baud rate to 115200 and select BothNL & CR. The result will look like the following image.

Make sure the serial baud rate matches the value defined in the programme code. If the serial baud rate is not the same between the programme code and the serial monitor, the ASCII characters will not be read properly.

Serial Monitor Image

5. Check Data in Antares

After uploading the programme successfully, then open the device antares page and see if the data has been successfully sent.

Data sent from ESP8266 with HTTP protocol in the form of temperature and humidity variables.

6. Output program

DHT 11 data sent and displayed on the OLED display after connecting to Wi-Fi is shown in the figure below:

DHT11 sensor results displayed on OLED