Retrieve Data displayed on OLED Display

In this project, you will display data from Antares IoT Platform on OLED using ESP8266 module. In this Antares Shield Workshop, there are temperature, humidity (DHT11), relay, LED, and push button sensors. You will send messages in the form of data displayed on the OLED display. The process of sending this data uses MQTTX Software to send data to the Antares IoT Platform.

Image of WEMOS D1R2 Displaying Data on OLED

Prerequisites

The materials required follow the General Prerequisites on the previous page. If you have not prepared the requirements on that page, then you can visit the following page.

pageGeneral Prerequisites ESP8266 Wi-Fi

The additional materials specific to this project are as follows.

1. Shield Workshop Antares

2. I2C-based 0.96inch 128x64 pixel SSD1036 OLED module

SSD1036 0.96inch OLED Module Image

3. OLED display library. This documentation uses Adafruit_SSD1306 by Adafruit version 2.5.7.

If you have not installed the Adafruit SSD1306 by Adafruit library version 2.5.7. you can follow the steps in the following link.

4. MQTTX Software

If you have not installed the MQTTX Software, you can follow the steps in the following link.

MQTTX Installation

Follow These Steps

1. Launch the Arduino IDE application

2. Opening Sample Programme

You can open the programme code in the Arduino IDE via File > Example > Antares ESP MQTT > ESP8266-Simple-Project > RETRIEVE_DATA_OLED.

Below is the programme code of the RETRIEVE_DATA_OLED example.

#include <AntaresESPMQTT.h>    // Import the AntaresESPMQTT library for communication with Antares
#include <Adafruit_SSD1306.h>  // Import the Adafruit_SSD1306 library for controlling the OLED display

#define ACCESSKEY "your-access-key"    // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid"      // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password"  // Replace with your Wi-Fi password

#define projectName "your-project-name"  // Antares project name
#define deviceName "your-project-name"   // Name of the device

AntaresESPMQTT antares(ACCESSKEY);  // Initialize the AntaresESPMQTT object with the access key

#define SCREEN_WIDTH 128  // OLED display width
#define SCREEN_HEIGHT 64  // OLED display height
#define OLED_RESET -1     // OLED display reset pin

String testData;       // Store received mqtt data
String lastData = "";  // Store last received mqtt data

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);  // Initialize the display object

void callback(char topic[], byte payload[], unsigned int length) {
  antares.get(topic, payload, length);

  Serial.println("New Message!");
  Serial.println("Topic: " + antares.getTopic());
  Serial.println("Payload: " + antares.getPayload());

  testData = antares.getString("Test");
  Serial.println("Received: " + testData);
  if (testData != "null") {
    if (lastData != testData) {
      lastData = testData;
      display.clearDisplay();
      display.setTextSize(1);
      display.setTextColor(SSD1306_WHITE);
      display.setCursor(0, 0);
      display.println("Received: " + testData);
      display.display();
    }
  }
}

void setup() {
  Serial.begin(115200);                        // Start serial communication at baud rate 115200
  antares.setDebug(true);                      // Enable debug mode for Antares
  antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to Wi-Fi using SSID and password
  antares.setMqttServer();                     // Set up the Antares MQTT server
  antares.setCallback(callback);               // Set the callback function for MQTT messages

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {  // Initialize the OLED display
    Serial.println(F("SSD1306 allocation failed"));  // Display a message if OLED initialization fails
    for (;;)
      ;  // Halt the program
  }

  display.clearDisplay();                  // Clear the OLED display
  display.setTextSize(1);                  // Set text size
  display.setTextColor(SSD1306_WHITE);     // Set text color
  display.setCursor(0, 0);                 // Set text cursor position
  display.println("Waiting for data...");  // Display initial message
  display.display();                       // Show the message on the display
}

void loop() {
  antares.checkMqttConnection();  // Check MQTT connection to Antares
}

3. Set WiFi Credential and Antares Credential in Program Code

Change the HTTP Protocol parameters in the following variables *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, and *deviceName. Adjust to the parameters in the Antares console.

#define ACCESSKEY "your-access-key" // Replace with your Antares account access key
#define WIFISSID "your-wifi-ssid" // Replace with your Wi-Fi SSID
#define PASSWORD "your-wifi-password" // Replace with your Wi-Fi password

#define projectName "your-project-name"   // Antares project name
#define deviceName "your-project-name"   // Name of the device

The *Access key parameter is obtained from your Antares account page.

Access Key Location on Antares Account Page

