> For the complete documentation index, see [llms.txt](https://docs.antares.id/llms.txt). Markdown versions of documentation pages are available by appending `.md` to page URLs; this page is available as [Markdown](https://docs.antares.id/contoh-kode-dan-library/esp8266-wi-fi/esp8266-wi-fi-protokol-http/project-sederhana-esp8266-http-antares/mengontrol-relay-dan-led-melalui-perintah-get.md).

# Mengontrol Relay dan LED Melalui Perintah Get

## Pendahuluan

Pada project ini, Anda akan menggunakan **Shield Workshop Antares** pada modul **ESP8266 .** Pada **Shield Workshop Antares** ini terdapat sensor suhu, kelembapan (DHT11), relay, LED, dan push button. Anda akan melakukan **Post Data** menggunakan software **POSTMAN** yang berisi perintah untuk mengontrol LED dan relay. Kemudian **ESP8266** melakukan **Get Data** dari **Antares IoT Platform** yang berisi dua opsi perintah, yaitu apabila masukan Relay bernilai 1 maka relay akan menyala; masukan Relay bernilai 0 maka relay akan mati; LED bernilai 1 maka LED akan menyala; masukan LED bernilai 0 maka LED akan mati. 

<figure><img src="/files/gJBXzI7tSU5NEFkLaQGh" alt=""><figcaption><p>Gambar Ilustrasi Project</p></figcaption></figure>

## Prasyarat

Material yang dibutuhkan mengikuti **Prasyarat Umum** pada laman sebelumnya. Jika Anda belum menyiapkan kebutuhan pada laman tersebut, maka Anda dapat mengunjungi laman berikut.

{% content-ref url="/pages/FfvYH4773vShlmvxo6Gj" %}
[Prasyarat Umum ESP8266 Wi-Fi](/contoh-kode-dan-library/esp8266-wi-fi/prasyarat-umum-esp8266-wi-fi.md)
{% endcontent-ref %}

Adapun tambahan material yang spesifik untuk project ini adalah sebagai berikut.

1. Shield Workshop Antares

<figure><img src="/files/RsArsZxm75lDZErUHUMT" alt="" width="563"><figcaption><p>Gambar ESP8266 terpasang Antares Shield</p></figcaption></figure>

2. Library Antares ESP HTTP. Pada dokumentasi ini menggunakan library **Antares ESP HTTP versi 1.6.0.**

{% hint style="info" %}
Jika anda belum menginstall **Antares ESP HTTP 1.6.0** dapat mengikuti langkah berikut.

[Antares Wi-Fi HTTP](/pendahuluan/instalasi-library-arduino/antares-wi-fi-http.md)
{% endhint %}

3. Software Postman&#x20;

{% hint style="info" %}
Jika Anda belum menginstall **Software POSTMAN** dapat mengikuti langkah pada link berikut.

[Instalasi Postman](/pendahuluan/instalasi-software/instalasi-postman.md)
{% endhint %}

## Langkah Kerja

### **1. Jalankan Aplikasi Arduino IDE**

### **2. Membuka Contoh Program**&#x20;

{% hint style="info" %}
Kode program dapat Anda buka pada Arduino IDE melalui **File > Example > Antares ESP HTTP > ESP8266-Simple-Project > GET\_DATA\_RELAY\_LED.**&#x20;
{% endhint %}

Berikut adalah kode program dari contoh **GET\_DATA\_RELAY\_LED .**&#x20;

```cpp
#include <AntaresESPHTTP.h>  // Include the AntaresESP8266HTTP library

#define ACCESSKEY "YOUR-ACCESS-KEY"    // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"      // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"  // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"  // Antares project name
#define deviceName "YOUR-DEVICE-NAME"        // Name of the device receiving data from POSTMAN

AntaresESPHTTP antares(ACCESSKEY);  // Initialize AntaresESP8266HTTP with the access key

#define relayPin D6  // Digital pin for controlling the relay
#define ledPin D2    // Digital pin for controlling the LED

const unsigned long interval = 10000;  // 10 seconds interval to send message
unsigned long previousMillis = 0;      // Will store the last time a message was sent

void setup() {
  Serial.begin(115200);                        // Initialize serial communication
  antares.setDebug(true);                      // Enable Antares library debug mode
  antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to WiFi using provided SSID and password

  pinMode(relayPin, OUTPUT);  // Set relay pin as output
  pinMode(ledPin, OUTPUT);    // Set LED pin as output
}

void loop() {

  if (millis() - previousMillis > interval) {  // Check if it's time to send a message
    previousMillis = millis();                 // Update the last sent time

    antares.get(projectName, deviceName);  // Get data from Antares

    if (antares.getSuccess()) {                       // Check if data retrieval was successful
      String dataValue = antares.getString("Relay");  // Get the value of "Relay" data field
      String ledValue = antares.getString("LED");     // Get the value of "LED" data field

      // Control relay based on received data
      if (dataValue == "1") {
        digitalWrite(relayPin, HIGH);  // Turn on the relay
      } else if (dataValue == "0") {
        digitalWrite(relayPin, LOW);  // Turn off the relay
      }

      // Control LED based on received data
      if (ledValue == "1") {
        digitalWrite(ledPin, HIGH);  // Turn on the LED
      } else if (ledValue == "0") {
        digitalWrite(ledPin, LOW);  // Turn off the LED
      }

      Serial.println("Received data - Relay: " + dataValue + " | LED: " + ledValue);
    }
  }
}
```

### **3. Set Credential WiFi dan Credential Antares pada Kode Program**&#x20;

Ubah parameter Protokol HTTP pada variabel berikut **\*ACCESSKEY, \*WIFISSID, \*PASSWORD, \*projectName,** **\*deviceName.** Sesuaikan dengan parameter di console Antares.&#x20;

```cpp
#define ACCESSKEY "your-access-key" // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid" // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password" // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"     // Antares project name
#define deviceName "YOUR-DEVICE-NAME-"    // Name of the device receiving data from POSTMAN
```

{% hint style="info" %}
Parameter **\*Access key** didapat dari laman akun Antares Anda.
{% endhint %}

<figure><img src="/files/xfmf0ZwiWkeinNu95sAR" alt=""><figcaption><p>Letak Access Key di Laman Akun Antares</p></figcaption></figure>

{% hint style="info" %}
Parameter **WIFISSID** didapat dari nama **Wifi/Hotspot** yang sedang digunakan oleh Anda. contohnya pada gambar di bawah ini.
{% endhint %}

<div align="center" data-full-width="true"><figure><img src="/files/91jCkr93lgA9HGLE0xUN" alt="" width="375"><figcaption><p>WiFi SSID yang digunakan.</p></figcaption></figure></div>

{% hint style="info" %}
Parameter **\*PASSWORD** didapat dari **password WiFi** yang sedang anda gunakan.
{% endhint %}

{% hint style="info" %}
Parameter **\*projectName**  ,**\*deviceName** didapat dari **Application Name** dan **Device Name** yang sudah dibuat dalam akun Antares.&#x20;
{% endhint %}

<figure><img src="/files/FVJT8EeaGz9yGlsgxg01" alt=""><figcaption><p>Tampilan Application Name</p></figcaption></figure>

<figure><img src="/files/qV4k7vw4xTQzfBmZ0227" alt=""><figcaption><p>Tampilan Device Name</p></figcaption></figure>

### **4. Compile dan Upload Program**

Hubungkan **ESP8266 WEMOS D1R2** dengan komputer Anda dan pastikan **Communication Port** terbaca.

{% hint style="info" %}
Pada sistem operasi Windows pengecekan dapat dilakukan melalui **Device Manager.** Jika **ESP8266 WEMOS D1R2** Anda terbaca maka tampil **USB-Serial CH340** dengan port menyesuaikan ketersediaan port (pada kasus ini terbaca **COM4**).
{% endhint %}

<figure><img src="/files/qeZlyzjfiniU89hJauqF" alt=""><figcaption><p>Gambar Device Manager pada Windows.</p></figcaption></figure>

Atur board **ESP8266 WEMOS D1R2** dengan klik **Tools > Board > esp8266** pada Arduino IDE, kemudian pastikan yang digunakan adalah **LOLIN(WEMOS) D1 R2 & mini.** Pilih port sesuai communication port yang terbaca (dalam kasus ini COM4). Hasilnya akan terlihat seperti gambar berikut.

<figure><img src="/files/AZcKkJrIueIpzS1Lebmb" alt="" width="563"><figcaption><p>Gambar Menu Tools pada Arduino IDE</p></figcaption></figure>

Setelah semua setup selesai, lakukan upload program dengan menekan icon panah seperti gambar berikut. Tunggu hingga selesai proses compile dan upload

<figure><img src="/files/mqipR4YsQcvyKilFtXtb" alt=""><figcaption><p>Gambar Icon Verify dan Upload pada Arduino IDE.</p></figcaption></figure>

{% hint style="info" %}
**Icon Centang** pada Arduino IDE hanyalah proses verify. Biasanya digunakan untuk **Compile** program untuk mengetahui apakah terdapat error atau tidak.

**Icon Panah** pada Arduino IDE adalah proses verify and upload. Biasanya digunakan untuk **Compile** program sekaligus **Flash program** kedalam target board.
{% endhint %}

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

<figure><img src="/files/dsHWKZESPlwTJ83Vg6tB" alt=""><figcaption><p>Gambar Halaman Arduino IDE Setelah Upload Berhasil.</p></figcaption></figure>

Setelah selesai upload program, Anda dapat melihat **serial monitor** untuk melakukan debug program. Icon **serial monitor** terlihat pada gambar berikut.

<figure><img src="/files/Aw5xEtzUTln0Pc60Pi5s" alt=""><figcaption><p>Gambar Icon Serial Monitor pada Arduino IDE.</p></figcaption></figure>

Atur **serial baud rate** menjadi 115200 dan pilih BothNL & CR. Hasilnya akan terlihat seperti gambar berikut.

{% hint style="danger" %}
Pastikan **serial baud rate** sesuai dengan nilai yang terdefinisi di kode program. Jika **serial baud rate** tidak sama, antara **kode program** dan **serial monitor** maka karakter ASCII tidak akan terbaca dengan baik.
{% endhint %}

<figure><img src="/files/5xW9KnxUcBKefSHHoVlG" alt=""><figcaption><p>Gambar Serial Monitor </p></figcaption></figure>

### **5. Setup Software POSTMAN**

Pada langkah ini anda memerlukan software POSTMAN, Anda dapat menginput **end-point, request header dan request body** terlebih dahulu dengan mengikuti format berikut.

**End Point**&#x20;

<table data-header-hidden><thead><tr><th width="134.5"></th><th></th></tr></thead><tbody><tr><td><strong>Method</strong></td><td>POST</td></tr><tr><td><strong>URL</strong></td><td>https://platform.antares.id:8443/~/antares-cse/antares-id/<mark style="color:red;">your-application-name/your-device-name</mark></td></tr></tbody></table>

{% hint style="info" %}
Sesuaikan <mark style="color:red;">your-application-name</mark> dan <mark style="color:red;">your-device-name</mark> sesuai nama-nama yang terdaftar pada akun Antares Anda.
{% endhint %}

**Request Header**

<table data-header-hidden><thead><tr><th width="134.5"></th><th></th></tr></thead><tbody><tr><td><strong>Key</strong></td><td><strong>Value</strong></td></tr><tr><td>X-M2M-Origin</td><td><mark style="color:red;">your-access-key</mark></td></tr><tr><td>Content-Type</td><td>application/json;ty=4</td></tr><tr><td>Accept</td><td>application/json</td></tr></tbody></table>

{% hint style="info" %}
Sesuaikan <mark style="color:red;">your-access-key</mark> dengan access key akun Antares Anda.
{% endhint %}

Hasilnya akan seperti gambar berikut.

<figure><img src="/files/LsLEfDBO9X0U1sl12fTG" alt=""><figcaption><p>Gambar setting end-point dan header pada software POSTMAN.</p></figcaption></figure>

Selanjutnya Anda perlu menginput request body dengan mengikuti format berikut.

**Request Body**

```json
{
  "m2m:cin": {
    "con": "{\"key1\":\"integer-value\", \"key2\":\"string-value\", \"keyN\":\"valueN\"}"
  }
}
```

Pada software POSTMAN pilih tab **Body** kemudian pilih **raw** dan masukkan payload sesuai request body yang ingin digunakan seperti gambar berikut.

<figure><img src="/files/sKUOvNi2RxE7i8sQV4lo" alt=""><figcaption><p>Gambar isi payload request body pada software POSTMAN.</p></figcaption></figure>

{% hint style="info" %}
Sesuaikan isi field "con" sesuai dengan "key" dan "value" yang ingin Anda kirimkan.
{% endhint %}

### **6. Mengirim Pesan POSTMAN ke Server Antares**

Setelah setup software POSTMAN selesai, saatnya mengirimkan perintah POST. Pada field "Relay" diisi dengan string "1" untuk **RELAY ON**  atau "0" untuk **RELAY OFF**. Pada field "LED" diisi dengan string "1" untuk **LED ON** atau "0" untuk **LED OFF**. Field "Relay" dan "LED" ini merupakan pesan perintah untuk mengendalikan Relay dan LED yang akan dikirim melalui protokol HTTP ke server Antares. &#x20;

```json
{
  "m2m:cin": {
    "con": "{\"Relay\":\"0\", \"LED\":\"0\"}" 
  }
}
```

{% hint style="info" %}
Sesuaikan isi field "Relay" dan "LED" sesuai dengan perintah downlink yang ingin Anda kirimkan. Berikan nilai "1" atau "0" untuk menyalakan atau mematikan.
{% endhint %}

Jika sudah selesai mengisi field "Relay" dan "LED" selanjutnya tekan tombol **Send** pada software POSTMAN. Terlihat seperti pada gambar berikut.

<figure><img src="/files/Qt1vYQGA8cI4GFgG5BA2" alt=""><figcaption><p>Gambar isi pesan pada software POSTMAN.</p></figcaption></figure>

Jika request HTTP melalui software POSTMAN berhasil, pada bagian response software POSTMAN akan muncul seperti gambar berikut&#x20;

<figure><img src="/files/FxRXSG4hpIRiudx47zpr" alt=""><figcaption><p>Gambar response hit API pada software POSTMAN. </p></figcaption></figure>

### **7. Periksa Data di Antares**

Setelah upload program berhasil, selanjutnya buka halaman device antares kemudian lihat apakah data sudah berhasil dikirim.

<figure><img src="/files/NSXINuvboNNnlNQq5MqT" alt=""><figcaption></figcaption></figure>

<figure><img src="/files/ERR2Co1UzcIBRnmOt4F8" alt=""><figcaption><p>Gambar Halaman Console Antares Ketika Data Berhasil Diterima.</p></figcaption></figure>

{% hint style="info" %}
Data yang diterima oleh **ESP8266** dengan protokol HTTP berupa variabel Relay dan LED.
{% endhint %}

### 8. Output program&#x20;

Get data dari **Antares IoT Platform** dan menggerakan relay dan menyalakan LED.

<figure><img src="/files/D7xEtg8JqCpPzrWLj3S0" alt=""><figcaption><p>Hasil Relay dan LED ON</p></figcaption></figure>