Post and Get DHT 11 Data displayed on OLED

In this project, you will use the Antares Workshop Shield on the Lynx-32 Development Board module. In this Antares Shield Workshop, there are temperature, humidity (DHT11), relay, LED, and push button sensors. You will monitor the temperature and humidity with a specified interval period. The data sent by the sensors can be monitored through the Antares console and displayed on the OLED. You can also send messages in the form of string data displayed on the OLED display. This data transmission process uses POSTMAN software to send data to the Antares IoT Platform.

Prerequisites

The materials required follow the General Prerequisites on the previous page. If you have not prepared the requirements on that page, then you can visit the following page.

General Prerequisites ESP32 Wi-Fi

The additional materials specific to this project are as follows.

1. Shield Workshop Antares

2. I2C-based 0.96inch 128x64 pixel SSD1036 OLED module

SSD1036 0.96inch OLED Module Picture

1. Antares ESP HTTP Library. This documentation uses the Antares ESP HTTP library version 1.4.0.

If you have not installed Antares ESP HTTP 1.4.0, please follow these steps.

Antares Wi-Fi HTTP

1. DHT11 Library. This documentation uses DHT11 Sensor Library version 1.4.4.

If you have not installed the DHT11 Sensor Library version 1.4.4. you can follow the steps in the following link.

DHT11 Sensor Library

1. SSD1306 OLED Library. This documentation uses Adafruit SSD1306 by Adafruit version 2.5.7.

If you have not installed the Adafruit SSD1306 by Adafruit library version 2.5.7. you can follow the steps in the following link.

1. Postman Software

If you have not installed POSTMAN Software, you can follow the steps in the following link.

Postman Installation

Follow These Steps

1. Launch the Arduino IDE application

2. Opening Sample Programme

You can open the programme code in the Arduino IDE via File > Examples > Antares ESP HTTP > Lynx32-Simple-Project > POST_DATA_GET_DATA_OLED.

Here is the programme code of the POST_DATA_GET_DATA_OLED. example.

#include <AntaresESPHTTP.h>     // Include the AntaresESP32HTTP library
#include <Adafruit_SSD1306.h>     // Include the Adafruit SSD1306 library
#include "DHT.h"                  // Include the DHT sensor library

#define DHTPIN 14                   // Digital pin connected to the DHT sensor
#define DHTTYPE DHT11               // Type of DHT sensor (DHT11 in this case)

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"          // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNamePostman "YOUR-DEVICE-NAME-2"     // Name of the device receiving data

AntaresESPHTTP antares(ACCESSKEY);   // Initialize AntaresESP32HTTP with the access key
DHT dht(DHTPIN, DHTTYPE);              // Initialize DHT sensor object

#define SCREEN_WIDTH 128         // OLED screen width in pixels
#define SCREEN_HEIGHT 64         // OLED screen height in pixels
#define OLED_RESET -1            // Reset pin for the OLED (not used in this case)

const unsigned long interval = 5000;     // Interval to send sensor data (5 seconds)
const unsigned long interval2 = 10000;   // Interval to get data from Antares (10 seconds)
unsigned long previousMillis = 0;        // Store the last time sensor data was sent
unsigned long previousMillis2 = 0;       // Store the last time data was received from Antares

String testData;            // String to hold received data from Antares
String lastData="";         // String to store last received data

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);   // Initialize OLED display object

bool showSensorData = true;   // Boolean to control display of sensor data

void setup() {
  Serial.begin(115200);      // Initialize serial communication
  antares.setDebug(true);    // Enable Antares library debug mode
  antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to WiFi using provided SSID and password
  dht.begin();               // Initialize the DHT sensor

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {   // Initialize the OLED display
    Serial.println(F("SSD1306 allocation failed"));
    for (;;)
      ;
  }

  display.clearDisplay();    // Clear the OLED display buffer
  display.display();         // Display the cleared buffer
}

void loop() {
  
   if (millis() - previousMillis > interval) {     // Check if it's time to send sensor data
    previousMillis = millis();                    // Update the last sent time
    
    float hum = dht.readHumidity();                // Read humidity from the DHT sensor
    float temp = dht.readTemperature();            // Read temperature from the DHT sensor
    if (isnan(hum) || isnan(temp)) {
        Serial.println("Failed to read DHT sensor!");  // Print an error message if sensor reading fails
        return;
    }
    antares.add("temperature", temp);              // Add temperature data to the Antares payload
    antares.add("humidity", hum);                  // Add humidity data to the Antares payload
    antares.send(projectName, deviceNameSensor);   // Send sensor data to Antares
    display.clearDisplay();                        // Clear the OLED display buffer
    display.setTextSize(1);                        // Set text size on the display
    display.setTextColor(SSD1306_WHITE);           // Set text color to white
    display.setCursor(0, 0);                       // Set cursor position on the display
    display.println("Temp: " + String(temp) + " *C");     // Display temperature
    display.println("Humidity: " + String(hum) + " %");  // Display humidity
    display.display();                             // Display the updated buffer on the OLED
    }
    
    if (millis() - previousMillis2 > interval2) {   // Check if it's time to get data from Antares
    previousMillis2 = millis();                    // Update the last received time
    
    antares.get(projectName, deviceNamePostman);   // Get data from Antares
    
    if (antares.getSuccess()) {                    // Check if data retrieval was successful
      testData = antares.getString("Test Data");   // Get the "Test Data" field from the response

      if(lastData != testData)                     // Check if the received data is different from the last one
      {
        lastData = testData;                       // Update the last received data
        Serial.println("Received Data: " + testData);   // Print received data to the serial monitor
        display.clearDisplay();                    // Clear the OLED display buffer
        display.setTextSize(1);                    // Set text size on the display
        display.setTextColor(SSD1306_WHITE);       // Set text color to white
        display.setCursor(0, 0);                   // Set cursor position on the display
        display.println("Received:");              // Display "Received:"
        display.println(testData);                 // Display the received data
        display.display();                         // Display the updated buffer on the OLED
        delay(2000);                               // Display received data for 2 seconds
      }
     }
    }

}

