Controlling Relays and LEDs Through Get Commands

In this project, you will use the Antares Workshop Shield on the Lynx-32 Development Board module. In this Antares Shield Workshop, there are temperature, humidity (DHT11), relay, LED, and push button sensors. You will Post Data using POSTMAN software which contains commands to control the LEDs and relays. Then the Lynx-32 Development Board performs Get Data from the Antares IoT Platform which contains two command options, namely if the Relay input is 1 then the relay will turn on; Relay input is 0 then the relay will turn off; LED is 1 then the LED will turn on; LED input is 0 then the LED will turn off.

Prerequisites

The materials required follow the General Prerequisites on the previous page. If you have not prepared the requirements on that page, then you can visit the following page.

General Prerequisites ESP32 Wi-Fi

The additional materials specific to this project are as follows.

Shield Workshop Antares
Antares ESP HTTP Library. This documentation uses the Antares ESP HTTP library version 1.4.0.

If you have not installed Antares ESP HTTP 1.4.0, please follow these steps.

Antares Wi-Fi HTTP

Postman Software

If you have not installed POSTMAN Software, you can follow the steps in the following link.

Postman Installation

Follow These Steps

1. Launch the Arduino IDE application

2. Opening Sample Programme

You can open the programme code in the Arduino IDE via File > Examples > Antares ESP HTTP > Lynx32-Simple-Project > GET_DATA_RELAY_LED.

Here is the sample programme code of GET_DATA_RELAY_LED.

#include <AntaresESPHTTP.h>     // Include the AntaresESP32HTTP library

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"   // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"     // Replace with the Antares device name that was created

AntaresESPHTTP antares(ACCESSKEY);   // Initialize AntaresESP32HTTP with the access key

#define relayPin  25    // Digital pin for controlling the relay
#define ledPin  12      // Digital pin for controlling the LED

const unsigned long interval = 10000;    // 10 seconds interval to send message
unsigned long previousMillis = 0;  // Will store the last time a message was sent

void setup() {
    Serial.begin(115200);   // Initialize serial communication
    antares.setDebug(true);  // Enable Antares library debug mode
    antares.wifiConnection(WIFISSID, PASSWORD);  // Connect to WiFi using provided SSID and password

    pinMode(relayPin, OUTPUT);  // Set relay pin as output
    pinMode(ledPin, OUTPUT);    // Set LED pin as output
}

void loop() {

    if (millis() - previousMillis > interval) {  // Check if it's time to send a message
        previousMillis = millis();               // Update the last sent time
        
        antares.get(projectName, deviceName);    // Get data from Antares
        
        if (antares.getSuccess()) {              // Check if data retrieval was successful
            String dataValue = antares.getString("Relay");  // Get the value of "Relay" data field
            String ledValue = antares.getString("LED");      // Get the value of "LED" data field

            // Control relay based on received data
            if (dataValue == "1") {
                digitalWrite(relayPin, HIGH);  // Turn on the relay
            } else if (dataValue == "0") {
                digitalWrite(relayPin, LOW);   // Turn off the relay
            }

            // Control LED based on received data
            if (ledValue == "1") {
                digitalWrite(ledPin, HIGH);    // Turn on the LED
            } else if (ledValue == "0") {
                digitalWrite(ledPin, LOW);     // Turn off the LED
            }

            Serial.println("Received data - Relay: " + dataValue + " | LED: " + ledValue);
        }
    }
}

3. Set WiFi Credential and Antares Credential in Program Code

Change the HTTP Protocol parameters in the following variables *ACCESSKEY, *WIFISSID, *PASSWORD, *projectName, and *deviceName. Adjust to the parameters in the Antares console.

#define ACCESSKEY "YOUR-ACCESS-KEY"       // Replace with your Antares account access key
#define WIFISSID "YOUR-WIFI-SSID"         // Replace with your Wi-Fi SSID
#define PASSWORD "YOUR-WIFI-PASSWORD"     // Replace with your Wi-Fi password

#define projectName "YOUR-APPLICATION-NAME"   // Replace with the Antares application name that was created
#define deviceName "YOUR-DEVICE-NAME"     // Replace with the Antares device name that was created

The *Access key parameter is obtained from your Antares account page.

The WIFISSID parameter is obtained from the name of the Wifi / Hotspot that is currently being used by you. for example in the image below.

The *PASSWORD parameter is obtained from the WiFi password you are currently using.

The parameters *projectName, *deviceName are obtained from the Application Name and Device Name that have been created in the Antares account.

4. Compile and Upload Program

Connect the Lynx-32 with your computer and make sure the Communication Port is read.

On Windows operating systems the check can be done via Device Manager. If your Lynx-32 is read then the USB-Serial CH340 appears with the port adjusting the port availability (in this case it reads COM4).

Set up the ESP32 board by clicking Tools > Board > esp32 in the Arduino IDE, then make sure the ESP32 Dev Module is used. Select the port according to the communication port that is read (in this case COM4). The result will look like the following image.

After all the setup is complete, upload the programme by pressing the arrow icon as shown below. Wait for the compile and upload process to finish

The Tick icon on the Arduino IDE is just the verify process. Usually used to Compile the programme to find out whether there are errors or not.

The Arrow icon on the Arduino IDE is the verify and upload process. Usually used to Compile the programme as well as Flash the programme to the target board.

If the programme upload is successful, it will look like the following image..

After uploading the programme, you can view the serial monitor to debug the programme. The serial monitor icon is shown in the following image.

Set the serial baud rate to 115200 and select BothNL & CR. The result will look like the following image.

Make sure the serial baud rate matches the value defined in the programme code. If the serial baud rate is not the same between the programme code and the serial monitor, the ASCII characters will not be read properly.

5. Setup POSTMAN Software

In this step you need POSTMAN software, you can input the end-point, request header and request body first by following the following format.

End Point

Method

POST

URL

https://platform.antares.id:8443/~/antares-cse/antares-id/your-application-name/your-device-name

Customise your-application-name and your-device-name to the names registered to your Antares account.

Request Header

Key

Value

X-M2M-Origin

your-access-key

Content-Type

application/json;ty=4

application/json

Customise your-access-key with your Antares account access key.

The result will be as shown below.

Next, you need to input the request body by following the following format.

Request Body

{
  "m2m:cin": {
    "con": "{\"key1\":\"integer-value\", \"key2\":\"string-value\", \"keyN\":\"valueN\"}"
  }
}

In the POSTMAN software, select the Body tab then select raw and enter the payload according to the request body you want to use as shown below.

Customise the contents of the "con" field according to the "key" and "value" you want to send.

6. Sending POSTMAN Messages to the Antares Server

After the POSTMAN software setup is complete, it's time to send the POST command. The "Relay" field is filled with the string "1" for RELAY ON or "0" for RELAY OFF. The "LED" field is filled with the string "1" for LED ON or "0" for LED OFF. The "Relay" and "LED" fields are command messages to control the Relay and LED that will be sent via HTTP protocol to the Antares server.

{
  "m2m:cin": {
    "con": "{\"Relay\":\"1\", \"LED\":\"1\"}" 
  }
}

Customise the contents of the "Relay" and "LED" fields according to the get command you want to send. Give the value "1" or "0" to switch on or off.

If you have finished filling in the "test" field, then press the Send button on the POSTMAN software. The HTTP request indicator through the POSTMAN software is successful, the POSTMAN software response section will appear as shown below