Mengontrol Relay dan LED Melalui Perintah Get

Pendahuluan

Pada project ini, Anda akan menggunakan Shield Workshop Antares pada modul Development Board Lynx-32 . Pada Shield Workshop Antares ini terdapat sensor suhu, kelembapan (DHT11), relay, LED, dan push button. Anda akan melakukan Post Data menggunakan software POSTMAN yang berisi perintah untuk mengontrol LED dan relay. Kemudian Development Board Lynx-32 melakukan Get Data dari Antares IoT Platform yang berisi dua opsi perintah, yaitu apabila masukan Relay bernilai 1 maka relay akan menyala; masukan Relay bernilai 0 maka relay akan mati; LED bernilai 1 maka LED akan menyala; masukan LED bernilai 0 maka LED akan mati.

Gambar Ilustrasi Project

Prasyarat

Material yang dibutuhkan mengikuti Prasyarat Umum pada laman sebelumnya. Jika Anda belum menyiapkan kebutuhan pada laman tersebut, maka Anda dapat mengunjungi laman berikut.

Prasyarat Umum ESP32 Wi-Fi

Adapun tambahan material yang spesifik untuk project ini adalah sebagai berikut.

1. Shield Workshop Antares

2. Library Antares ESP HTTP. Pada dokumentasi ini menggunakan library Antares ESP HTTP versi 1.6.0.

Jika anda belum menginstall Antares ESP HTTP 1.6.0 dapat mengikuti langkah berikut.

Antares Wi-Fi HTTP

1. Software Postman

Jika Anda belum menginstall Software POSTMAN dapat mengikuti langkah pada link berikut.

Instalasi Postman

Langkah Kerja

1. Jalankan Aplikasi Arduino IDE

2. Membuka Contoh Program

Kode program dapat Anda buka pada Arduino IDE melalui File > Examples > Antares ESP HTTP > Lynx32-Simple-Project > GET_DATA_RELAY_LED.

Berikut adalah kode program contoh GET_DATA_RELAY_LED.

#include <AntaresESPHTTP.h>     // Include the AntaresESP32HTTP library

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"   // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"     // Replace with the Antares device name that was created

AntaresESPHTTP antares(ACCESSKEY);   // Initialize AntaresESP32HTTP with the access key

#define relayPin  25    // Digital pin for controlling the relay
#define ledPin  12      // Digital pin for controlling the LED

const unsigned long interval = 10000;    // 10 seconds interval to send message
unsigned long previousMillis = 0;  // Will store the last time a message was sent

void setup() {
    Serial.begin(115200);   // Initialize serial communication
    antares.setDebug(true);  // Enable Antares library debug mode
    antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to WiFi using provided SSID and password

    pinMode(relayPin, OUTPUT);  // Set relay pin as output
    pinMode(ledPin, OUTPUT);    // Set LED pin as output
}

void loop() {

    if (millis() - previousMillis > interval) {  // Check if it's time to send a message
        previousMillis = millis();               // Update the last sent time
        
        antares.get(projectName, deviceName);    // Get data from Antares
        
        if (antares.getSuccess()) {              // Check if data retrieval was successful
            String dataValue = antares.getString("Relay");  // Get the value of "Relay" data field
            String ledValue = antares.getString("LED");      // Get the value of "LED" data field

            // Control relay based on received data
            if (dataValue == "1") {
                digitalWrite(relayPin, HIGH);  // Turn on the relay
            } else if (dataValue == "0") {
                digitalWrite(relayPin, LOW);   // Turn off the relay
            }

            // Control LED based on received data
            if (ledValue == "1") {
                digitalWrite(ledPin, HIGH);    // Turn on the LED
            } else if (ledValue == "0") {
                digitalWrite(ledPin, LOW);     // Turn off the LED
            }

            Serial.println("Received data - Relay: " + dataValue + " | LED: " + ledValue);
        }
    }
}

3. Set Credential WiFi dan Credential Antares pada Kode Program

Ubah parameter Protokol HTTP pada variabel berikut *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, dan *deviceName. Sesuaikan dengan parameter di console Antares.

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"   // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"     // Replace with the Antares device name that was created

Parameter *Access key didapat dari laman akun Antares Anda.

Letak Access Key di Laman Akun Antares

Parameter WIFISSID didapat dari nama Wifi/Hotspot yang sedang digunakan oleh Anda. contohnya pada gambar di bawah ini.

WIFISSID

Parameter *PASSWORD didapat dari password WiFi yang sedang anda gunakan.

Parameter *projectName dan *deviceName didapat dari Application Name dan Device Name yang sudah dibuat dalam akun Antares.

Tampilan Application Name

Tampilan Device Name

4. Compile dan Upload Program