The WIFISSID parameter is obtained from the name of the Wifi / Hotspot that is currently being used by you for example in the image below.

The WiFi SSID being used.

The *PASSWORD parameter is obtained from the WiFi password you are currently using.

The parameters *projectName and *deviceName are obtained from the Application Name and Device Name that have been created in the Antares account.

Application Name Display

Device Name Display

4. Compile and Upload Program

Connect the ESP8266 WEMOS D1R2 with your computer and make sure the Communication Port is read.

On Windows operating systems, checking can be done via Device Manager. If your ESP8266 WEMOS D1R2 is read, the USB-Serial CH340 appears with the port adjusting the port availability (in this case it reads COM4).

Device Manager image on Windows.

Set up the ESP8266 WEMOS D1R2 board by clicking Tools > Board > esp8266 in the Arduino IDE, then make sure the one used is LOLIN (WEMOS) D1 R2 & mini. Select the port according to the communication port that is read (in this case COM4). The result will look like the following picture.

Image of Tools Menu on Arduino IDE

After all the setup is complete, upload the programme by pressing the arrow icon as shown below. Wait for the compile and upload process to finish.

Image of the Verify and Upload icons in the Arduino IDE.

The Tick icon on the Arduino IDE is just the verify process. Usually used to Compile the programme to find out whether there are errors or not. The Arrow icon on the Arduino IDE is the verify and upload process. Usually used to Compile the programme as well as Flash the programme to the target board.

If the programme upload is successful, it will look like the following image.

Arduino IDE page image after successful upload.

After uploading the programme, you can view the serial monitor to debug the programme. The serial monitor icon is shown in the following image.

Image of the Serial Monitor Icon in the Arduino IDE.

Set the serial baud rate to 115200 and select BothNL & CR. The result will look like the following image.

Make sure the serial baud rate matches the value defined in the programme code. If the serial baud rate is not the same between the programme code and the serial monitor, the ASCII characters will not be read properly.

Serial Monitor Image

5. Setup MQTTX Software

Open the MQTTX App, then select New Connection

Creating a New Connection

In order to configure MQTTX with Antares broker, adjust the Name, Host and Port as shown below, then click Connect.

Antares MQTT Broker Configuration

If it is connected, there is a notification as shown below

Antares Broker MQTTX Connected

To publish to the Antares server, enter Topic and Payload in the fields in MQTTX.

Topic and Payload pages in MQTTX

Field	Value
Topic	/oneM2M/req/your-access-key/antares-cse/json
Payload	{ "m2m:rqp": { "fr": "your-access-key", "to": "/antares-cse/antares-id/nama-aplikasi-anda/nama-device-anda", "op": 1, "rqi": 123456, "pc": { "m2m:cin": { "cnf": "message", "con": "{\"your-first-data\":\"the-integer-value\",\"your-second-data\":\"the-string-data\"}" } }, "ty": 4 } }

Customise your-access-key, your-application-name, and your-device-name to the names registered to your Antares account. Fill in the "Field" data and "Value" data in "con" as you wish.

In the MQTTX software, enter the Topic and Payload that you want to use. Then click Publish to send the message from MQTTX to the Antares server.

Publish to send the message to Antares server

6. Sending MQTTX Messages to Antares Server

After the MQTTX software setup is complete, it's time to send the PUBLISH command. The "Test" field is filled with the string "Hello Antares" as the message that will be sent via the MQTT protocol to the Antares server.

{
      "m2m:rqp": {
        "fr": "your-access-key",
        "to": "/antares-cse/antares-id/nama-aplikasi-anda/nama-device-anda",
        "op": 1,
        "rqi": 123456,
        "pc": {
          "m2m:cin": {
            "cnf": "message",
            "con": "{\"Test\":\"Hallo Antares\"}"
          }
        },
        "ty": 4
      }
    }

If you have finished filling in the "Test" field, then press the Publish button on the MQTTX software, as shown below.

Image of MQTTX Payload content

If it has been published, the MQTTX page will have a message like the following.

Notification Message Published

7. Check Data in Antares

After uploading the programme successfully, then open the device antares page and see if the data has been successfully sent.

Image of the Antares Console Page When Data is Successfully Received.

The data received by ESP8266 with MQTT protocol is in the form of Test variable.

8. Output program

Get data from the Antares IoT Platform and display it on the OLED display after connecting to Wi-Fi is shown in the figure below:

MQTTX Data Retrieve Results displayed on OLED