Mengontrol Relay dan LED Melalui Perintah Get

Pendahuluan

Pada project ini, Anda akan menggunakan Shield Workshop Antares pada modul ESP8266 . Pada Shield Workshop Antares ini terdapat sensor suhu, kelembapan (DHT11), relay, LED, dan push button. Anda akan melakukan publish data menggunakan MQTTX yang berisi perintah untuk mengontrol LED dan relay. Kemudian ESP8266 melakukan Subscribe Data ke Antares IoT Platform yang berisi dua opsi perintah, yaitu apabila masukan Relay bernilai 1 maka relay akan menyala; masukan Relay bernilai 0 maka relay akan mati; LED bernilai 1 maka LED akan menyala; masukan LED bernilai 0 maka LED akan mati.

Prasyarat

Material yang dibutuhkan mengikuti Prasyarat Umum pada laman sebelumnya. Jika Anda belum menyiapkan kebutuhan pada laman tersebut, maka Anda dapat mengunjungi laman berikut.

Adapun tambahan material yang spesifik untuk project ini adalah sebagai berikut.

1. Shield Workshop Antares

1. Library Antares ESP MQTT. Pada dokumentasi ini menggunakan library Antares ESP MQTT versi 1.0.

1. Software MQTTX

Langkah Kerja

1. Jalankan Aplikasi Arduino IDE

2. Membuka Contoh Program

Berikut adalah kode program dari contoh RETRIEVE_DATA_RELAY_LED.

// Include necessary libraries
#include <AntaresESPMQTT.h> // Include the ESP8266 MQTT library

// Replace these with your own credentials
#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"   // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"     // Replace with the Antares device name that was created

#define relayPin D6 // Define the pin connected to the Relay
#define ledPin D2   // Define the pin connected to the LED

const unsigned long interval = 10000;    // 10 s interval to send message
unsigned long previousMillis = 0;  // will store last time message sent

AntaresESPMQTT antares(ACCESSKEY);

void callback(char topic[], byte payload[], unsigned int length) {
  antares.get(topic, payload, length);

  Serial.println("New Message!");
  Serial.println("Topic: " + antares.getTopic());
  Serial.println("Payload: " + antares.getPayload());

  String relayValue = antares.getString("Relay"); // Change data field to "Relay"
  String ledValue = antares.getString("LED");     // Add reading for "LED" data field
  // Control relay based on received data
  if (relayValue == "1") {
  digitalWrite(relayPin, HIGH);
  } 
  else if (relayValue == "0") {
  digitalWrite(relayPin, LOW);
  }

  // Control LED based on received data
  if (ledValue == "1") {
  digitalWrite(ledPin, HIGH);
  } 
  else if (ledValue == "0") {
  digitalWrite(ledPin, LOW);
  }

  Serial.println("Received data - Relay: " + relayValue + " | LED: " + ledValue);
  
}

void setup() {
    Serial.begin(115200); // Initialize serial communication
    antares.setDebug(true); // Enable debugging for Antares
    antares.wifiConnection(WIFISSID, PASSWORD); // Connect to WiFi
    antares.setMqttServer();
    antares.setCallback(callback);
    pinMode(relayPin, OUTPUT); // Set relayPin as an output
    pinMode(ledPin, OUTPUT); // Set ledPin as an output
}

void loop() {
 /*
    Check if we're still connected to the MQTT broker/server.
    If disconnected, the device will try to reconnect.
   */
  antares.checkMqttConnection();
}

3. Set Credential WiFi dan Credential Antares pada Kode Program

Ubah parameter Protokol HTTP pada variabel berikut *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, dan *deviceName. Sesuaikan dengan parameter di console Antares.

#define ACCESSKEY "your-access-key" // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid" // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password" // Replace with your Wi-Fi password

#define projectName "your-project-name"   // Antares project name
#define deviceName "YOUR-DEVICE-NAME-"    // Antares device name

4. Compile dan Upload Program

Hubungkan ESP8266 WEMOS D1R2 dengan komputer Anda dan pastikan Communication Port terbaca.

Atur board ESP8266 WEMOS D1R2 dengan klik Tools > Board > esp8266 pada Arduino IDE, kemudian pastikan yang digunakan adalah LOLIN(WEMOS) D1 R2 & mini. Pilih port sesuai communication port yang terbaca (dalam kasus ini COM4). Hasilnya akan terlihat seperti gambar berikut.

Setelah semua setup selesai, lakukan upload program dengan menekan icon panah seperti gambar berikut. Tunggu hingga selesai proses compile dan upload

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

Setelah selesai upload program, Anda dapat melihat serial monitor untuk melakukan debug program. Icon serial monitor terlihat pada gambar berikut.

Atur serial baud rate menjadi 115200 dan pilih BothNL & CR. Hasilnya akan terlihat seperti gambar berikut.

5. Setup Software MQTTX

Buka Aplikasi MQTTX, lalu pilih New Connection

Agar dapat terconfigurasi antara MQTTX dengan broker Antares, sesuaikan Name, Host dan Port seperti yang ditunjukan di bawah ini, setelah itu klik Connect

Jika sudah terkoneksi maka terdapat notifikasi seperti gambar berikut

Untuk melakukan publish ke server Antares masukan Topic dan Payload pada kolom di MQTTX.

{
      "m2m:rqp": {
        "fr": "your-access-key",
        "to": "/antares-cse/antares-id/nama-aplikasi-anda/nama-device-anda",
        "op": 1,
        "rqi": 123456,
        "pc": {
          "m2m:cin": {
            "cnf": "message",
            "con": "{\"your-first-data\":\"the-integer-value\",\"your-second-data\":\"the-string-data\"}"
          }
        },
        "ty": 4
      }
    }

Pada software MQTTX masukan Topic dan Payload yang ingin digunakan. Kemudian klik Publish untuk mengirimkan pesan dari MQTTX ke server Antares.

6. Mengirim Pesan MQTTX ke Server Antares

Setelah setup software MQTTX selesai, saatnya mengirimkan perintah PUBLISH. Pada field "Relay" diisi dengan string "1" untuk RELAY ON atau "0" untuk RELAY OFF. Pada field "LED" diisi dengan string "1" untuk LED ON atau "0" untuk LED OFF. Field "Relay" dan "LED" ini merupakan pesan perintah untuk mengendalikan Relay dan LED yang akan dikirim melalui protokol HTTP ke server Antares.

{
      "m2m:rqp": {
        "fr": "your-access-key",
        "to": "/antares-cse/antares-id/nama-aplikasi-anda/nama-device-anda",
        "op": 1,
        "rqi": 123456,
        "pc": {
          "m2m:cin": {
            "cnf": "message",
            "con": "{\"Relay\":\"1\",\"LED\":\"1\"}"
          }
        },
        "ty": 4
      }
    }

Jika sudah selesai mengisi field "Relay" dan "LED" selanjutnya tekan tombol PUBLISH pada software MQTTX yang terletak di sebelah kanan kolom pengisian Topic, seperti pada gambar berikut.

Jika sudah publish maka laman MQTTX akan terdapat Message seperti berikut.

7. Periksa Data di Antares

Setelah upload program berhasil, selanjutnya buka halaman device antares kemudian lihat apakah data sudah berhasil dikirim.

8. Output program

Get data dari Antares IoT Platform dan ditampilkan pada display OLED setelah terhubung ke Wi-Fi tertampil pada gambar dibawah ini: