Periodic Send DHT 11 Data

In this project, you will use the Antares Workshop Shield on the Lynx-32 Development Board module. In this Antares Shield Workshop, there are temperature, humidity (DHT11), relay, LED and push button sensors. You will monitor the temperature and humidity according to the specified interval period. The results of the data sent by the sensors can be monitored through the Antares console.

Prerequisites

The materials required follow the General Prerequisites on the previous page. If you have not prepared the requirements on that page, then you can visit the following page.

General Prerequisites ESP32 Wi-Fi

The additional materials specific to this project are as follows.

1. Shield Workshop Antares

2. Antares ESP HTTP Library. This documentation uses the Antares ESP MQTT library version 1.0.

If you have not installed Antares ESP MQTT version 1.0, you can follow these steps.

Antares Wi-Fi MQTT

1. DHT11 Library. This documentation uses DHT11 Sensor Library version 1.4.4.

If you have not installed the DHT11 Sensor Library version 1.4.4. you can follow the steps in the following link.

DHT11 Sensor Library

Follow These Steps

1. Launch the Arduino IDE application

2. Opening Sample Programme

You can open the programme code in the Arduino IDE via File > Examples > Antares ESP MQTT > Lynx32-Simple-Project > SEND_DATA_DHT11.

The following is the sample programme code for SEND_DATA_DHT11.

// Include necessary libraries
#include <AntaresESPMQTT.h> // Library initiation for Antares ESP32 MQTT
#include "DHT.h"            // Library initiation for DHT11 sensor
#define DHTPIN 14           // Create a variable DHTPIN, pointing to pin 14
#define DHTTYPE DHT11       // Specify the DHT type to be DHT11

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"   // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"     // Replace with the Antares device name that was created

const unsigned long interval = 10000;    // 10 s interval to send message
unsigned long previousMillis = 0;  // will store last time message sent

AntaresESPMQTT antares(ACCESSKEY);    // Create an object for interacting with Antares
DHT dht(DHTPIN, DHTTYPE);   // Create an object for the DHT11 sensor

void setup() {
  Serial.begin(115200);     // Initialize serial communication with baudrate 115200
  antares.setDebug(true);   // Turn on debugging. Set to "false" if you don't want messages to appear on the serial monitor
  antares.wifiConnection(WIFISSID, PASSWORD);  // Attempt to connect to Wi-Fi
  antares.setMqttServer();
  dht.begin();             // Initialize the DHT11 sensor
}

void loop() {
  antares.checkMqttConnection();
  if (millis() - previousMillis > interval) {
    previousMillis = millis();
  
    float hum = dht.readHumidity();      // Read the humidity value from the DHT11 sensor
    float temp = dht.readTemperature();  // Read the temperature value from the DHT11 sensor
    
    if (isnan(hum) || isnan(temp)) {     // Check if there's an error reading the sensor
      Serial.println("Failed to read DHT sensor!");
      return;
    }
    
    Serial.println("Temperature: " + (String)temp + " *C");  // Print the temperature in Celsius
    Serial.println("Humidity: " + (String)hum + " %");       // Print the humidity as a percentage

    // Add the temperature and humidity data to the storage buffer
    antares.add("temperature", temp);
    antares.add("humidity", hum);
  
    // Send the data from the storage buffer to Antares
    antares.publish(projectName, deviceName);
  }
}

3. Set MQTT Parameters in Programme Code

Change the HTTP Protocol parameters in the following variables *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, and *deviceName. Adjust to the parameters in the Antares console.

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"   // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"     // Replace with the Antares device name that was created

The *Access key parameter is obtained from your Antares account page.

Access Key Location on Antares Account Page

The WIFISSID parameter is obtained from the Wi-Fi/Hotspot name that will be used by the Lynx-32 Development Board. An example is shown below.

WIFISSID

The *PASSWORD parameter is obtained from the Wi-Fi password you are currently using.

The parameters *projectName and *deviceName are obtained from the Application Name and Device Name that have been created in the Antares account.

Application Name Display

Device Name Display

4. Compile and Upload Program

Connect the Lynx-32 with your computer and make sure the Communication Port is read.

On Windows operating systems the check can be done via Device Manager. If your Lynx-32 is read then the USB-Serial CH340 appears with the port adjusting the port availability (in this case it reads COM4).

Device Manager Display

Set up the ESP32 board by clicking Tools > Board > esp32 in the Arduino IDE, then make sure the ESP32 Dev Module is used. Select the port according to the communication port that is read (in this case COM4). The result will look like the following image.

Display of Board Specifications and Ports Used

Display of Board Specifications and Ports Used

After all the setup is complete, upload the programme by pressing the arrow icon as shown below. Wait for the compile and upload process to finish

Compile Icon for Tick and Upload Icon for Arrow

The Tick icon on the Arduino IDE is just the verify process. Usually used to Compile the programme to find out whether there are errors or not. The Arrow icon on the Arduino IDE is the verify and upload process. Usually used to Compile the programme as well as Flash the programme to the target board.

If the programme upload is successful, it will look like the following image.

Arduino IDE page image after successful upload.

After uploading the programme, you can view the serial monitor to debug the programme. The serial monitor icon is shown in the following image.

Serial Monitor Icon

Set the serial baud rate to 115200 and select BothNL & CR. The result will look like the following image.

Serial Monitor Display

Make sure the serial baud rate matches the value defined in the programme code. If the serial baud rate is not the same between the programme code and the serial monitor, the ASCII characters will not be read properly.

5. Check Data in Antares

After uploading the programme successfully, then open the device antares page and see if the data has been successfully sent.

Antares Console Display

Data sent from the Lynx-32 Development Board with the MQTT protocol in the form of temperature and humidity variables.