Hubungkan Lynx-32 dengan komputer Anda dan pastikan Communication Port terbaca.

Pada sistem operasi Windows pengecekan dapat dilakukan melalui Device Manager. Jika Lynx-32 Anda terbaca maka tampil USB-Serial CH340 dengan port menyesuaikan ketersediaan port (pada kasus ini terbaca COM4).

Tampilan Device Manager

Atur board ESP32 dengan klik Tools > Board > esp32 pada Arduino IDE, kemudian pastikan yang digunakan adalah ESP32 Dev Module. Pilih port sesuai communication port yang terbaca (dalam kasus ini COM4). Hasilnya akan terlihat seperti gambar berikut.

Tampilan Spesifikasi Board dan Port yang Digunakan

Setelah semua setup selesai, lakukan upload program dengan menekan icon panah seperti gambar berikut. Tunggu hingga selesai proses compile dan upload

Ikon Compile untuk Centang dan Ikon Upload untuk Tanda Panah

Icon Centang pada Arduino IDE hanyalah proses verify. Biasanya digunakan untuk Compile program untuk mengetahui apakah terdapat error atau tidak .

Icon Panah pada Arduino IDE adalah proses verify dan upload. Biasanya digunakan untuk Compile program sekaligus Flash Program pada target board.

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

Setelah selesai upload program, Anda dapat melihat serial monitor untuk melakukan debug program. Icon serial monitor terlihat pada gambar berikut.

Ikon Serial Monitor

Atur serial baud rate menjadi 115200 dan pilih BothNL & CR. Hasilnya akan terlihat seperti gambar berikut.

Tampilan Serial Monitor

Pastikan serial baud rate sesuai dengan nilai yang terdefinisi di kode program. Jika serial baud rate tidak sama, antara kode program dan serial monitor maka karakter ASCII tidak akan terbaca dengan baik.

5. Setup Software POSTMAN

Pada langkah ini anda memerlukan software POSTMAN, Anda dapat menginput end-point, request header dan request body terlebih dahulu dengan mengikuti format berikut.

End Point

Method	POST
URL	https://platform.antares.id:8443/~/antares-cse/antares-id/your-application-name/your-device-name

Sesuaikan your-application-name dan your-device-name sesuai nama-nama yang terdaftar pada akun Antares Anda.

Request Header

Key	Value
X-M2M-Origin	your-access-key
Content-Type	application/json;ty=4
Accept	application/json

Sesuaikan your-access-key dengan access key akun Antares Anda.

Hasilnya akan seperti gambar berikut.

Gambar setting end-point dan header pada software POSTMAN.

Selanjutnya Anda perlu menginput request body dengan mengikuti format berikut.

Request Body

{
  "m2m:cin": {
    "con": "{\"key1\":\"integer-value\", \"key2\":\"string-value\", \"keyN\":\"valueN\"}"
  }
}

Pada software POSTMAN pilih tab Body kemudian pilih raw dan masukkan payload sesuai request body yang ingin digunakan seperti gambar berikut.

Gambar isi payload request body pada software POSTMAN.

Sesuaikan isi field "con" sesuai dengan "key" dan "value" yang ingin Anda kirimkan.

6. Mengirim Pesan POSTMAN ke Server Antares

Setelah setup software POSTMAN selesai, saatnya mengirimkan perintah POST. Pada field "Relay" diisi dengan string "1" untuk RELAY ON atau "0" untuk RELAY OFF. Pada field "LED" diisi dengan string "1" untuk LED ON atau "0" untuk LED OFF. Field "Relay" dan "LED" ini merupakan pesan perintah untuk mengendalikan Relay dan LED yang akan dikirim melalui protokol HTTP ke server Antares.

{
  "m2m:cin": {
    "con": "{\"Relay\":\"1\", \"LED\":\"1\"}" 
  }
}

Sesuaikan isi field "Relay" dan "LED" sesuai dengan perintah get yang ingin Anda kirimkan. Berikan nilai "1" atau "0" untuk menyalakan atau mematikan.

Jika sudah selesai mengisi field "test" selanjutnya tekan tombol Send pada software POSTMAN. Indikator request HTTP melalui software POSTMAN berhasil, pada bagian response software POSTMAN akan muncul seperti gambar berikut

Gambar response hit API pada software POSTMAN.

7. Periksa Data di Antares

Setelah upload program berhasil, selanjutnya buka halaman device antares kemudian lihat apakah data sudah berhasil dikirim.

Gambar Halaman Console Antares Ketika Data Berhasil Diterima.

Data yang diterima oleh Lynx-32 dengan protokol HTTP berupa variabel Relay dan LED.

8. Output Program

Get data dari Antares IoT Platform dan menggerakan relay dan menyalakan LED.

Hasil Relay dan LED ON