DHT 11 Send Data and Retrieve Data displayed on OLED Display

In this project, you will use the Antares Shield Workshop on the ESP8266 module. In this Antares Shield Workshop, there are temperature, humidity (DHT11), relay, LED, and push button sensors. You will monitor the temperature and humidity with a specified interval period. The results of the data sent by the sensors can be monitored through the Antares console and displayed on the OLED. You can also send messages in the form of string data displayed on the OLED display. This data transmission process uses MQTTX software to send data to the Antares IoT Platform.

Prerequisites

The materials required follow the General Prerequisites on the previous page. If you have not prepared the requirements on that page, then you can visit the following page.

General Prerequisites ESP8266 Wi-Fi

The additional materials specific to this project are as follows.

Shield Workshop Antares
I2C-based 0.96inch 128x64 pixel SSD1036 OLED module

Antares ESP MQTT Library. This documentation uses the Antares ESP MQTT library version 1.0.

If you have not installed Antares ESP MQTT version 1.0, you can follow these steps.

Antares Wi-Fi MQTT

OLED display library. This documentation uses Adafruit_SSD1306 by Adafruit version 2.5.7.

If you have not installed the Adafruit SSD1306 by Adafruit library version 2.5.7. you can follow the steps in the following link.

DHT11 Library. This documentation uses DHT11 Sensor Library version 1.4.4.

If you have not installed the DHT11 Sensor Library version 1.4.4. you can follow the steps in the following link.

DHT11 Sensor Library

MQTTX Software

If you have not installed the MQTTX Software, you can follow the steps in the following link.

MQTTX Installation

Follow These Steps

1. Launch the Arduino IDE application

2. Opening Sample Programme

You can open the programme code in the Arduino IDE via File > Example > Antares ESP HTTP > ESP8266-Simple-Project > POST_DATA_GET_DATA_OLED.

Below is the programme code of the POST_DATA_DHT11_OLED example.

// Include necessary libraries
#include <AntaresESPMQTT.h>   // Include AntaresESP8266HTTP library for Antares platform communication
#include <Adafruit_SSD1306.h>   // Include Adafruit_SSD1306 library for OLED display
#include "DHT.h"               // Include DHT library for temperature and humidity sensor

#define DHTPIN D1               // Define the pin connected to the DHT sensor
#define DHTTYPE DHT11           // Set the DHT sensor type as DHT11

#define ACCESSKEY "your-access-key" // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid" // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password" // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"     // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNameMQTT "YOUR-DEVICE-NAME-2"  // Name of the device receiving data

AntaresESPMQTT antares(ACCESSKEY); // Create AntaresESP8266HTTP object
DHT dht(DHTPIN, DHTTYPE);            // Create DHT object for sensor readings

#define SCREEN_WIDTH 128          // Set OLED screen width
#define SCREEN_HEIGHT 64          // Set OLED screen height
#define OLED_RESET -1             // Define OLED reset pin, not used in this case

const unsigned long interval = 5000; // Interval for sending sensor data (5 seconds)
const unsigned long interval2 = 10000; // Interval for receiving Postman data (10 seconds)
unsigned long previousMillis = 0;     // Store the last time sensor data was sent
unsigned long previousMillis2 = 0;    // Store the last time Postman data was received

String testData;             // Store received Postman data
String lastData = "";        // Store last received Postman data

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET); // Create OLED display object

bool showSensorData = true;  // Flag to control displaying sensor data

void callback(char topic[], byte payload[], unsigned int length) {
  antares.get(topic, payload, length);

  Serial.println("New Message!");
  Serial.println("Topic: " + antares.getTopic());
  Serial.println("Payload: " + antares.getPayload());

  testData = antares.getString("Test");
  Serial.println("Received: " + testData);
  if (testData!="null")
  {
    if (lastData!=testData)
    {
      lastData=testData;
      display.clearDisplay();
      display.setTextSize(1);
      display.setTextColor(SSD1306_WHITE);
      display.setCursor(0, 0);
      display.println("Received: " + testData);
      display.display();
    }
  }
}

void setup() {
  Serial.begin(115200);                 // Initialize serial communication
  antares.setDebug(true);               // Enable debugging for Antares
  antares.wifiConnection(WIFISSID, PASSWORD);
  antares.setMqttServer();
  antares.setCallback(callback);

  dht.begin();                          // Initialize DHT sensor

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Initialize OLED display
    Serial.println(F("SSD1306 allocation failed"));
    for (;;)
      ;
  }

  display.clearDisplay();               // Clear the display buffer
  display.display();                    // Display the cleared buffer
}

