Send Data DHT 11 dengan Push Button

In this project, you will use the Antares Workshop Shield on the Lynx-32 Development Board module. In this Antares Shield Workshop, there are temperature, humidity (DHT11), relay, LED and push button sensors. You will monitor the temperature and humidity according to the specified interval period. The results of the data sent by the sensors can be monitored through the Antares console.

Prerequisites

The materials required follow the General Prerequisites on the previous page. If you have not prepared the requirements on that page, then you can visit the following page.

General Prerequisites ESP32 Wi-Fi

The additional materials specific to this project are as follows.

1. Shield Workshop Antares

2. Antares ESP HTTP Library. This documentation uses the Antares ESP MQTT library version 1.0.

If you have not installed Antares ESP MQTT version 1.0, you can follow these steps.

Antares Wi-Fi MQTT

1. DHT11 Library. This documentation uses DHT11 Sensor Library version 1.4.4.

If you have not installed the DHT11 Sensor Library version 1.4.4. you can follow the steps in the following link.

DHT11 Sensor Library

Follow These Steps

1. Launch the Arduino IDE application

2. Opening Sample Programme

Kode program dapat Anda buka pada Arduino IDE melalui File > Examples > Antares ESP MQTT > Lynx32-Simple-Project > SEND_DATA_DHT11_PUSHBUTTON.

The following is the SEND_DATA_DHT11_PUSHBUTTON example programme code.

// Include necessary libraries
#include <AntaresESPMQTT.h> // Library initiation for Antares ESP32 MQTT
#include "DHT.h"               // Include the DHT sensor library

#define DHTPIN 14              // Define the pin number for the DHT sensor (connected to pin 14)
#define DHTTYPE DHT11          // Define the DHT sensor type as DHT11

#define pushButtonPin 32         // Define the pin number for the push button (connected to pin 32)
#define ledPin  12                // Define the pin number for the LED (connected to pin 12)

#define ACCESSKEY "YOUR-ACCESS-KEY"  // Replace with your Antares access key
#define WIFISSID "YOUR-WIFI-SSID"      // Replace with your WiFi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"  // Replace with your WiFi password

#define projectName "YOUR-APPLICATION-NAME"   // Replace with your Antares application name
#define deviceName "YOUR-DEVICE-NAME"         // Replace with your Antares device name

AntaresESPMQTT antares(ACCESSKEY);    // Create an object for interacting with Antares
DHT dht(DHTPIN, DHTTYPE);             // Create a DHT object for the DHT sensor

bool ledState = false;                // Variable to store the state of the LED (ON or OFF)
bool lastButtonState = false;         // Variable to store the previous state of the push button

void setup() {
  Serial.begin(115200);     // Initialize serial communication with baudrate 115200
  antares.setDebug(true);   // Enable debug mode for AntaresESP32HTTP (messages will be displayed in the serial monitor)
  antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to Wi-Fi with the specified SSID and password
  antares.setMqttServer();
  dht.begin();             // Initialize the DHT sensor

  pinMode(pushButtonPin, INPUT_PULLUP);  // Set the push button pin as input with internal pull-up resistor
  pinMode(ledPin, OUTPUT);               // Set the LED pin as output
  digitalWrite(ledPin, LOW);             // Turn off the LED initially
}

void loop() {
  antares.checkMqttConnection();
  // Read the current state of the push button
  bool currentButtonState = digitalRead(pushButtonPin);

  // Check if the button state has changed (button press detected)
  if (currentButtonState != lastButtonState && currentButtonState == LOW) {
    Serial.println("The button is pressed");

    // Toggle state of the LED (ON to OFF or OFF to ON)
    ledState = !ledState;
    digitalWrite(ledPin, ledState);

    // Read temperature and humidity from the DHT sensor
    float hum = dht.readHumidity();
    float temp = dht.readTemperature();

    // Check if the sensor reading is valid
    if (isnan(hum) || isnan(temp)) {
      Serial.println("Failed to read DHT sensor!");
      return;
    }

    // Print temperature and humidity values to the serial monitor
    Serial.println("Temperature: " + (String)temp + " *C");
    Serial.println("Humidity: " + (String)hum + " %");

    // Add temperature and humidity data to the Antares storage buffer
    antares.add("temperature", temp);
    antares.add("humidity", hum);

    // Send the data from the storage buffer to Antares
    antares.publish(projectName, deviceName);

    // Add some delay to avoid multiple data sending due to button debouncing
    delay(1000);
  }

  // Update the last button state for the next iteration
  lastButtonState = currentButtonState;
}

3. Set MQTT Parameters in Programme Code

Change the HTTP Protocol parameters in the following variables *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, and *deviceName. Adjust to the parameters in the Antares console.

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"   // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"     // Replace with the Antares device name that was created

The *Access key parameter is obtained from your Antares account page.

Access Key Location on Antares Account Page

The WIFISSID parameter is obtained from the Wi-Fi/Hotspot name that will be used by the Lynx-32 Development Board. An example is shown below.

WIFISSID

The *PASSWORD parameter is obtained from the Wi-Fi password you are currently using.

The parameters *projectName and *deviceName are obtained from the Application Name and Device Name that have been created in the Antares account.

Application Name Display

Device Name Display

4. Compile and Upload Program

Connect the Lynx-32 with your computer and make sure the Communication Port is read.

On Windows operating systems the check can be done via Device Manager. If your Lynx-32 is read then the USB-Serial CH340 appears with the port adjusting the port availability (in this case it reads COM4).

Device Manager Display

Set up the ESP32 board by clicking Tools > Board > esp32 in the Arduino IDE, then make sure the ESP32 Dev Module is used. Select the port according to the communication port that is read (in this case COM4). The result will look like the following image.

Display of Board Specifications and Ports Used

After all the setup is complete, upload the programme by pressing the arrow icon as shown below. Wait for the compile and upload process to finish

Compile Icon for Tick and Upload Icon for Arrow

The Tick icon on the Arduino IDE is just the verify process. Usually used to Compile the programme to find out whether there are errors or not. The Arrow icon on the Arduino IDE is the verify and upload process. Usually used to Compile the programme as well as Flash the programme to the target board.

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

Arduino IDE page image after successful upload.

After uploading the programme, you can view the serial monitor to debug the programme. The serial monitor icon is shown in the following image.

Serial Monitor Icon

Set the serial baud rate to 115200 and select BothNL & CR. The result will look like the following image.

Serial Monitor Display

Make sure the serial baud rate matches the value defined in the programme code. If the serial baud rate is not the same between the programme code and the serial monitor, the ASCII characters will not be read properly.

5.Check Data in Antares

After uploading the programme successfully, then open the device antares page and see if the data has been successfully sent.

Antares Console Display

Data sent from the Lynx-32 Development Board with the MQTT protocol in the form of temperature and humidity variables.