Post Data DHT 11 dengan Push Button

Pendahuluan

Pada project ini, Anda akan menggunakan Shield Workshop Antares pada modul ESP8266 . Pada Shield Workshop Antares ini terdapat sensor suhu, kelembapan (DHT11), relay, LED dan push button. Anda akan melakukan monitoring suhu dan kelembapan dengan push button sebagai pemicu pengiriman data. Hasil data yang dikirim sensor dapat Anda pantau melalui console Antares.

Gambar Ilustrasi Project

Prasyarat

Material yang dibutuhkan mengikuti Prasyarat Umum pada laman sebelumnya. Jika Anda belum menyiapkan kebutuhan pada laman tersebut, maka Anda dapat mengunjungi laman berikut.

Prasyarat Umum ESP8266 Wi-Fi

Adapun tambahan material yang spesifik untuk project ini adalah sebagai berikut.

1. Shield Workshop Antares

Gambar WEMOSD1R2 Terpasang Antares Shield

1. Library Antares ESP HTTP. Pada dokumentasi ini menggunakan library Antares ESP HTTP versi 1.6.0.

Jika anda belum menginstall Antares ESP HTTP 1.6.0 dapat mengikuti langkah berikut.

Antares Wi-Fi HTTP

1. Library DHT11. Pada dokumentasi ini menggunakan DHT11 Sensor Library versi 1.4.4.

Jika Anda belum menginstall library DHT11 Sensor Library versi 1.4.4. dapat mengikuti langkah pada link berikut.

DHT11 Sensor Library

Langkah Kerja

1. Jalankan Aplikasi Arduino IDE

2. Membuka Contoh Program

Kode program dapat Anda buka pada Arduino IDE melalui File > Example > Antares ESP HTTP > ESP8266-Simple-Project > POST_DATA_DHT11_PUSHBUTTON.

Berikut adalah kode program dari contoh POST_DATA_DHT11_PUSHBUTTON

#include <AntaresESPHTTP.h>  // Include the AntaresESP2866HTTP library for connecting to the Antares platform
#include "DHT.h"             // Include the DHT sensor library

#define DHTPIN D1      // Define the pin number for the DHT sensor (connected to pin D1)
#define DHTTYPE DHT11  // Define the DHT sensor type as DHT11

#define ACCESSKEY "YOUR-ACCESS-KEY"    // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"      // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"  // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"  // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"        // Replace with the Antares device name that was created

AntaresESPHTTP antares(ACCESSKEY);  // Create an AntaresESP2866HTTP object to interact with Antares
DHT dht(DHTPIN, DHTTYPE);           // Create a DHT object for the DHT sensor

#define pushButtonPin A0  // Define the pin number for the push button (connected to pin 32)
#define ledPin D2         // Define the pin number for the LED (connected to pin 12)

bool ledState = false;         // Variable to store the state of the LED (ON or OFF)
bool lastButtonState = false;  // Variable to store the previous state of the push button

void setup() {
  Serial.begin(115200);    // Initialize serial communication with baudrate 115200
  antares.setDebug(true);  // Enable debug mode for AntaresESP32HTTP (messages will be displayed in the serial monitor)

  // Reset WiFi cache before connecting
  WiFi.disconnect();

  antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to Wi-Fi with the specified SSID and password
  dht.begin();                                 // Initialize the DHT sensor

  pinMode(pushButtonPin, INPUT);  // Set the push button pin as input with internal pull-up resistor
  pinMode(ledPin, OUTPUT);        // Set the LED pin as output
  digitalWrite(ledPin, LOW);      // Turn off the LED initially
}