void loop() {
   /*
    Check if we're still connected to the MQTT broker/server.
    If disconnected, the device will try to reconnect.
   */
  antares.checkMqttConnection();
  // Send sensor data
  if (millis() - previousMillis > interval) {
    previousMillis = millis();

    float hum = dht.readHumidity();      // Read humidity from DHT sensor
    float temp = dht.readTemperature();  // Read temperature from DHT sensor

    if (isnan(hum) || isnan(temp)) {     // Check if sensor reading is valid
      Serial.println("Failed to read DHT sensor!");
      return;
    }

    // Add temperature and humidity data to the storage buffer
    antares.add("temperature", temp);
    antares.add("humidity", hum);

    // Send data from the storage buffer to Antares
    antares.publish(projectName, deviceNameSensor);

    // Display temperature and humidity on OLED
    display.clearDisplay();
    display.setTextSize(1);
    display.setTextColor(SSD1306_WHITE);
    display.setCursor(0, 0);
    display.println("Temp: " + String(temp) + " *C");
    display.println("Humidity: " + String(hum) + " %");
    display.display();
  }
  
  // Receive and display latest data
  if (millis() - previousMillis2 > interval2) {
    previousMillis2 = millis();
    antares.retrieveLastData(projectName,deviceNameMQTT);
   }
}

3.Set WiFi Credential and Antares Credential in Program Code

Change the HTTP Protocol parameters in the following variables *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, and *deviceName. Adjust to the parameters in the Antares console.

This project requires 2 devices, namely a device to receive data from DHT11 and a device to receive data from MQTTX made in one application on the Antares console.

#define ACCESSKEY "your-access-key" // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid" // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password" // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"     // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNameMQTT "YOUR-DEVICE-NAME-2"  // Name of the device receiving data

The *Access key parameter is obtained from your Antares account page.

The WIFISSID parameter is obtained from the name of the Wifi / Hotspot that is currently being used by you. for example in the image below.

The *PASSWORD parameter is obtained from the WiFi password you are currently using.

The parameters *projectName and *deviceName are obtained from the Application Name and Device Name that have been created in the Antares account.

4. Compile and Upload Program

Connect the ESP8266 WEMOS D1R2 with your computer and make sure the Communication Port is read.

On Windows operating systems, checking can be done via Device Manager. If your ESP8266 WEMOS D1R2 is read, the USB-Serial CH340 appears with the port adjusting the port availability (in this case it reads COM4).

Set up the ESP8266 WEMOS D1R2 board by clicking Tools > Board > esp8266 in the Arduino IDE, then make sure the one used is LOLIN (WEMOS) D1 R2 & mini. Select the port according to the communication port that is read (in this case COM4). The result will look like the following picture.

After all the setup is complete, upload the programme by pressing the arrow icon as shown below. Wait for the compile and upload process to finish.

The Tick icon on the Arduino IDE is just the verify process. Usually used to Compile the programme to find out whether there are errors or not. The Arrow icon on the Arduino IDE is the verify and upload process. Usually used to Compile the programme as well as Flash the programme to the target board.

If the programme upload is successful, it will look like the following image.

After uploading the programme, you can view the serial monitor to debug the programme. The serial monitor icon is shown in the following image.

Set the serial baud rate to 115200 and select BothNL & CR. The result will look like the following image.

Make sure the serial baud rate matches the value defined in the programme code. If the serial baud rate is not the same between the programme code and the serial monitor, the ASCII characters will not be read properly.

5. MQTTX Software Setup

Open the MQTTX App, then select New Connection.

In order to configure MQTTX with Antares broker, adjust the Name, Host and Port as shown below, then click Connect.

If it is connected, there is a notification as shown below.

To publish to the Antares server, enter Topic and Payload in the fields in MQTTX.

Field

Value

Topic

/oneM2M/req/your-access-key/antares-cse/json

Payload

{
      "m2m:rqp": {
        "fr": "your-access-key",
        "to": "/antares-cse/antares-id/nama-aplikasi-anda/nama-device-anda",
        "op": 1,
        "rqi": 123456,
        "pc": {
          "m2m:cin": {
            "cnf": "message",
            "con": "{\"your-first-data\":\"the-integer-value\",\"your-second-data\":\"the-string-data\"}"
          }
        },
        "ty": 4
      }
    }

Customise your-access-key, your-application-name, and your-device-name to the names registered to your Antares account. Fill in the "Field" data and "Value" data in "con" as you wish.

In the MQTTX software, enter the Topic and Payload that you want to use. Then click Publish to send the message from MQTTX to the Antares server.

6. Sending MQTTX Messages to Antares Server

After the MQTTX software setup is complete, it's time to send the PUBLISH command. The "Test" field is filled with the string "Hello Antares" as the message that will be sent via the MQTT protocol to the Antares server.

{
      "m2m:rqp": {
        "fr": "your-access-key",
        "to": "/antares-cse/antares-id/nama-aplikasi-anda/nama-device-anda",
        "op": 1,
        "rqi": 123456,
        "pc": {
          "m2m:cin": {
            "cnf": "message",
            "con": "{\"Test\":\"Hallo Antares\"}"
          }
        },
        "ty": 4
      }
    }

If you have finished filling in the "Test" field, then press the Publish button on the MQTTX software, as shown below.

If it has been published, the MQTTX page will have a message like the following.

7. Check Data in Antares

After uploading the programme successfully, then open the device antares page and see if the data has been successfully sent.

The data received by ESP8266 with the MQTT protocol is in the form of Test Data variables.

8. Output program

Send and Retrieve data from the Antares IoT Platform and display on the OLED display after connecting to Wi-Fi is shown in the figure below:

PreviousRetrieve Data displayed on OLED Display NextControlling Relays and LEDs Through Get Commands

Last updated 1 year ago