# Post and Get DHT 11 Data displayed on OLED

In this project, you will use the **Antares Shield Workshop** on the **ESP8266** module. In this **Antares Shield Workshop**, there are temperature, humidity (DHT11), relay, LED, and push button sensors. You will monitor the temperature and humidity with a specified interval period. The results of the data sent by the sensors can be monitored through the Antares console and displayed on the **OLED**. You can also send messages in the form of **string data** displayed on the **OLED** display. This data transmission process uses POSTMAN software to send data to the Antares IoT Platform.<br>

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/6iKmSgvL4LKRCAwlN6f3/BoardESP8266+SHIELD+OLED.jpeg" alt="" width="563"><figcaption><p>Image of WEMOS D1R2 Displaying DHT11 Data</p></figcaption></figure>

## Prerequisites

The materials required follow the **General Prerequisites** on the previous page. If you have not prepared the requirements on that page, then you can visit the following page.

{% content-ref url="../../general-prerequisites-esp8266-wi-fi" %}
[general-prerequisites-esp8266-wi-fi](https://docs.antares.id/en/code-and-library-examples/esp8266-wi-fi/general-prerequisites-esp8266-wi-fi)
{% endcontent-ref %}

The additional materials specific to this project are as follows.

1. Shield Workshop Antares
2. I2C-based 0.96inch 128x64 pixel SSD1036 OLED module

   <figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/yukHhJmqDEnF3wQNR3ty/OLED.jpeg" alt="" width="345"><figcaption><p>SSD1036 0.96inch OLED Module Picture</p></figcaption></figure>
3. Antares ESP HTTP Library. This documentation uses the **Antares ESP HTTP library version 1.4.0.**

{% hint style="info" %}
If you have not installed **Antares ESP HTTP 1.4.0**, please follow these steps.

[antares-wi-fi-http](https://docs.antares.id/en/getting-started/arduino-library-installation/antares-wi-fi-http "mention")
{% endhint %}

4. &#x20;OLED display library. This documentation uses Adafruit\_SSD1306 by **Adafruit version 2.5.7.**

{% hint style="info" %}
If you have not installed the **Adafruit SSD1306 by Adafruit library version 2.5.7.** you can follow the steps in the following link.

[adafruit-ssd1306](https://docs.antares.id/en/getting-started/arduino-library-installation/adafruit-ssd1306 "mention")
{% endhint %}

5. DHT11 Library. This documentation uses **DHT11 Sensor Library version 1.4.4.**

{% hint style="info" %}
If you have not installed the **DHT11 Sensor Library version 1.4.4**. you can follow the steps in the following link.

[dht11-sensor-library](https://docs.antares.id/en/getting-started/arduino-library-installation/dht11-sensor-library "mention")
{% endhint %}

6. POSTMAN SOFTWARE

{% hint style="info" %}
If you have not installed **POSTMAN Software**, you can follow the steps in the following link.

[postman-installation](https://docs.antares.id/en/getting-started/software-installation/postman-installation "mention")
{% endhint %}

## Follow These Steps

### **1.** Launch the Arduino IDE application

### **2.** Opening Sample Programme&#x20;

{% hint style="info" %}
You can open the programme code in the Arduino IDE via **File > Example > Antares ESP HTTP > ESP8266-Simple-Project > GET\_DATA\_OLED.**
{% endhint %}

Here is the programme code of the **GET\_DATA\_OLED** example.

```cpp
#include <AntaresESPHTTP.h>    // Include the AntaresESP8266HTTP library
#include <Adafruit_SSD1306.h>  // Include the Adafruit SSD1306 library
#include "DHT.h"               // Include the DHT sensor library

#define DHTPIN D1      // Digital pin connected to the DHT sensor
#define DHTTYPE DHT11  // Type of DHT sensor (DHT11 in this case)

#define ACCESSKEY "YOUR-ACCESS-KEY"    // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"      // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"  // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"     // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNamePostman "YOUR-DEVICE-NAME-2"  // Name of the device receiving data

AntaresESPHTTP antares(ACCESSKEY);  // Initialize AntaresESP8266HTTP with the access key
DHT dht(DHTPIN, DHTTYPE);           // Initialize DHT sensor object

#define SCREEN_WIDTH 128  // OLED screen width in pixels
#define SCREEN_HEIGHT 64  // OLED screen height in pixels
#define OLED_RESET -1     // Reset pin for the OLED (not used in this case)

const unsigned long interval = 5000;    // Interval to send sensor data (5 seconds)
const unsigned long interval2 = 10000;  // Interval to get data from Antares (10 seconds)
unsigned long previousMillis = 0;       // Store the last time sensor data was sent
unsigned long previousMillis2 = 0;      // Store the last time data was received from Antares

String testData;       // String to hold received data from Antares
String lastData = "";  // String to store last received data

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);  // Initialize OLED display object

bool showSensorData = true;  // Boolean to control display of sensor data

void setup() {
  Serial.begin(115200);                        // Initialize serial communication
  antares.setDebug(true);                      // Enable Antares library debug mode
  antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to WiFi using provided SSID and password
  dht.begin();                                 // Initialize the DHT sensor

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {  // Initialize the OLED display
    Serial.println(F("SSD1306 allocation failed"));
    for (;;)
      ;
  }

  display.clearDisplay();  // Clear the OLED display buffer
  display.display();       // Display the cleared buffer
}

void loop() {

  if (millis() - previousMillis > interval) {  // Check if it's time to send sensor data
    previousMillis = millis();                 // Update the last sent time

    float hum = dht.readHumidity();      // Read humidity from the DHT sensor
    float temp = dht.readTemperature();  // Read temperature from the DHT sensor
    if (isnan(hum) || isnan(temp)) {
      Serial.println("Failed to read DHT sensor!");  // Print an error message if sensor reading fails
      return;
    }
    antares.add("temperature", temp);                    // Add temperature data to the Antares payload
    antares.add("humidity", hum);                        // Add humidity data to the Antares payload
    antares.send(projectName, deviceNameSensor);         // Send sensor data to Antares
    display.clearDisplay();                              // Clear the OLED display buffer
    display.setTextSize(1);                              // Set text size on the display
    display.setTextColor(SSD1306_WHITE);                 // Set text color to white
    display.setCursor(0, 0);                             // Set cursor position on the display
    display.println("Temp: " + String(temp) + " *C");    // Display temperature
    display.println("Humidity: " + String(hum) + " %");  // Display humidity
    display.display();                                   // Display the updated buffer on the OLED
  }

  if (millis() - previousMillis2 > interval2) {  // Check if it's time to get data from Antares
    previousMillis2 = millis();                  // Update the last received time

    antares.get(projectName, deviceNamePostman);  // Get data from Antares

    if (antares.getSuccess()) {                   // Check if data retrieval was successful
      testData = antares.getString("Test Data");  // Get the "Test Data" field from the response

      if (lastData != testData)  // Check if the received data is different from the last one
      {
        lastData = testData;                           // Update the last received data
        Serial.println("Received Data: " + testData);  // Print received data to the serial monitor
        display.clearDisplay();                        // Clear the OLED display buffer
        display.setTextSize(1);                        // Set text size on the display
        display.setTextColor(SSD1306_WHITE);           // Set text color to white
        display.setCursor(0, 0);                       // Set cursor position on the display
        display.println("Received:");                  // Display "Received:"
        display.println(testData);                     // Display the received data
        display.display();                             // Display the updated buffer on the OLED
        delay(2000);                                   // Display received data for 2 seconds
      }
    }
  }
}
```

### **3.** Set WiFi Credential and Antares Credential in Program Code

Change the HTTP Protocol parameters in the following variables **\*ACCESSKEY, \*WIFISSID, \*PASSWORD, \*projectName**, and **\*deviceName**. Adjust to the parameters in the Antares console.

{% hint style="info" %}
This project requires 2 devices, namely a device in Antares to receive data from DHT11 with the variable name deviceNameSensor and a device to receive data from POSTMAN with the variable name deviceNamePostman made in one application on the Antares console.
{% endhint %}

```cpp
#define ACCESSKEY "your-access-key" // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid" // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password" // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"     // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNamePostman "YOUR-DEVICE-NAME-2"  // Name of the device receiving data
```

{% hint style="info" %}
The **\*Access key** parameter is obtained from your Antares account page.
{% endhint %}

<figure><img src="https://3873791589-files.gitbook.io/~/files/v0/b/gitbook-x-prod.appspot.com/o/spaces%2F7cujmJ5QHdJaAjH815aZ%2Fuploads%2FOY1G0gpCFv9QxGHjoSJZ%2Fimage.png?alt=media&#x26;token=6d672266-7b0f-4c32-9bfa-7c84d4a9fbc0" alt=""><figcaption><p>Access Key Location on Antares Account Page</p></figcaption></figure>

{% hint style="info" %}
The **WIFISSID** parameter is obtained from the name of the **Wifi / Hotspot** that is currently being used by you. for example in the image below.
{% endhint %}

<div align="center" data-full-width="true"><figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/rbEUpQFGMxxAlsbhx80l/WIFI%20SSID.jpeg" alt="" width="375"><figcaption><p>The WiFi SSID being used.</p></figcaption></figure></div>

{% hint style="info" %}
The **\*PASSWORD** parameter is obtained from the **WiFi password** you are currently using.
{% endhint %}

{% hint style="info" %}
The parameters **\*projectName, \*deviceNameSensor, \*deviceNamePostman** are obtained from the **Application Name** and **Device Name** that have been created in the Antares account. This project requires two device names so you must create two new devices as shown below.
{% endhint %}

<figure><img src="https://3873791589-files.gitbook.io/~/files/v0/b/gitbook-x-prod.appspot.com/o/spaces%2F7cujmJ5QHdJaAjH815aZ%2Fuploads%2FGOxXv0CnPWoHxdkXvvdb%2Fimage.png?alt=media&#x26;token=2ff3c443-094a-482a-b18a-2c11f855ec5e" alt=""><figcaption><p>Application Name and Device Name on the Antares page.</p></figcaption></figure>

### **4. Compile dan Upload Program**

Connect the **ESP8266 WEMOS D1R2** with your computer and make sure the **Communication Port** is read.

{% hint style="info" %}
On Windows operating systems, checking can be done via **Device Manager**. If your **ESP8266 WEMOS D1R2** is read, the **USB-Serial CH340** appears with the port adjusting the port availability (in this case it reads **COM4**).
{% endhint %}

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/fcfcdEElfdAfcfnsotd3/Device%20Manager%20Windows.jpeg" alt=""><figcaption><p>Device Manager image on Windows.</p></figcaption></figure>

Set up the **ESP8266 WEMOS D1R2** board by clicking **Tools > Board > esp8266** in the Arduino IDE, then make sure the one used is **LOLIN (WEMOS) D1 R2 & mini**. Select the port according to the communication port that is read (in this case COM4). The result will look like the following picture.

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/3DGOyZL4YMBe2p0gfBEE/Menu%20Tools%20Arduino%20IDE.jpeg" alt="" width="563"><figcaption><p>Image of Tools Menu on Arduino IDE</p></figcaption></figure>

After all the setup is complete, upload the programme by pressing the arrow icon as shown below. Wait for the compile and upload process to finish.

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/7F0snCGF0w1VsDAHsEOf/Icon%20Verify%20dan%20Upload%20pada%20Arduino%20IDE.jpeg" alt=""><figcaption><p>Image of the Verify and Upload icons in the Arduino IDE.</p></figcaption></figure>

{% hint style="info" %}
**The Tick icon** on the Arduino IDE is just the verify process. Usually used to **Compile** the programme to find out whether there are errors or not.&#x20;

**The Arrow icon** on the Arduino IDE is the verify and upload process. Usually used to **Compile** the programme as well as Flash the programme to the target board.
{% endhint %}

If the programme upload is successful, it will look like the following image.

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/xJJW0O6EgD0yvDmkwf1N/Halaman%20Arduino%20IDE%20Setelah%20Upload%20Berhasil.jpeg" alt=""><figcaption><p>Arduino IDE page image after successful upload.</p></figcaption></figure>

After uploading the programme, you can view the **serial monitor** to debug the programme. The **serial monitor** icon is shown in the following image.

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/E54RxnSDN15dXSK6ANie/Icon%20Serial%20Monitor%20pada%20Arduino%20IDE.jpeg" alt=""><figcaption><p>Image of the Serial Monitor Icon in the Arduino IDE.</p></figcaption></figure>

Set the **serial baud rate** to 115200 and select BothNL & CR. The result will look like the following image.

{% hint style="danger" %}
Make sure the **serial baud rate** matches the value defined in the programme code. If the **serial baud rate** is not the same between the **programme code** and the **serial monitor**, the ASCII characters will not be read properly.
{% endhint %}

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/LQvVW6AIKpcSh7gj4yuB/Serial%20Monitor%20POST&#x26;GET%20HTTP.jpeg" alt=""><figcaption><p>Serial Monitor Image</p></figcaption></figure>

### **5. Setup POSTMAN Software**

In this step you need POSTMAN software, you can input the **end-point, request header** and **request** body first by following the following format.

**End Point**&#x20;

<table data-header-hidden><thead><tr><th width="134.5"></th><th></th></tr></thead><tbody><tr><td><strong>Method</strong></td><td>POST</td></tr><tr><td><strong>URL</strong></td><td>https://platform.antares.id:8443/~/antares-cse/antares-id/<mark style="color:red;">your-application-name/your-device-name</mark></td></tr></tbody></table>

{% hint style="info" %}
Customise <mark style="color:red;">your-application-name</mark> and <mark style="color:red;">your-device-name</mark> to the names registered to your Antares account.
{% endhint %}

**Request Header**

<table data-header-hidden><thead><tr><th width="134.5"></th><th></th></tr></thead><tbody><tr><td><strong>Key</strong></td><td><strong>Value</strong></td></tr><tr><td>X-M2M-Origin</td><td><mark style="color:red;">your-access-key</mark></td></tr><tr><td>Content-Type</td><td>application/json;ty=4</td></tr><tr><td>Accept</td><td>application/json</td></tr></tbody></table>

{% hint style="info" %}
Customise <mark style="color:red;">your-access-key</mark> with your Antares account access key.
{% endhint %}

The result will be as shown below.

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/7p87ee4RDHN5micRaC2h/POSTMAN%201.png" alt=""><figcaption><p>Image of end-point and header settings in POSTMAN software.</p></figcaption></figure>

Next, you need to input the request body by following the following format.

**Request Body**

```json
{
  "m2m:cin": {
    "con": "{\"key1\":\"integer-value\", \"key2\":\"string-value\", \"keyN\":\"valueN\"}"
  }
}
```

In the POSTMAN software, select the **Body** tab then select **raw** and enter the payload according to the request body you want to use as shown below.

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/gCm9rHiAXIzQI32ZKM3I/POSTMAN2.png" alt=""><figcaption><p>Image of the contents of the payload request body in POSTMAN software.</p></figcaption></figure>

{% hint style="info" %}
Customise the contents of the "con" field according to the "key" and "value" you want to send.
{% endhint %}

### **6.** Sending POSTMAN Messages to the Antares Server

After the POSTMAN software setup is complete, it's time to send the POST command. The "Test Data" field is filled with the string "Hello TEST 123" as the message to be sent via HTTP protocol to the Antares server.

```json
{
  "m2m:cin": {
    "con": "{\"Test Data\":\"Hallo TEST 123\"}"
  }
}
```

If you have finished filling in the "Test Data" field, then press the **Send** button on the POSTMAN software. It looks like the following picture.

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/bLDk28P5rnq6R17QvvBq/Gambar%20isi%20pesan%20pada%20software%20POSTMAN.jpeg" alt=""><figcaption><p>Image of the message content in POSTMAN software.</p></figcaption></figure>

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/jxDivnoxoEWbeYUyD3Cw/Gambar%20response%20hit%20API%20pada%20software%20POSTMAN..jpeg" alt=""><figcaption><p>Image of API hit response in POSTMAN software.</p></figcaption></figure>

### **7.** Check Data in Antares

After uploading the programme successfully, then open the device antares page and see if the data has been successfully sent.

<figure><img src="https://3873791589-files.gitbook.io/~/files/v0/b/gitbook-x-prod.appspot.com/o/spaces%2F7cujmJ5QHdJaAjH815aZ%2Fuploads%2FOs4RhOOdaQhuk6DbaU6S%2Fimage.png?alt=media&#x26;token=3e2ecd92-4f74-46cb-a1ac-36283444f368" alt=""><figcaption><p>Image of the Antares Console Page when data is successfully received from the DHT11 Sensor.</p></figcaption></figure>

<figure><img src="https://3873791589-files.gitbook.io/~/files/v0/b/gitbook-x-prod.appspot.com/o/spaces%2F7cujmJ5QHdJaAjH815aZ%2Fuploads%2FibonMS85vwQVCncbYyr1%2Fimage.png?alt=media&#x26;token=c8be6602-27cb-4288-b006-d496e3cd7d6e" alt=""><figcaption><p>Image of the Antares Console Page when data is successfully received from POSTMAN.</p></figcaption></figure>

### 8. Output program&#x20;

Get data from the **Antares IoT Platform** and display it on the OLED display after connecting to Wi-Fi is shown in the figure below:

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/id39MMHcqlayj5kb44o2/WEMOS%20D1R2%20+%20OLED%20Menampilkan%20DHT11.jpeg" alt=""><figcaption><p>DHT11 sensor results displayed on OLED</p></figcaption></figure>

<figure><img src="https://content.gitbook.com/content/7cujmJ5QHdJaAjH815aZ/blobs/FUkEZdbgwyBTDyyOsrUZ/OLED%20Hallo%20TEST%20123.jpeg" alt=""><figcaption><p>Get Postman results displayed on OLED</p></figcaption></figure>