Retrieve Data ditampilkan pada Display OLED

Pendahuluan

Pada project ini, Anda akan menampilkan data dari Antares IoT Platform pada OLED dengan menggunakan modul ESP8266 . Pada Shield Workshop Antares ini terdapat sensor suhu, kelembapan (DHT11), relay, LED, dan push button. Anda akan mengirim pesan berupa data ditampilkan pada display OLED. Proses pengiriman data ini menggunakan Software MQTTX untuk mengirimkan data ke Antares IoT Platform.

Prasyarat

Material yang dibutuhkan mengikuti Prasyarat Umum pada laman sebelumnya. Jika Anda belum menyiapkan kebutuhan pada laman tersebut, maka Anda dapat mengunjungi laman berikut.

Prasyarat Umum ESP8266 Wi-Fi

Adapun tambahan material yang spesifik untuk project ini adalah sebagai berikut.

1. Shield Workshop Antares

Gambar WEMOS D1R2 Menampilkan Data pada OLED

1. Modul OLED SSD1036 0,96inch 128x64 pixel berbasis I2C

Gambar Modul OLED SSD1036 0.96inch

1. Library display OLED. Pada dokumentasi ini menggunakan Adafruit_SSD1306 by Adafruit versi 2.5.7.

Jika Anda belum menginstall library Adafruit SSD1306 by Adafruit versi 2.5.7. dapat mengikuti langkah pada link berikut.

Adafruit SSD1306

1. Software MQTTX

Jika Anda belum menginstall Software MQTTX dapat mengikuti langkah pada link berikut.

Instalasi MQTTX

Langkah Kerja

1. Jalankan Aplikasi Arduino IDE

2. Membuka Contoh Program

Kode program dapat Anda buka pada Arduino IDE melalui File > Example > Antares ESP MQTT > ESP8266-Simple-Project > RETRIEVE_DATA_OLED.

Berikut adalah kode program dari contoh RETRIEVE_DATA_OLED.

#include <AntaresESPMQTT.h>    // Import the AntaresESPMQTT library for communication with Antares
#include <Adafruit_SSD1306.h>  // Import the Adafruit_SSD1306 library for controlling the OLED display

#define ACCESSKEY "your-access-key"    // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid"      // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password"  // Replace with your Wi-Fi password

#define projectName "your-project-name"  // Antares project name
#define deviceName "your-project-name"   // Name of the device

AntaresESPMQTT antares(ACCESSKEY);  // Initialize the AntaresESPMQTT object with the access key

#define SCREEN_WIDTH 128  // OLED display width
#define SCREEN_HEIGHT 64  // OLED display height
#define OLED_RESET -1     // OLED display reset pin

String testData;       // Store received mqtt data
String lastData = "";  // Store last received mqtt data

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);  // Initialize the display object

void callback(char topic[], byte payload[], unsigned int length) {
  antares.get(topic, payload, length);

  Serial.println("New Message!");
  Serial.println("Topic: " + antares.getTopic());
  Serial.println("Payload: " + antares.getPayload());

  testData = antares.getString("Test");
  Serial.println("Received: " + testData);
  if (testData != "null") {
    if (lastData != testData) {
      lastData = testData;
      display.clearDisplay();
      display.setTextSize(1);
      display.setTextColor(SSD1306_WHITE);
      display.setCursor(0, 0);
      display.println("Received: " + testData);
      display.display();
    }
  }
}

void setup() {
  Serial.begin(115200);                        // Start serial communication at baud rate 115200
  antares.setDebug(true);                      // Enable debug mode for Antares
  antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to Wi-Fi using SSID and password
  antares.setMqttServer();                     // Set up the Antares MQTT server
  antares.setCallback(callback);               // Set the callback function for MQTT messages

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {  // Initialize the OLED display
    Serial.println(F("SSD1306 allocation failed"));  // Display a message if OLED initialization fails
    for (;;)
      ;  // Halt the program
  }

  display.clearDisplay();                  // Clear the OLED display
  display.setTextSize(1);                  // Set text size
  display.setTextColor(SSD1306_WHITE);     // Set text color
  display.setCursor(0, 0);                 // Set text cursor position
  display.println("Waiting for data...");  // Display initial message
  display.display();                       // Show the message on the display
}

void loop() {
  antares.checkMqttConnection();  // Check MQTT connection to Antares
}

3. Set Credential WiFi dan Credential Antares pada Kode Program

Ubah parameter Protokol HTTP pada variabel berikut *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, dan *deviceName. Sesuaikan dengan parameter di console Antares.

#define ACCESSKEY "your-access-key" // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid" // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password" // Replace with your Wi-Fi password

#define projectName "your-project-name"   // Antares project name
#define deviceName "your-project-name"   // Name of the device

Parameter *Access key didapat dari laman akun Antares Anda.

Letak Access Key di Laman Akun Antares

Parameter WIFISSID didapat dari nama Wifi/Hotspot yang sedang digunakan oleh Anda. contohnya pada gambar di bawah ini.

WiFi SSID yang digunakan.

Parameter *PASSWORD didapat dari password WiFi yang sedang anda gunakan.

Parameter *projectName dan *deviceName didapat dari Application Name dan Device Name yang sudah dibuat dalam akun Antares.

Tampilan Application Name

Tampilan Device Name

4. Compile dan Upload Program

Hubungkan ESP8266 WEMOS D1R2 dengan komputer Anda dan pastikan Communication Port terbaca.

Pada sistem operasi Windows pengecekan dapat dilakukan melalui Device Manager. Jika ESP8266 WEMOS D1R2 Anda terbaca maka tampil USB-Serial CH340 dengan port menyesuaikan ketersediaan port (pada kasus ini terbaca COM4).

Gambar Device Manager pada Windows.

Atur board ESP8266 WEMOS D1R2 dengan klik Tools > Board > esp8266 pada Arduino IDE, kemudian pastikan yang digunakan adalah LOLIN(WEMOS) D1 R2 & mini. Pilih port sesuai communication port yang terbaca (dalam kasus ini COM4). Hasilnya akan terlihat seperti gambar berikut.

Gambar Menu Tools pada Arduino IDE

Setelah semua setup selesai, lakukan upload program dengan menekan icon panah seperti gambar berikut. Tunggu hingga selesai proses compile dan upload

Gambar Icon Verify dan Upload pada Arduino IDE.

Icon Centang pada Arduino IDE hanyalah proses verify. Biasanya digunakan untuk Compile program untuk mengetahui apakah terdapat error atau tidak .

Icon Panah pada Arduino IDE adalah proses verify dan upload. Biasanya digunakan untuk Compile program sekaligus Flash Program pada target board.

Jika upload program berhasil maka akan terlihat seperti gambar berikut.

Gambar Halaman Arduino IDE Setelah Upload Berhasil.

Setelah selesai upload program, Anda dapat melihat serial monitor untuk melakukan debug program. Icon serial monitor terlihat pada gambar berikut.

Gambar Icon Serial Monitor pada Arduino IDE.

Atur serial baud rate menjadi 115200 dan pilih BothNL & CR. Hasilnya akan terlihat seperti gambar berikut.

Pastikan serial baud rate sesuai dengan nilai yang terdefinisi di kode program. Jika serial baud rate tidak sama, antara kode program dan serial monitor maka karakter ASCII tidak akan terbaca dengan baik.

Gambar Serial Monitor

5. Setup Software MQTTX

Buka Aplikasi MQTTX, lalu pilih New Connection

Membuat New Connection

Agar dapat terconfigurasi antara MQTTX dengan broker Antares, sesuaikan Name, Host dan Port seperti yang ditunjukan di bawah ini, setelah itu klik Connect

Antares MQTT Broker Configuration

Jika sudah terkoneksi maka terdapat notifikasi seperti gambar berikut

Antares Broker MQTTX Connected

Untuk melakukan publish ke server Antares masukan Topic dan Payload pada kolom di MQTTX.

Laman Topic dan Payload pada MQTTX

Field	Value
Topic	/oneM2M/req/your-access-key/antares-cse/json
Payload	{ "m2m:rqp": { "fr": "your-access-key", "to": "/antares-cse/antares-id/nama-aplikasi-anda/nama-device-anda", "op": 1, "rqi": 123456, "pc": { "m2m:cin": { "cnf": "message", "con": "{\"your-first-data\":\"the-integer-value\",\"your-second-data\":\"the-string-data\"}" } }, "ty": 4 } }

Sesuaikan your-access-key, nama-aplikasi-anda, dan nama-device-anda sesuai nama-nama yang terdaftar pada akun Antares Anda. Isikan pula "Field" data dan "Nilai" data pada "con" sesuai yang Anda inginkan.

Pada software MQTTX masukan Topic dan Payload yang ingin digunakan. Kemudian klik Publish untuk mengirimkan pesan dari MQTTX ke server Antares.

Publish untuk mengirim pesan ke server Antares

6. Mengirim Pesan MQTTX ke Server Antares

Setelah setup software MQTTX selesai, saatnya mengirimkan perintah PUBLISH. Pada field "Test" diisi dengan string "Hallo Antares" sebagai pesan yang akan dikirim melalui protokol MQTT ke server Antares.

{
      "m2m:rqp": {
        "fr": "your-access-key",
        "to": "/antares-cse/antares-id/nama-aplikasi-anda/nama-device-anda",
        "op": 1,
        "rqi": 123456,
        "pc": {
          "m2m:cin": {
            "cnf": "message",
            "con": "{\"Test\":\"Hallo Antares\"}"
          }
        },
        "ty": 4
      }
    }

Jika sudah selesai mengisi field "Test" selanjutnya tekan tombol Publish pada software MQTTX, seperti pada gambar berikut.

Gambar isi Payload MQTTX

Jika sudah publish maka laman MQTTX akan terdapat Message seperti berikut.

Notifikasi Message Published

7. Periksa Data di Antares

Setelah upload program berhasil, selanjutnya buka halaman device antares kemudian lihat apakah data sudah berhasil dikirim.

Gambar Halaman Console Antares Ketika Data Berhasil Diterima.

Data yang diterima oleh ESP8266 dengan protokol MQTT berupa variabel Test.

8. Output program

Get data dari Antares IoT Platform dan ditampilkan pada display OLED setelah terhubung ke Wi-Fi tertampil pada gambar dibawah ini:

Hasil Retrieve Data MQTTX ditampilkan pada OLED