3. Set WiFi Credential and Antares Credential in Program Code

Change the HTTP Protocol parameters in the following variables *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, and *deviceName. Adjust to the parameters in the Antares console.

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"          // Antares project name
#define deviceNameSensor "YOUR-DEVICE-NAME-1"   // Name of the device sending sensor data
#define deviceNamePostman "YOUR-DEVICE-NAME-2"     // Name of the device receiving data

The *Access key parameter is obtained from your Antares account page.

Access Key Location on Antares Account Page

The WIFISSID parameter is obtained from the name of the Wifi / Hotspot that is currently being used by you. for example in the image below.

WIFISSID

The *PASSWORD parameter is obtained from the WiFi password you are currently using.

The parameters *projectName and *deviceName are obtained from the Application Name and Device Name that have been created in the Antares account.

Application Name Display

Device Name Display

4. Compile and Upload Program

Connect the Lynx-32 with your computer and make sure the Communication Port is read.

On Windows operating systems the check can be done via Device Manager. If your Lynx-32 is read then the USB-Serial CH340 appears with the port adjusting the port availability (in this case it reads COM4).

Device Manager Display

Set up the ESP32 board by clicking Tools > Board > esp32 in the Arduino IDE, then make sure the ESP32 Dev Module is used. Select the port according to the communication port that is read (in this case COM4). The result will look like the following image.

Display of Board Specifications and Ports Used

After all the setup is complete, upload the programme by pressing the arrow icon as shown below. Wait for the compile and upload process to finish

Compile Icon for Tick and Upload Icon for Arrow

The Tick icon on the Arduino IDE is just the verify process. Usually used to Compile the programme to find out whether there are errors or not.

The Arrow icon on the Arduino IDE is the verify and upload process. Usually used to Compile the programme as well as Flash the programme to the target board.

If the programme upload is successful, it will look like the following image.

Arduino IDE page image after successful upload.

After uploading the programme, you can view the serial monitor to debug the programme. The serial monitor icon is shown in the following image.

Serial Monitor Icon

Set the serial baud rate to 115200 and select BothNL & CR. The result will look like the following image.

Serial Monitor Display

Make sure the serial baud rate matches the value defined in the programme code. If the serial baud rate is not the same between the programme code and the serial monitor, the ASCII characters will not be read properly.

5. Setup POSTMAN Software

In this step you need POSTMAN software, you can input the end-point, request header and request body first by following the following format.

End Point

Method	POST
URL	https://platform.antares.id:8443/~/antares-cse/antares-id/your-application-name/your-device-name

Customise your-application-name and your-device-name to the names registered to your Antares account.

Request Header

Key	Value
X-M2M-Origin	your-access-key
Content-Type	application/json;ty=4
Accept	application/json

Customise your-access-key with your Antares account access key.

The result will be as shown below.

Image of end-point and header settings in POSTMAN software.

Next, you need to input the request body by following the following format.

Request Body

{
  "m2m:cin": {
    "con": "{\"key1\":\"integer-value\", \"key2\":\"string-value\", \"keyN\":\"valueN\"}"
  }
}

In the POSTMAN software, select the Body tab then select raw and enter the payload according to the request body you want to use as shown below.

Image of the contents of the payload request body in POSTMAN software.

Customise the contents of the "con" field according to the "key" and "value" you want to send.

6. Customise the contents of the "con" field according to the "key" and "value" you want to send.

After the POSTMAN software setup is complete, it's time to send the POST command. The "Test Data" field is filled with the string "Halloo Test" as the message to be sent via HTTP protocol to the Antares server.

{
  "m2m:cin": {
    "con": "{\"Test Data\":\"Halloo Test\"}"
  }
}

If you have finished filling in the "Test Data" field, then press the Send button on the POSTMAN software. It

Image of API hit response in POSTMAN software.

7. Check Data in Antares

After uploading the programme successfully, then open the device antares page and see if the data has been successfully sent.

Image of the Antares Console Page when data is successfully received from POSTMAN.

Image of the Antares Console Page When Data is Successfully Received from the DHT11 Sensor.

The data received by Lynx-32 with the HTTP protocol is in the form of Test Data variables.

8. Viewing Get Messages

Get data from the Antares IoT Platform and display it on the OLED display after connecting to Wi-Fi is shown in the figure below:

Oled Display Result Message from POSTMAN.

Oled Display Results Showing Temperature and Humidity.