# Post dan Get Data DHT 11 ditampilkan pada Display OLED

## Pendahuluan

Pada project ini, Anda akan menggunakan **Shield Workshop Antares** pada modul **ESP8266 .** Pada **Shield Workshop Antares** ini terdapat sensor suhu, kelembapan (DHT11), relay, LED, dan push button. Anda akan melakukan monitoring suhu dan kelembapan dengan periode interval yang di tentukan. Hasil data yang dikirim sensor dapat Anda pantau melalui console Antares dan ditampilkan pada **OLED.** Anda juga dapat mengirim pesan berupa **data string** yang ditampilkan pada display **OLED**. Proses pengiriman data ini menggunakan **Software POSTMAN** untuk mengirimkan data ke **Antares IoT Platform**. 

<figure><img src="/files/8r4RcTaWaqoJ7iFMnNEI" alt=""><figcaption><p>Gambar Ilustrasi Project</p></figcaption></figure>

## Prasyarat

Material yang dibutuhkan mengikuti **Prasyarat Umum** pada laman sebelumnya. Jika Anda belum menyiapkan kebutuhan pada laman tersebut, maka Anda dapat mengunjungi laman berikut.

{% content-ref url="/pages/FfvYH4773vShlmvxo6Gj" %}
[Prasyarat Umum ESP8266 Wi-Fi](/contoh-kode-dan-library/esp8266-wi-fi/prasyarat-umum-esp8266-wi-fi.md)
{% endcontent-ref %}

Adapun tambahan material yang spesifik untuk project ini adalah sebagai berikut.

1. Shield Workshop Antares

<figure><img src="/files/WU4NmpHsFcX2RbRYOoMk" alt="" width="563"><figcaption><p>Gambar WEMOS D1R2 Menampilkan Data DHT11</p></figcaption></figure>

2. Modul OLED SSD1036 0,96inch 128x64 pixel berbasis I2C

<figure><img src="/files/mY1URVw2mV1PCFiJmKet" alt="" width="345"><figcaption><p>Gambar Modul OLED SSD1036 0.96inch</p></figcaption></figure>

1. Library Antares ESP HTTP. Pada dokumentasi ini menggunakan library **Antares ESP HTTP versi 1.6.0.**

{% hint style="info" %}
Jika anda belum menginstall **Antares ESP HTTP 1.6.0** dapat mengikuti langkah berikut.

[Antares Wi-Fi HTTP](/pendahuluan/instalasi-library-arduino/antares-wi-fi-http.md)
{% endhint %}

4. Library display OLED. Pada dokumentasi ini menggunakan **Adafruit\_SSD1306 by Adafruit versi 2.5.7.**

{% hint style="info" %}
Jika Anda belum menginstall library **Adafruit SSD1306 by Adafruit versi 2.5.7.** dapat mengikuti langkah pada link berikut.

[Adafruit SSD1306](/pendahuluan/instalasi-library-arduino/adafruit-ssd1306.md)
{% endhint %}

5. Library DHT11. Pada dokumentasi ini menggunakan **DHT11 Sensor Library versi 1.4.4.**

{% hint style="info" %}
Jika Anda belum menginstall library **DHT11 Sensor Library versi 1.4.4.** dapat mengikuti langkah pada link berikut.

[DHT11 Sensor Library](/pendahuluan/instalasi-library-arduino/dht11-sensor-library.md)
{% endhint %}

6. Software Postman&#x20;

{% hint style="info" %}
Jika Anda belum menginstall **Software POSTMAN** dapat mengikuti langkah pada link berikut.

[Instalasi Postman](/pendahuluan/instalasi-software/instalasi-postman.md)
{% endhint %}

## Langkah Kerja

### **1. Jalankan Aplikasi Arduino IDE**

### **2. Membuka Contoh Program**&#x20;

{% hint style="info" %}
Kode program dapat Anda buka pada Arduino IDE melalui **File > Example > Antares ESP HTTP > ESP8266-Simple-Project > POST\_DATA\_GET\_DATA\_OLED.**&#x20;
{% endhint %}

Berikut adalah kode program dari contoh **POST\_DATA\_GET\_DATA\_OLED. .**&#x20;

```cpp
#include <AntaresESPHTTP.h>    // Include the AntaresESP8266HTTP library
#include <Adafruit_SSD1306.h>  // Include the Adafruit SSD1306 library
#include "DHT.h"               // Include the DHT sensor library

#define DHTPIN D1      // Digital pin connected to the DHT sensor
#define DHTTYPE DHT11  // Type of DHT sensor (DHT11 in this case)

#define ACCESSKEY "YOUR-ACCESS-KEY"    // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"      // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"  // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"     // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNamePostman "YOUR-DEVICE-NAME-2"  // Name of the device receiving data

AntaresESPHTTP antares(ACCESSKEY);  // Initialize AntaresESP8266HTTP with the access key
DHT dht(DHTPIN, DHTTYPE);           // Initialize DHT sensor object

#define SCREEN_WIDTH 128  // OLED screen width in pixels
#define SCREEN_HEIGHT 64  // OLED screen height in pixels
#define OLED_RESET -1     // Reset pin for the OLED (not used in this case)

const unsigned long interval = 5000;    // Interval to send sensor data (5 seconds)
const unsigned long interval2 = 10000;  // Interval to get data from Antares (10 seconds)
unsigned long previousMillis = 0;       // Store the last time sensor data was sent
unsigned long previousMillis2 = 0;      // Store the last time data was received from Antares

String testData;       // String to hold received data from Antares
String lastData = "";  // String to store last received data

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);  // Initialize OLED display object

bool showSensorData = true;  // Boolean to control display of sensor data

void setup() {
  Serial.begin(115200);                        // Initialize serial communication
  antares.setDebug(true);                      // Enable Antares library debug mode
  antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to WiFi using provided SSID and password
  dht.begin();                                 // Initialize the DHT sensor

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {  // Initialize the OLED display
    Serial.println(F("SSD1306 allocation failed"));
    for (;;)
      ;
  }

  display.clearDisplay();  // Clear the OLED display buffer
  display.display();       // Display the cleared buffer
}

void loop() {

  if (millis() - previousMillis > interval) {  // Check if it's time to send sensor data
    previousMillis = millis();                 // Update the last sent time

    float hum = dht.readHumidity();      // Read humidity from the DHT sensor
    float temp = dht.readTemperature();  // Read temperature from the DHT sensor
    if (isnan(hum) || isnan(temp)) {
      Serial.println("Failed to read DHT sensor!");  // Print an error message if sensor reading fails
      return;
    }
    antares.add("temperature", temp);                    // Add temperature data to the Antares payload
    antares.add("humidity", hum);                        // Add humidity data to the Antares payload
    antares.send(projectName, deviceNameSensor);         // Send sensor data to Antares
    display.clearDisplay();                              // Clear the OLED display buffer
    display.setTextSize(1);                              // Set text size on the display
    display.setTextColor(SSD1306_WHITE);                 // Set text color to white
    display.setCursor(0, 0);                             // Set cursor position on the display
    display.println("Temp: " + String(temp) + " *C");    // Display temperature
    display.println("Humidity: " + String(hum) + " %");  // Display humidity
    display.display();                                   // Display the updated buffer on the OLED
  }

  if (millis() - previousMillis2 > interval2) {  // Check if it's time to get data from Antares
    previousMillis2 = millis();                  // Update the last received time

    antares.get(projectName, deviceNamePostman);  // Get data from Antares

    if (antares.getSuccess()) {                   // Check if data retrieval was successful
      testData = antares.getString("Test Data");  // Get the "Test Data" field from the response

      if (lastData != testData)  // Check if the received data is different from the last one
      {
        lastData = testData;                           // Update the last received data
        Serial.println("Received Data: " + testData);  // Print received data to the serial monitor
        display.clearDisplay();                        // Clear the OLED display buffer
        display.setTextSize(1);                        // Set text size on the display
        display.setTextColor(SSD1306_WHITE);           // Set text color to white
        display.setCursor(0, 0);                       // Set cursor position on the display
        display.println("Received:");                  // Display "Received:"
        display.println(testData);                     // Display the received data
        display.display();                             // Display the updated buffer on the OLED
        delay(2000);                                   // Display received data for 2 seconds
      }
    }
  }
}
```

### **3. Set Credential WiFi dan Credential Antares pada Kode Program**

Ubah parameter Protokol HTTP pada variabel berikut **\*ACCESSKEY, \*WIFISSID, \*PASSWORD, \*projectName,** **\*deviceNameSensor, \*deviceNamePostman.** Sesuaikan dengan parameter di console Antares.&#x20;

{% hint style="info" %}
Pada project ini membutuhkan 2 Device yaitu device di Antares untuk menerima data dari DHT11 dengan nama variabel deviceNameSensor dan device untuk menerima data dari POSTMAN dengan nama variabel deviceNamePostman yang dibuat dalam satu Aplikasi pada console Antares.
{% endhint %}

```cpp
#define ACCESSKEY "your-access-key" // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid" // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password" // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"     // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNamePostman "YOUR-DEVICE-NAME-2"  // Name of the device receiving data
```

{% hint style="info" %}
Parameter **\*Access key** didapat dari laman akun Antares Anda.
{% endhint %}

<figure><img src="/files/xfmf0ZwiWkeinNu95sAR" alt=""><figcaption><p>Letak Access Key di Laman Akun Antares</p></figcaption></figure>

{% hint style="info" %}
Parameter **WIFISSID** didapat dari nama **Wifi/Hotspot** yang sedang digunakan oleh Anda. contohnya pada gambar di bawah ini.
{% endhint %}

