Post dan Get Data DHT 11 ditampilkan pada Display OLED

Pendahuluan

Pada project ini, Anda akan menggunakan Shield Workshop Antares pada modul Development Board Lynx-32. Pada Shield Workshop Antares ini terdapat sensor suhu, kelembapan (DHT11), relay, LED, dan push button. Anda akan melakukan monitoring suhu dan kelembapan dengan periode interval yang dintentukan. Hasil data yang dikirim sensor dapat Anda pantau melalui console Antares dan ditampilkan pada OLED. Anda juga dapat mengirim pesan berupa data string yang ditampilkan pada display OLED. Proses pengiriman data ini menggunakan Software POSTMAN untuk mengirimkan data ke Antares IoT Platform.

Prasyarat

Material yang dibutuhkan mengikuti Prasyarat Umum pada laman sebelumnya. Jika Anda belum menyiapkan kebutuhan pada laman tersebut, maka Anda dapat mengunjungi laman berikut.

Adapun tambahan material yang spesifik untuk project ini adalah sebagai berikut.

  1. Shield Workshop Antares

  2. Modul OLED SSD1036 0,96inch 128x64 pixel berbasis I2C

  1. Library Antares ESP HTTP. Pada dokumentasi ini menggunakan library Antares ESP HTTP versi 1.5.0.

Jika anda belum menginstall Antares ESP HTTP 1.5.0 dapat mengikuti langkah berikut.

Antares Wi-Fi HTTP

  1. Library DHT11. Pada dokumentasi ini menggunakan DHT11 Sensor Library versi 1.4.4.

Jika Anda belum menginstall library DHT11 Sensor Library versi 1.4.4. dapat mengikuti langkah pada link berikut.

DHT11 Sensor Library

  1. Library OLED SSD1306. Pada dokumentasi ini menggunakan Adafruit SSD1306 by Adafruit versi 2.5.7.

Jika Anda belum menginstall library Adafruit SSD1306 by Adafruit versi 2.5.7. dapat mengikuti langkah pada link berikut.

Adafruit SSD1306

  1. Software Postman

Jika Anda belum menginstall Software POSTMAN dapat mengikuti langkah pada link berikut.

Instalasi Postman

Langkah Kerja

Langkah Kerja

1. Jalankan Aplikasi Arduino IDE

2. Membuka Contoh Program

Kode program dapat Anda buka pada Arduino IDE melalui File > Examples > Antares ESP HTTP > Lynx32-Simple-Project > POST_DATA_GET_DATA_OLED.

Berikut adalah kode program contoh POST_DATA_GET_DATA_OLED.

#include <AntaresESPHTTP.h>     // Include the AntaresESP32HTTP library
#include <Adafruit_SSD1306.h>     // Include the Adafruit SSD1306 library
#include "DHT.h"                  // Include the DHT sensor library

#define DHTPIN 14                   // Digital pin connected to the DHT sensor
#define DHTTYPE DHT11               // Type of DHT sensor (DHT11 in this case)

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"          // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNamePostman "YOUR-DEVICE-NAME-2"     // Name of the device receiving data

AntaresESPHTTP antares(ACCESSKEY);   // Initialize AntaresESP32HTTP with the access key
DHT dht(DHTPIN, DHTTYPE);              // Initialize DHT sensor object

#define SCREEN_WIDTH 128         // OLED screen width in pixels
#define SCREEN_HEIGHT 64         // OLED screen height in pixels
#define OLED_RESET -1            // Reset pin for the OLED (not used in this case)

const unsigned long interval = 5000;     // Interval to send sensor data (5 seconds)
const unsigned long interval2 = 10000;   // Interval to get data from Antares (10 seconds)
unsigned long previousMillis = 0;        // Store the last time sensor data was sent
unsigned long previousMillis2 = 0;       // Store the last time data was received from Antares

String testData;            // String to hold received data from Antares
String lastData="";         // String to store last received data

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);   // Initialize OLED display object

bool showSensorData = true;   // Boolean to control display of sensor data

void setup() {
  Serial.begin(115200);      // Initialize serial communication
  antares.setDebug(true);    // Enable Antares library debug mode
  antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to WiFi using provided SSID and password
  dht.begin();               // Initialize the DHT sensor

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {   // Initialize the OLED display
    Serial.println(F("SSD1306 allocation failed"));
    for (;;)
      ;
  }

  display.clearDisplay();    // Clear the OLED display buffer
  display.display();         // Display the cleared buffer
}

void loop() {
  
   if (millis() - previousMillis > interval) {     // Check if it's time to send sensor data
    previousMillis = millis();                    // Update the last sent time
    
    float hum = dht.readHumidity();                // Read humidity from the DHT sensor
    float temp = dht.readTemperature();            // Read temperature from the DHT sensor
    if (isnan(hum) || isnan(temp)) {
        Serial.println("Failed to read DHT sensor!");  // Print an error message if sensor reading fails
        return;
    }
    antares.add("temperature", temp);              // Add temperature data to the Antares payload
    antares.add("humidity", hum);                  // Add humidity data to the Antares payload
    antares.send(projectName, deviceNameSensor);   // Send sensor data to Antares
    display.clearDisplay();                        // Clear the OLED display buffer
    display.setTextSize(1);                        // Set text size on the display
    display.setTextColor(SSD1306_WHITE);           // Set text color to white
    display.setCursor(0, 0);                       // Set cursor position on the display
    display.println("Temp: " + String(temp) + " *C");     // Display temperature
    display.println("Humidity: " + String(hum) + " %");  // Display humidity
    display.display();                             // Display the updated buffer on the OLED
    }
    
    if (millis() - previousMillis2 > interval2) {   // Check if it's time to get data from Antares
    previousMillis2 = millis();                    // Update the last received time
    
    antares.get(projectName, deviceNamePostman);   // Get data from Antares
    
    if (antares.getSuccess()) {                    // Check if data retrieval was successful
      testData = antares.getString("Test Data");   // Get the "Test Data" field from the response

      if(lastData != testData)                     // Check if the received data is different from the last one
      {
        lastData = testData;                       // Update the last received data
        Serial.println("Received Data: " + testData);   // Print received data to the serial monitor
        display.clearDisplay();                    // Clear the OLED display buffer
        display.setTextSize(1);                    // Set text size on the display
        display.setTextColor(SSD1306_WHITE);       // Set text color to white
        display.setCursor(0, 0);                   // Set cursor position on the display
        display.println("Received:");              // Display "Received:"
        display.println(testData);                 // Display the received data
        display.display();                         // Display the updated buffer on the OLED
        delay(2000);                               // Display received data for 2 seconds
      }
     }
    }

}