void loop() {
  // Read the current state of the push button
  int analogValue = analogRead(A0);
  bool currentButtonState = (analogValue < 512);  // Adjust the threshold as needed

  // Check if the button state has changed (button press detected)
  if (currentButtonState != lastButtonState && currentButtonState == LOW) {
    Serial.println("The button is pressed");

    // Toggle state of the LED (ON to OFF or OFF to ON)
    ledState = !ledState;
    digitalWrite(ledPin, ledState);

    // Read temperature and humidity from the DHT sensor
    float hum = dht.readHumidity();
    float temp = dht.readTemperature();

    // Check if the sensor reading is valid
    if (isnan(hum) || isnan(temp)) {
      Serial.println("Failed to read DHT sensor!");
      return;
    }

    // Print temperature and humidity values to the serial monitor
    Serial.println("Temperature: " + (String)temp + " *C");
    Serial.println("Humidity: " + (String)hum + " %");

    // Add temperature and humidity data to the Antares storage buffer
    antares.add("temperature", temp);
    antares.add("humidity", hum);

    // Send the data from the storage buffer to Antares
    antares.send(projectName, deviceName);

    // Add some delay to avoid multiple data sending due to button debouncing
    delay(1000);
  }

  // Update the last button state for the next iteration
  lastButtonState = currentButtonState;
}

3. Set Credential WiFi dan Credential Antares pada Kode Program

Ubah parameter Protokol HTTP pada variabel berikut *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, dan *deviceName. Sesuaikan dengan parameter di console Antares.

#define ACCESSKEY "YOUR-ACCESS-KEY"    // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"      // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"  // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"  // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"        // Replace with the Antares device name that was created

Parameter *Access key didapat dari laman akun Antares Anda.

Letak Access Key di Laman Akun Antares

Parameter WIFISSID didapat dari nama Wifi/Hotspot yang sedang digunakan oleh Anda. contohnya pada gambar di bawah ini.

WiFi SSID yang digunakan.

Parameter *PASSWORD didapat dari password WiFi yang sedang anda gunakan.

Parameter *projectName dan *deviceName didapat dari Application Name dan Device Name yang sudah dibuat dalam akun Antares.

Tampilan Application Name

Tampilan Device Name

4. Compile dan Upload Program

Hubungkan ESP 8266 WEMOS D1R2 dengan komputer Anda dan pastikan Communication Port terbaca.

Pada sistem operasi Windows pengecekan dapat dilakukan melalui Device Manager. Jika ESP 8266 WEMOS D1R2 Anda terbaca maka tampil USB-Serial CH340 dengan port menyesuaikan ketersediaan port (pada kasus ini terbaca COM4).

Gambar Device Manager pada Windows.

Atur board ESP8266 WEMOS D1R2 dengan klik Tools > Board > esp8266 pada Arduino IDE, kemudian pastikan yang digunakan adalah LOLIN(WEMOS) D1 R2 & mini. Pilih port sesuai communication port yang terbaca (dalam kasus ini COM4). Hasilnya akan terlihat seperti gambar berikut.

Gambar Menu Tools pada Arduino IDE

Setelah semua setup selesai, lakukan upload program dengan menekan icon panah seperti gambar berikut. Tunggu hingga selesai proses compile dan upload

Gambar Icon Verify dan Upload pada Arduino IDE.

Icon Centang pada Arduino IDE hanyalah proses verify. Biasanya digunakan untuk Compile program untuk mengetahui apakah ada error atau tidak .

Icon panah pada Arduino IDE adalah proses verify dan upload. Biasanya digunakan untuk Compile program sekaligus Flash Program pada target board.

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

Gambar Halaman Arduino IDE Setelah Upload Berhasil.

Setelah selesai upload program, Anda dapat melihat serial monitor untuk melakukan debug program. Icon serial monitor terlihat pada gambar berikut.

Gambar Icon Serial Monitor pada Arduino IDE.

Atur serial baud rate menjadi 115200 dan pilih BothNL & CR. Hasilnya akan terlihat seperti gambar berikut.

Pastikan serial baud rate sesuai dengan nilai yang terdefinisi di kode program. Jika serial baud rate tidak sama, antara kode program dan serial monitor maka karakter ASCII tidak akan terbaca dengan baik.

Gambar Serial Monitor

5. Periksa Data di Antares

Setelah upload program berhasil, selanjutnya buka halaman device antares kemudian lihat apakah data sudah berhasil dikirim.

Gambar Halaman Console Ketika Data Berhasil Diterima

Data yang dikirimkan dari ESP8266 dengan protokol HTTP berupa variabel temperature dan humidity.