<div align="center" data-full-width="true"><figure><img src="/files/pGbdSqkDslbcHRojnVVI" alt="" width="375"><figcaption><p>WiFi SSID yang digunakan.</p></figcaption></figure></div>

{% hint style="info" %}
Parameter **\*PASSWORD** didapat dari **password WiFi** yang sedang anda gunakan.
{% endhint %}

{% hint style="info" %}
Parameter **\*projectName**  ,**\*deviceNameSensor , \*deviceNamePostman** didapat dari **Application Name** dan **Device Name** yang sudah dibuat dalam akun Antares. Pada project ini membutuhkan **Dua Device Name** sehingga Anda wajib membuat dua Device Baru seperti gambar di bawah.
{% endhint %}

<figure><img src="/files/M13drxGHxMKyRWW0UsL3" alt=""><figcaption><p>Application Name dan Device Name pada laman Antares.</p></figcaption></figure>

### **4. Compile dan Upload Program**

Hubungkan **ESP8266 WEMOS D1R2** dengan komputer Anda dan pastikan **Communication Port** terbaca.

{% hint style="info" %}
Pada sistem operasi Windows pengecekan dapat dilakukan melalui **Device Manager.** Jika **ESP8266 WEMOS D1R2** Anda terbaca maka tampil **USB-Serial CH340** dengan port menyesuaikan ketersediaan port (pada kasus ini terbaca **COM4**).
{% endhint %}

<figure><img src="/files/VvWOHXcl2QJZIrTDug2i" alt=""><figcaption><p>Gambar Device Manager pada Windows.</p></figcaption></figure>

Atur board **ESP8266 WEMOS D1R2** dengan klik **Tools > Board > esp8266** pada Arduino IDE, kemudian pastikan yang digunakan adalah **LOLIN(WEMOS) D1 R2 & mini.** Pilih port sesuai communication port yang terbaca (dalam kasus ini COM4). Hasilnya akan terlihat seperti gambar berikut.

<figure><img src="/files/SpSgBv4PeWtQPaPDOIbY" alt="" width="563"><figcaption><p>Gambar Menu Tools pada Arduino IDE</p></figcaption></figure>

Setelah semua setup selesai, lakukan upload program dengan menekan icon panah seperti gambar berikut. Tunggu hingga selesai proses compile dan upload

<figure><img src="/files/6RkHI5AxFLwEKhdiRPWH" alt=""><figcaption><p>Gambar Icon Verify dan Upload pada Arduino IDE.</p></figcaption></figure>

{% hint style="info" %}
**Icon Centang** pada Arduino IDE hanyalah proses verify. Biasanya digunakan untuk **Compile** program untuk mengetahui apakah terdapat error atau tidak.

**Icon Panah** pada Arduino IDE adalah proses verify and upload. Biasanya digunakan untuk **Compile** program sekaligus **Flash program** kedalam target board.
{% endhint %}

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

<figure><img src="/files/BmMXpV0TMUICYx3Tj7BF" alt=""><figcaption><p>Gambar Halaman Arduino IDE Setelah Upload Berhasil.</p></figcaption></figure>

Setelah selesai upload program, Anda dapat melihat **serial monitor** untuk melakukan debug program. Icon **serial monitor** terlihat pada gambar berikut.

<figure><img src="/files/5iWlFOZmA4kFUywjbBVg" alt=""><figcaption><p>Gambar Icon Serial Monitor pada Arduino IDE.</p></figcaption></figure>

Atur **serial baud rate** menjadi 115200 dan pilih BothNL & CR. Hasilnya akan terlihat seperti gambar berikut.

{% hint style="danger" %}
Pastikan **serial baud rate** sesuai dengan nilai yang terdefinisi di kode program. Jika **serial baud rate** tidak sama, antara **kode program** dan **serial monitor** maka karakter ASCII tidak akan terbaca dengan baik.
{% endhint %}

<figure><img src="/files/QiOIuT3TdJHlclAVJ6Pf" alt=""><figcaption><p>Gambar Serial Monitor </p></figcaption></figure>

### **5. Setup Software POSTMAN**

Pada langkah ini anda memerlukan software POSTMAN, Anda dapat menginput **end-point, request header dan request body** terlebih dahulu dengan mengikuti format berikut.

**End Point**&#x20;

<table data-header-hidden><thead><tr><th width="134.5"></th><th></th></tr></thead><tbody><tr><td><strong>Method</strong></td><td>POST</td></tr><tr><td><strong>URL</strong></td><td>https://platform.antares.id:8443/~/antares-cse/antares-id/<mark style="color:red;">your-application-name/your-device-name</mark></td></tr></tbody></table>

{% hint style="info" %}
Sesuaikan <mark style="color:red;">your-application-name</mark> dan <mark style="color:red;">your-device-name</mark> sesuai nama-nama yang terdaftar pada akun Antares Anda.
{% endhint %}

**Request Header**

<table data-header-hidden><thead><tr><th width="134.5"></th><th></th></tr></thead><tbody><tr><td><strong>Key</strong></td><td><strong>Value</strong></td></tr><tr><td>X-M2M-Origin</td><td><mark style="color:red;">your-access-key</mark></td></tr><tr><td>Content-Type</td><td>application/json;ty=4</td></tr><tr><td>Accept</td><td>application/json</td></tr></tbody></table>

{% hint style="info" %}
Sesuaikan <mark style="color:red;">your-access-key</mark> dengan access key akun Antares Anda.
{% endhint %}

Hasilnya akan seperti gambar berikut.

<figure><img src="/files/LsLEfDBO9X0U1sl12fTG" alt=""><figcaption><p>Gambar setting end-point dan header pada software POSTMAN.</p></figcaption></figure>

Selanjutnya Anda perlu menginput request body dengan mengikuti format berikut.

**Request Body**

```json
{
  "m2m:cin": {
    "con": "{\"key1\":\"integer-value\", \"key2\":\"string-value\", \"keyN\":\"valueN\"}"
  }
}
```

Pada software POSTMAN pilih tab **Body** kemudian pilih **raw** dan masukkan payload sesuai request body yang ingin digunakan seperti gambar berikut.

<figure><img src="/files/sKUOvNi2RxE7i8sQV4lo" alt=""><figcaption><p>Gambar isi payload request body pada software POSTMAN.</p></figcaption></figure>

{% hint style="info" %}
Sesuaikan isi field "con" sesuai dengan "key" dan "value" yang ingin Anda kirimkan.
{% endhint %}

### **6. Mengirim Pesan POSTMAN ke Server Antares**

Setelah setup software POSTMAN selesai, saatnya mengirimkan perintah POST. Pada field "Test Data" diisi dengan string "Hallo TEST 123" sebagai pesan yang akan dikirim melalui protokol HTTP ke server Antares.&#x20;

```json
{
  "m2m:cin": {
    "con": "{\"Test Data\":\"Hallo TEST 123\"}"
  }
}
```

Jika sudah selesai mengisi field "Test Data" selanjutnya tekan tombol **Send** pada software POSTMAN. Terlihat seperti gambar berikut.

<figure><img src="/files/hYcuKmBpItArhlBFxxmZ" alt=""><figcaption><p>Gambar isi pesan pada software POSTMAN.</p></figcaption></figure>

Jika request HTTP melalui software POSTMAN berhasil, pada bagian response software POSTMAN akan muncul seperti gambar berikut&#x20;

<figure><img src="/files/9JKYiHxirPk3Zec6H52B" alt=""><figcaption><p>Gambar response hit API pada software POSTMAN. </p></figcaption></figure>

### **7. Periksa Data di Antares**

Setelah upload program berhasil, selanjutnya buka halaman device antares kemudian lihat apakah data sudah berhasil dikirim.

<figure><img src="/files/Vkda4vjupJOGXQWLOBDl" alt=""><figcaption><p>Gambar Halaman Console Antares Ketika Data Berhasil Diterima dari Sensor DHT11. </p></figcaption></figure>

<figure><img src="/files/SZQYDBsqgMlaIMD09VvT" alt=""><figcaption><p>Gambar Halaman Console Antares Ketika Data Berhasil Diterima dari POSTMAN.</p></figcaption></figure>

### 8. Output program&#x20;

Get data dari **Antares IoT Platform** dan ditampilkan pada display OLED setelah terhubung ke Wi-Fi tertampil pada gambar dibawah ini:

<figure><img src="/files/lusIXz06j2HhXfJfYVqC" alt=""><figcaption><p>Hasil sensor DHT11 ditampilkan pada OLED</p></figcaption></figure>

<figure><img src="/files/sbORHYgbx10fcUtMaaaa" alt=""><figcaption><p>Hasil Get Postman ditampilkan pada OLED</p></figcaption></figure>


---

# Agent Instructions: Querying This Documentation

If you need additional information that is not directly available in this page, you can query the documentation dynamically by asking a question.

Perform an HTTP GET request on the current page URL with the `ask` query parameter:

```
GET https://docs.antares.id/contoh-kode-dan-library/esp8266-wi-fi/esp8266-wi-fi-protokol-http/project-sederhana-esp8266-http-antares/post-dan-get-data-dht-11-ditampilkan-pada-display-oled.md?ask=<question>
```

The question should be specific, self-contained, and written in natural language.
The response will contain a direct answer to the question and relevant excerpts and sources from the documentation.

Use this mechanism when the answer is not explicitly present in the current page, you need clarification or additional context, or you want to retrieve related documentation sections.