3. Set Credential WiFi dan Credential Antares pada Kode Program

Ubah parameter Protokol HTTP pada variabel berikut *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, dan *deviceNameSensor, dan *deviceNamePostman. Sesuaikan dengan parameter di console Antares.

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"          // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNamePostman "YOUR-DEVICE-NAME-2"     // Name of the device receiving data

Parameter *Access key didapat dari laman akun Antares Anda.

Parameter WIFISSID didapat dari nama Wifi/Hotspot yang sedang digunakan oleh Anda. contohnya pada gambar di bawah ini.

Parameter *PASSWORD didapat dari password WiFi yang sedang anda gunakan.

Parameter *projectName dan *deviceName didapat dari Application Name dan Device Name yang sudah dibuat dalam akun Antares.

4. Compile dan Upload Program

Hubungkan Lynx-32 dengan komputer Anda dan pastikan Communication Port terbaca.

Pada sistem operasi Windows pengecekan dapat dilakukan melalui Device Manager. Jika Lynx-32 Anda terbaca maka tampil USB-Serial CH340 dengan port menyesuaikan ketersediaan port (pada kasus ini terbaca COM4).

Atur board ESP32 dengan klik Tools > Board > esp32 pada Arduino IDE, kemudian pastikan yang digunakan adalah ESP32 Dev Module. Pilih port sesuai communication port yang terbaca (dalam kasus ini COM4). Hasilnya akan terlihat seperti gambar berikut.

Setelah semua setup selesai, lakukan upload program dengan menekan icon panah seperti gambar berikut. Tunggu hingga selesai proses compile dan upload

Icon Centang pada Arduino IDE hanyalah proses verify. Biasanya digunakan untuk Compile program untuk mengetahui apakah terdapat error atau tidak .

Icon Panah pada Arduino IDE adalah proses verify dan upload. Biasanya digunakan untuk Compile program sekaligus Flash Program pada target board.

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

Setelah selesai upload program, Anda dapat melihat serial monitor untuk melakukan debug program. Icon serial monitor terlihat pada gambar berikut.

Atur serial baud rate menjadi 115200 dan pilih BothNL & CR. Hasilnya akan terlihat seperti gambar berikut.

Pastikan serial baud rate sesuai dengan nilai yang terdefinisi di kode program. Jika serial baud rate tidak sama, antara kode program dan serial monitor maka karakter ASCII tidak akan terbaca dengan baik.

5. Setup Software POSTMAN

Pada langkah ini anda memerlukan software POSTMAN, Anda dapat menginput end-point, request header dan request body terlebih dahulu dengan mengikuti format berikut.

End Point

Sesuaikan your-application-name dan your-device-name sesuai nama-nama yang terdaftar pada akun Antares Anda.

Request Header

Sesuaikan your-access-key dengan access key akun Antares Anda.

Hasilnya akan seperti gambar berikut.

Selanjutnya Anda perlu menginput request body dengan mengikuti format berikut.

Request Body

{
  "m2m:cin": {
    "con": "{\"key1\":\"integer-value\", \"key2\":\"string-value\", \"keyN\":\"valueN\"}"
  }
}

Pada software POSTMAN pilih tab Body kemudian pilih raw dan masukkan payload sesuai request body yang ingin digunakan seperti gambar berikut.

Sesuaikan isi field "con" sesuai dengan "key" dan "value" yang ingin Anda kirimkan.

6. Mengirim Pesan POSTMAN ke Server Antares

Setelah setup software POSTMAN selesai, saatnya mengirimkan perintah POST. Pada field "Test Data" diisi dengan string "Halloo Test" sebagai pesan yang akan dikirim melalui protokol HTTP ke server Antares.

{
  "m2m:cin": {
    "con": "{\"Test Data\":\"Halloo Test\"}"
  }
}

Jika sudah selesai mengisi field "Test Data" selanjutnya tekan tombol Send pada software POSTMAN. Indikator request HTTP melalui software POSTMAN berhasil, pada bagian response software POSTMAN akan muncul seperti gambar berikut.

7. Periksa Data di Antares

Setelah upload program berhasil, selanjutnya buka halaman device antares kemudian lihat apakah data sudah berhasil dikirim.

Data yang diterima oleh Lynx-32 dengan protokol HTTP berupa variabel Test Data.

8. Melihat Pesan Get

Get data dari Antares IoT Platform dan ditampilkan pada display OLED setelah terhubung ke Wi-Fi tertampil pada gambar dibawah ini: